Hodgkin-Huxley models of different classes of cortical neurons (Pospischil et al. 2008)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:123623
"We review here the development of Hodgkin- Huxley (HH) type models of cerebral cortex and thalamic neurons for network simulations. The intrinsic electrophysiological properties of cortical neurons were analyzed from several preparations, and we selected the four most prominent electrophysiological classes of neurons. These four classes are 'fast spiking', 'regular spiking', 'intrinsically bursting' and 'low-threshold spike' cells. For each class, we fit 'minimal' HH type models to experimental data. ..."
Reference:
1 . Pospischil M, Toledo-Rodriguez M, Monier C, Piwkowska Z, Bal T, Frégnac Y, Markram H, Destexhe A (2008) Minimal Hodgkin-Huxley type models for different classes of cortical and thalamic neurons. Biol Cybern 99:427-41 [PubMed]
Citations  Citation Browser
Model Information (Click on a link to find other models with that property)
Model Type: Neuron or other electrically excitable cell; Channel/Receptor;
Brain Region(s)/Organism: Neocortex;
Cell Type(s): Neocortex V1 L6 pyramidal corticothalamic GLU cell; Neocortex V1 L2/6 pyramidal intratelencephalic GLU cell; Neocortex fast spiking (FS) interneuron; Neocortex spiking regular (RS) neuron; Neocortex spiking low threshold (LTS) neuron;
Channel(s): I Na,t; I L high threshold; I T low threshold; I K; I M;
Gap Junctions:
Receptor(s):
Gene(s):
Transmitter(s):
Simulation Environment: NEURON;
Model Concept(s): Parameter Fitting; Simplified Models;
Implementer(s): Destexhe, Alain [Destexhe at iaf.cnrs-gif.fr];
Search NeuronDB for information about:  Neocortex V1 L6 pyramidal corticothalamic GLU cell; Neocortex V1 L2/6 pyramidal intratelencephalic GLU cell; I Na,t; I L high threshold; I T low threshold; I K; I M;
/
PospischilEtAl2008
README.html *
cadecay_destexhe.mod *
HH_traub.mod *
IL_gutnick.mod
IM_cortex.mod *
IT_huguenard.mod *
demo_IN_FS.hoc *
demo_PY_IB.hoc *
demo_PY_IBR.hoc *
demo_PY_LTS.hoc *
demo_PY_RS.hoc *
fig5b.jpg *
mosinit.hoc *
rundemo.hoc *
sIN_template *
sPY_template *
sPYb_template *
sPYbr_template *
sPYr_template *
                            
TITLE High threshold calcium current

COMMENT
-----------------------------------------------------------------------------
	High threshold calcium current
	------------------------------

   - Ca++ current, L type channels
   - Differential equations

   - Model from:

   Reuveni I; Friedman A; Amitai Y; Gutnick MJ.
     Stepwise repolarization from Ca2+ plateaus in neocortical pyramidal cells:
     evidence for nonhomogeneous distribution of HVA Ca2+ channels in
     dendrites.
   Journal of Neuroscience, 1993 Nov, 13(11):4609-21.

   - Experimental data for voltage-dependent activation:

   Sayer RJ; Schwindt PC; Crill WE.
     High- and low-threshold calcium currents in neurons acutely isolated from
     rat sensorimotor cortex.
   Neuroscience Letters, 1990 Dec 11, 120(2):175-8.
 
   - Experimental data for voltage-dependent inactivation:

   Dichter MA; Zona C.
     Calcium currents in cultured rat cortical neurons.
   Brain Research, 1989 Jul 17, 492(1-2):219-29.

   - Calcium-dependent inactivation was not modeled; if interested, see:

   Kay AR.
     Inactivation kinetics of calcium current of acutely dissociated CA1
     pyramidal cells of the mature guinea-pig hippocampus.
   Journal of Physiology, 1991 Jun, 437:27-48.

   - m2h kinetics from:

   Kay AR; Wong RK.
     Calcium current activation kinetics in isolated pyramidal neurones of the
     Ca1 region of the mature guinea-pig hippocampus.
   Journal of Physiology, 1987 Nov, 392:603-16.

   - Reversal potential described by Nernst equation
   - no temperature dependence included (rates correspond to 36 degC)


   Alain Destexhe, Laval University, 1996

-----------------------------------------------------------------------------
ENDCOMMENT

INDEPENDENT {t FROM 0 TO 1 WITH 1 (ms)}

NEURON {
	SUFFIX ical
	USEION ca READ eca WRITE ica
        RANGE gcabar, alpha_m, beta_m, alpha_h, beta_h, m, h, carev
}


UNITS {
	(mA) = (milliamp)
	(mV) = (millivolt)
	(molar) = (1/liter)
	(mM) = (millimolar)
	FARADAY = (faraday) (coulomb)
	R = (k-mole) (joule/degC)
}


PARAMETER {
	v		(mV)
	celsius	= 36	(degC)
	eca		(mV)
	cai 	= .00024 (mM)		: initial [Ca]i = 200 nM
	cao 	= 2	(mM)		: [Ca]o = 2 mM
	gcabar	= 1e-4	(mho/cm2)	: Max conductance
}


STATE {
	m
	h
}

ASSIGNED {
	ica	(mA/cm2)		: current
	carev	(mV)			: rev potential
	alpha_m	(/ms)			: rate cst
	beta_m	(/ms)
	alpha_h	(/ms)
	beta_h	(/ms)
	tadj
}


BREAKPOINT { 
	SOLVE states METHOD cnexp : see http://www.neuron.yale.edu/phpBB/viewtopic.php?f=28&t=592
	carev = (1e3) * (R*(celsius+273.15))/(2*FARADAY) * log (cao/cai)
	ica = gcabar * m * m * h * (v-carev)
}

DERIVATIVE states { 
	evaluate_fct(v)

	m' = alpha_m * (1-m) - beta_m * m
	h' = alpha_h * (1-h) - beta_h * h
}


UNITSOFF

INITIAL {
	evaluate_fct(v)
:	m = alpha_m / (alpha_m + beta_m)
:	h = alpha_h / (alpha_h + beta_h)
:	tadj = 3 ^ ((celsius-36)/10)
}

PROCEDURE evaluate_fct(v(mV)) {

	: rates at 36 degC

	alpha_m = 0.055 * (-27-v) / (exp((-27-v)/3.8) - 1)
	beta_m = 0.94 * exp((-75-v)/17)

	alpha_h = 0.000457 * exp((-13-v)/50)
	beta_h = 0.0065 / (exp((-15-v)/28) + 1)
}

UNITSON