Frog second-order vestibular neuron models (Rossert et al. 2011)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:139654
This implements spiking Hodgkin-Huxley type models of tonic and phasic second-order vestibular neurons. Models fitted to intracellular spike and membrane potential recordings from frog (Rana temporaria). The models can be stimulated by intracellular step current, frequency current (ZAP) or synaptic stimulation.
Reference:
1 . Rössert C, Moore LE, Straka H, Glasauer S (2011) Cellular and network contributions to vestibular signal processing: impact of ion conductances, synaptic inhibition, and noise. J Neurosci 31:8359-72 [PubMed]
Citations  Citation Browser
Model Information (Click on a link to find other models with that property)
Model Type: Neuron or other electrically excitable cell;
Brain Region(s)/Organism:
Cell Type(s): Vestibular neuron; Abstract Morris-Lecar neuron;
Channel(s): I T low threshold; I K,Ca; I Sodium; I Potassium;
Gap Junctions:
Receptor(s):
Gene(s):
Transmitter(s): Glycine; Gaba; Glutamate;
Simulation Environment: NEURON;
Model Concept(s): Simplified Models; Action Potentials; Sensory processing; Vestibular;
Implementer(s): Roessert, Christian [christian.a at roessert.de];
Search NeuronDB for information about:  I T low threshold; I K,Ca; I Sodium; I Potassium; Glycine; Gaba; Glutamate;
TITLE kca.mod   Calcium activated K channel

COMMENT

    Calcium activated Potassium channel

    Simplifictaion: Spike dependent current only!

    Created by Christian Roessert

ENDCOMMENT




UNITS {
        (nA) = (milliamp)
        (mV) = (millivolt)
}

NEURON {
  POINT_PROCESS KCa
  NONSPECIFIC_CURRENT ik
  RANGE dgkbar, egk, ctau, thresh, gk
}


PARAMETER {
  	dgkbar = 0.1 (mS/cm2) <0,1e9>
	egk   = -90 (mV)   
  	ctau =  50   (ms)
  	thresh = -20 (mV)
}


STATE {
        c
}

ASSIGNED {
  	v (mV)
	area (um2) : area of current segment (automatically available within NMODL, like v)
 	dgk (uS) : set to dgkbar * segment area at initialization
  	gk (uS) : will be 0 or dgk*c depending on recent spiking history
	ik (nA)
}

BREAKPOINT {
	SOLVE state METHOD cnexp 
	gk = dgk*c
	ik = gk*(v - egk) 

}

INITIAL {
  	dgk = dgkbar*area*1e-5 : because area will be in um2, but dgk is in uS and dgkbar in mS/cm2
   	gk = 0 : because at t = 0 we assume that the cell has not yet spiked
	c = 0
	net_send(0, 1)
}

DERIVATIVE state {     : exact when v held constant; integrates over dt step
	c' = -c/ctau
}

NET_RECEIVE (null) {
	if (flag==1) { : no spike has occured
		WATCH (v > thresh) 2 : detect spike
	}

	if (flag==2) { : spike has occured
		WATCH (v < thresh) 3 : detect spike off
        :c = c+1 : increase c and wait for next spike
		:net_send(0, 1)
   	}
	
	if (flag==3) { : 
		c = c+1 : increase c and wait for next spike
        at_time(t)
		net_send(0, 1)
   	}
}