Complex CA1-neuron to study AP initiation (Wimmer et al. 2010)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:123927
Complex model of a pyramidal CA1-neuron, adapted from Royeck, M., et al. Role of axonal NaV1.6 sodium channels in action potential initiation of CA1 pyramidal neurons. Journal of neurophysiology 100, 2361-2380 (2008). It contains a biophysically realistic morphology comprising 265 compartments (829 segments) and 15 different distributed Ca2+- and/or voltage-dependent conductances.
Reference:
1 . Wimmer VC, Reid CA, Mitchell S, Richards KL, Scaf BB, Leaw BT, Hill EL, Royeck M, Horstmann MT, Cromer BA, Davies PJ, Xu R, Lerche H, Berkovic SF, Beck H, Petrou S (2010) Axon initial segment dysfunction in a mouse model of genetic epilepsy with febrile seizures plus. J Clin Invest 120:2661-71 [PubMed]
Citations  Citation Browser
Model Information (Click on a link to find other models with that property)
Model Type: Neuron or other electrically excitable cell;
Brain Region(s)/Organism:
Cell Type(s): Hippocampus CA1 pyramidal GLU cell;
Channel(s): I Na,p; I Na,t; I L high threshold; I N; I T low threshold; I p,q; I A; I K; I K,leak; I M; I h; I K,Ca; I Calcium;
Gap Junctions:
Receptor(s):
Gene(s): Nav SCN1B;
Transmitter(s):
Simulation Environment: NEURON;
Model Concept(s): Action Potential Initiation; Detailed Neuronal Models; Epilepsy;
Implementer(s): Horstmann, Marie-Therese [mhorstma at uni-bonn.de];
Search NeuronDB for information about:  Hippocampus CA1 pyramidal GLU cell; I Na,p; I Na,t; I L high threshold; I N; I T low threshold; I p,q; I A; I K; I K,leak; I M; I h; I K,Ca; I Calcium;
TITLE T-calcium channel

UNITS {
	(mA) = (milliamp)
	(mV) = (millivolt)
    (molar) = (1/liter)
    (mM) = (millimolar)

	FARADAY = 96520 (coul)
	R = 8.3134 (joule/degC)
	KTOMV = .0853 (mV/degC)
	F = 96485 (coul)
}

PARAMETER {
	v (mV)
	celsius = 6.3	(degC)
: wie gross ist PcaTbar
	PcaTbar = .000011 (cm/s)
	cai (mM)
	cao (mM)
	q10Ampl=3.3
	q10m=3.55
	q10h=2.8
}


NEURON {
	SUFFIX cat
	USEION ca READ cai,cao WRITE ica
        RANGE PcaTbar,cai
}

STATE {
	m h 
}

ASSIGNED {
	ica (mA/cm2)
        PcaT (cm/s)
}

INITIAL {
      m = minf(v)
      h = hinf(v)
}

UNITSOFF
BREAKPOINT {
	SOLVE states METHOD cnexp
	PcaT = PcaTbar*m*m*h
	ica = PcaT*ghk(v,cai,cao)

}

DERIVATIVE states {	
	m' = (minf(v) - m)/m_tau(v)
	h' = (hinf(v) - h)/h_tau(v)
}




FUNCTION ghk(v(mV), ci(mM), co(mM)) (mV) {
        LOCAL a, qtAmpl
	
	qtAmpl=q10Ampl^((celsius-23)/10)

        a=2*F*v/(R*(celsius+273.15)*1000)
	
        ghk=qtAmpl*2*F/1000*(co - ci*exp(a))*func(a)
}


FUNCTION func(a) {
	if (fabs(a) < 1e-4) {
		func = -1 + a/2
	}else{
		func = a/(1-exp(a))
	}
}


FUNCTION hinf(v(mV)) 
{       TABLE FROM -150 TO 150 WITH 3000 :Mitti 
	hinf = 1/(1+exp((v+72)/3.7))
}

FUNCTION minf(v(mV)) {
	TABLE FROM -150 TO 150 WITH 3000 :Mitti
        minf = (1/(1+exp(-(v+31.4)/8.8)))^0.5
}

FUNCTION m_tau(v(mV)) (ms) {
	LOCAL f1,f2, qtm
	
        TABLE FROM -150 TO 150 WITH 3000 :Mitti
        
	qtm=q10m^((celsius-23)/10)
	
	f1=1/(1+exp(-(v-7.63)/28.47))+0.01
	f2=62.82/(1+exp((v+37.02)/5.27))+3.78

	m_tau=f1*f2/qtm
}

FUNCTION h_tau(v(mV)) (ms) {
	LOCAL alphah, localhinf,qth
	
        TABLE FROM -150 TO 150 WITH 3000 :Mitti
        
	qth=q10h^((celsius-23)/10)
	
	localhinf = 1/(1+exp((v+72)/3.7))
	
	alphah=0.0021/(1+exp((v+65.77)/4.32))
	
	h_tau = localhinf/(qth*alphah)
}

UNITSON