Electrically-coupled Retzius neurons (Vazquez et al. 2009)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:120910
"Dendritic electrical coupling increases the number of effective synaptic inputs onto neurons by allowing the direct spread of synaptic potentials from one neuron to another. Here we studied the summation of excitatory postsynaptic potentials (EPSPs) produced locally and arriving from the coupled neuron (transjunctional) in pairs of electrically-coupled Retzius neurons of the leech. We combined paired recordings of EPSPs, the production of artificial EPSPs (APSPs) in neuron pairs with different coupling coefficients and simulations of EPSPs produced in the coupled dendrites. ..."
Reference:
1 . Vazquez Y, Mendez B, Trueta C, De-Miguel FF (2009) Summation of excitatory postsynaptic potentials in electrically-coupled neurones. Neuroscience 163:202-12 [PubMed]
Citations  Citation Browser
Model Information (Click on a link to find other models with that property)
Model Type: Realistic Network; Neuron or other electrically excitable cell;
Brain Region(s)/Organism: Leech;
Cell Type(s): Leech Retzius neuron;
Channel(s): I Na,t; I A; I K; I K,Ca; I Calcium;
Gap Junctions: Gap junctions;
Receptor(s):
Gene(s):
Transmitter(s):
Simulation Environment: NEURON;
Model Concept(s): Synaptic Integration;
Implementer(s):
Search NeuronDB for information about:  I Na,t; I A; I K; I K,Ca; I Calcium;
TITLE K-A channel from Beck Ficker and Heinemann (1992)
: M.Migliore 2001

UNITS {
	(mA) = (milliamp)
	(mV) = (millivolt)

}

PARAMETER {
	v (mV)
	celsius		(degC)
	gkabar= 0.01 (mho/cm2)
        vhalfn=-73.1   (mV)
        vl=-73.1   (mV)
	vn=11	(mV)
	kn=3
	th=-55	(mV)
        vhalfl=-73.1   (mV)
        a0l=0.02      (/ms)
        a0n=0.3    (/ms)
        zetan=-1.5    (1)
        zetal=2    (1)
        gmn=0.7   (1)
        gml=0.65   (1)
	lmin=7.5  (mS)
	nmin=0.5  (mS)
	q10=3
	ek
}


NEURON {
	SUFFIX kadend USEION k READ ek WRITE ik
        RANGE gkabar,gka
        GLOBAL ninf,linf,taul,taun,lmin
}

STATE {
	n
        l
}

ASSIGNED {
	ik (mA/cm2)
        ninf
        linf      
        taul
        taun
        gka
}

INITIAL {
	rates(v)
	n=ninf
	l=linf
}


BREAKPOINT {
	SOLVE states METHOD cnexp
	gka = gkabar*n*l
	ik = gka*(v-ek)

}


FUNCTION alpn(v(mV)) {
  alpn = exp(1.e-3*zetan*(v-vhalfn)*9.648e4/(8.315*(273.16+celsius))) 
}

FUNCTION betn(v(mV)) {
  betn = exp(1.e-3*zetan*gmn*(v-vhalfn)*9.648e4/(8.315*(273.16+celsius))) 
}

FUNCTION alpl(v(mV)) {
  alpl = exp(1.e-3*zetal*(v-vhalfl)*9.648e4/(8.315*(273.16+celsius))) 
}

FUNCTION betl(v(mV)) {
  betl = exp(1.e-3*zetal*gml*(v-vhalfl)*9.648e4/(8.315*(273.16+celsius))) 
}

DERIVATIVE states {     : exact when v held constant; integrates over dt step
        rates(v)
        n' = (ninf - n)/taun
        l' =  (linf - l)/taul
}

PROCEDURE rates(v (mV)) { :callable from hoc
        LOCAL a,qt
        qt=q10^((celsius-22)/10)
	if (v<=th) {ninf=0} else {ninf = (2*(v-th)^kn)/((vn-th)^kn+ (v-th)^kn)}
        taun = betn(v)/(qt*a0n*(1+alpn(v)))
	if (taun<nmin/qt) {taun=nmin/qt}
        linf = 1/(1+ exp((vl-v)/-6.3))
        taul = betl(v)/(qt*a0l*(1+alpl(v)))
	if (taul<lmin/qt) {taul=lmin/qt}
}