A set of reduced models of layer 5 pyramidal neurons (Bahl et al. 2012)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:146026
These are the NEURON files for 10 different models of a reduced L5 pyramidal neuron. The parameters were obtained by automatically fitting the models to experimental data using a multi objective evolutionary search strategy. Details on the algorithm can be found at http://www.g-node.org/emoo and in Bahl et al. (2012).
Reference:
1 . Bahl A, Stemmler MB, Herz AV, Roth A (2012) Automated optimization of a reduced layer 5 pyramidal cell model based on experimental data. J Neurosci Methods 210:22-34 [PubMed]
Citations  Citation Browser
Model Information (Click on a link to find other models with that property)
Model Type: Neuron or other electrically excitable cell; Dendrite;
Brain Region(s)/Organism:
Cell Type(s): Neocortex U1 L5B pyramidal pyramidal tract GLU cell;
Channel(s): I Na,p; I Na,t; I K; I M; I h; I K,Ca; I Calcium; I A, slow;
Gap Junctions:
Receptor(s):
Gene(s):
Transmitter(s):
Simulation Environment: NEURON;
Model Concept(s): Action Potential Initiation; Parameter Fitting; Simplified Models; Active Dendrites; Detailed Neuronal Models; Action Potentials; Methods; Calcium dynamics;
Implementer(s): Bahl, Armin [bahl at neuro.mpg.de];
Search NeuronDB for information about:  Neocortex U1 L5B pyramidal pyramidal tract GLU cell; I Na,p; I Na,t; I K; I M; I h; I K,Ca; I Calcium; I A, slow;
TITLE Cortical M current
:
:   M-current, responsible for the adaptation of firing rate and the 
:   afterhyperpolarization (AHP) of cortical pyramidal cells
:
:   First-order model described by hodgkin-Hyxley like equations.
:   K+ current, activated by depolarization, noninactivating.
:
:   Model taken from Yamada, W.M., Koch, C. and Adams, P.R.  Multiple 
:   channels and calcium dynamics.  In: Methods in Neuronal Modeling, 
:   edited by C. Koch and I. Segev, MIT press, 1989, p 97-134.
:
:   See also: McCormick, D.A., Wang, Z. and Huguenard, J. Neurotransmitter 
:   control of neocortical neuronal activity and excitability. 
:   Cerebral Cortex 3: 387-398, 1993.
:
:   Written by Alain Destexhe, Laval University, 1995
:

INDEPENDENT {t FROM 0 TO 1 WITH 1 (ms)}

NEURON {
	SUFFIX km : renamend (Armin Jul 09)
	USEION k READ ek WRITE ik
    RANGE gkbar, m_inf, tau_m, gk, m, vshift
	GLOBAL taumax

}

UNITS {
	(mA) = (milliamp)
	(mV) = (millivolt)
}


PARAMETER {
	v		(mV)
	vshift = 0
	celsius = 36    (degC)
	ek		(mV)
	gbar	= 0	(pS/um2)
	taumax	= 1000	(ms)		: peak value of tau
}



STATE {
	m
}

ASSIGNED {
	ik	(mA/cm2)
	m_inf
	tau_m	(ms)
	tau_peak	(ms)
	tadj
	gk 	(mho/cm2)
}

BREAKPOINT {
	SOLVE states METHOD euler
	gk = gbar * m
	ik =  (1e-4)*gk * (v - ek)
}

DERIVATIVE states { 
	evaluate_fct(v-vshift)

	m' = (m_inf - m) / tau_m
}

UNITSOFF
INITIAL {
	evaluate_fct(v-vshift)
	m = m_inf	 : changed from 0 to m_inf (Armin)
:
:  The Q10 value is assumed to be 2.3
:
        tadj = 2.3 ^ ((celsius-36)/10)
	tau_peak = taumax / tadj
}

PROCEDURE evaluate_fct(v(mV)) {

	m_inf = 1 / ( 1 + exptable(-(v+35)/10) )
	tau_m = tau_peak / ( 3.3 * exptable((v+35)/20) + exptable(-(v+35)/20) )
}
UNITSON


FUNCTION exptable(x) { 
	TABLE  FROM -25 TO 25 WITH 10000

	if ((x > -25) && (x < 25)) {
		exptable = exp(x)
	} else {
		exptable = 0.
	}
}