Phase response curve of a globus pallidal neuron (Fujita et al. 2011)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:143100
We investigated how changes in ionic conductances alter the phase response curve (PRC) of a globus pallidal (GP) neuron and stability of a synchronous activity of a GP network, using a single-compartmental conductance-based neuron model. The results showed the PRC and the stability were influenced by changes in the persistent sodium current, the Kv3 potassium, the M-type potassium and the calcium-dependent potassium current.
Reference:
1 . Fujita T, Fukai T, Kitano K (2012) Influences of membrane properties on phase response curve and synchronization stability in a model globus pallidus neuron. J Comput Neurosci 32:539-53 [PubMed]
Citations  Citation Browser
Model Information (Click on a link to find other models with that property)
Model Type: Neuron or other electrically excitable cell;
Brain Region(s)/Organism: Basal ganglia;
Cell Type(s): Globus pallidus neuron;
Channel(s): I Na,p; I Na,t; I A; I M; I h; I K,Ca; I Calcium; I A, slow; KCNQ1;
Gap Junctions:
Receptor(s):
Gene(s):
Transmitter(s): Ions;
Simulation Environment: NEURON;
Model Concept(s): Synchronization; Parkinson's; Phase Response Curves;
Implementer(s): Kitano, Katsunori [kitano at ci.ritsumei.ac.jp];
Search NeuronDB for information about:  I Na,p; I Na,t; I A; I M; I h; I K,Ca; I Calcium; I A, slow; KCNQ1; Ions;
TITLE KCNQ potassium channel for GPe neuron

COMMENT
 modeled by Gunay et al., 2008
 implemented in NEURON by Kitano, 2011
ENDCOMMENT

UNITS {
 (mV) = (millivolt)
 (mA) = (milliamp)
}

NEURON {
 SUFFIX KCNQ
 USEION k READ ek WRITE ik
 RANGE gmax, iKCNQ
}

PARAMETER {
 v (mV)
 dt (ms)
 gmax  = 0.001 (mho/cm2)
 iKCNQ  = 0.0 (mA/cm2)
 ek (mV)

 theta_m = -61.0 (mV)
 k_m = 19.5 (mV)
 tau_m0 = 6.7 (ms)
 tau_m1 = 100.0 (ms)
 phi_m = -61.0 (mV)
 sigma_m0 = 35.0 (mV)
 sigma_m1 = -25.0 (mV)
}

STATE {
 m
}

ASSIGNED { 
 ik (mA/cm2)
 minf
 taum (ms)
}

BREAKPOINT {
 SOLVE states METHOD cnexp
 ik  = gmax*m*m*m*m*(v-ek)
 iKCNQ = ik
}

UNITSOFF

INITIAL {
 settables(v)
 m = minf
}

DERIVATIVE states {  
 settables(v)
 m' = (minf - m)/taum
}

PROCEDURE settables(v) {
        TABLE minf, taum FROM -100 TO 100 WITH 400

	minf = 1.0 / (1.0 + exp((theta_m - v)/k_m))
	taum = tau_m0 + (tau_m1 - tau_m0)/(exp((phi_m - v)/sigma_m0) + exp((phi_m - v)/sigma_m1))
}

UNITSON