CA1 pyramidal neuron: dendritic Ca2+ inhibition (Muellner et al. 2015)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:206244
In our experimental study, we combined paired patch-clamp recordings and two-photon Ca2+ imaging to quantify inhibition exerted by individual GABAergic contacts on hippocampal pyramidal cell dendrites. We observed that Ca2+ transients from back-propagating action potentials were significantly reduced during simultaneous activation of individual nearby GABAergic synapses. To simulate dendritic Ca2+ inhibition by individual GABAergic synapses, we employed a multi-compartmental CA1 pyramidal cell model with detailed morphology, voltage-gated channel distributions, and calcium dynamics, based with modifications on the model of Poirazi et al., 2003, modelDB accession # 20212.
Reference:
1 . Müllner FE, Wierenga CJ, Bonhoeffer T (2015) Precision of Inhibition: Dendritic Inhibition by Individual GABAergic Synapses on Hippocampal Pyramidal Cells Is Confined in Space and Time. Neuron 87:576-89 [PubMed]
Citations  Citation Browser
Model Information (Click on a link to find other models with that property)
Model Type: Neuron or other electrically excitable cell;
Brain Region(s)/Organism: Hippocampus;
Cell Type(s): Hippocampus CA1 pyramidal cell;
Channel(s): I Calcium; I Sodium; I Potassium; I h;
Gap Junctions:
Receptor(s):
Gene(s):
Transmitter(s): Gaba;
Simulation Environment: NEURON;
Model Concept(s): Action Potentials; Dendritic Action Potentials; Active Dendrites; Calcium dynamics;
Implementer(s): Muellner, Fiona E [fiona.muellner at gmail.com];
Search NeuronDB for information about:  Hippocampus CA1 pyramidal cell; I h; I Sodium; I Calcium; I Potassium; Gaba;
/
CA1_multi
mechanism
previously used
ampa.mod *
cad.mod
cagk.mod *
cal.mod *
calH.mod *
cat.mod
cldif.mod
d3.mod *
gabaA_Cl.mod
h.mod *
hha_old.mod *
hha2.mod *
kadist.mod *
kaprox.mod *
kca.mod *
km.mod *
nap.mod *
nmda.mod *
                            
TITLE t-type calcium channel with high threshold for activation
: used in somatic and dendritic regions 
: it calculates I_Ca using channel permeability instead of conductance
:
: Modified by Fiona Muellner, MPI Neurobiology, March 2015 (email: fiona.muellner@gmail.com) to replace the dummy-ion Ca by the ion ca which updates cai.

UNITS {
	(mA) = (milliamp)
	(mV) = (millivolt)

	FARADAY = 96520 (coul)
	R = 8.3134 (joule/degK)
	KTOMV = .0853 (mV/degC)
}

INDEPENDENT {t FROM 0 TO 1 WITH 1 (ms)}

PARAMETER {           :parameters that can be entered when function is called in cell-setup 
        dt            (ms)
	v             (mV)
        tBase = 23.5  (degC)
	celsius = 22  (degC)
	gcatbar = 0   (mho/cm2)  : initialized conductance
	ki = 0.001    (mM)
	cai = 5.e-5   (mM)       : initial internal Ca++ concentration
	cao = 2       (mM)       : initial external Ca++ concentration
        tfa = 1                  : activation time constant scaling factor
        tfi = 0.68               : inactivation time constant scaling factor
        eca = 140                : Ca++ reversal potential
}

NEURON {
	SUFFIX cat
	USEION ca READ cai,cao 
        WRITE ica VALENCE 2
        RANGE gcatbar, hinf, minf, taum, tauh, ica
}

STATE {	m h }  : unknown activation and inactivation parameters to be solved in the DEs 

ASSIGNED {     : parameters needed to solve DE
	ica (mA/cm2)
        gcat  (mho/cm2) 
        minf
        hinf
        taum
        tauh
}

INITIAL {
:        tadj = 3^((celsius-tBase)/10)   : assume Q10 of 3
	rates(v)
        m = minf
        h = hinf
	gcat = gcatbar*m*m*h*h2(cai)
}

BREAKPOINT {
	SOLVE states
	gcat = gcatbar*m*m*h*h2(cai) : maximum channel permeability
	ica = gcat*ghk(v,cai,cao)    : dummy calcium current induced by this channel

}

UNITSOFF
FUNCTION h2(cai(mM)) {
	h2 = ki/(ki+cai)
}

FUNCTION ghk(v(mV), ci(mM), co(mM)) (mV) { LOCAL nu,f
        f = KTF(celsius)/2
        nu = v/f
        ghk=-f*(1. - (ci/co)*exp(nu))*efun(nu)
}

FUNCTION KTF(celsius (degC)) (mV) {   : temperature-dependent adjustment factor
        KTF = ((25./293.15)*(celsius + 273.15))
}

FUNCTION efun(z) {
	if (fabs(z) < 1e-4) {
		efun = 1 - z/2
	}else{
		efun = z/(exp(z) - 1)
	}
}

FUNCTION alph(v(mV)) {
	TABLE FROM -150 TO 150 WITH 200
	alph = 1.6e-4*exp(-(v+57)/19)
}

FUNCTION beth(v(mV)) {
        TABLE FROM -150 TO 150 WITH 200
	beth = 1/(exp((-v+15)/10)+1.0)
}

FUNCTION alpm(v(mV)) {
	TABLE FROM -150 TO 150 WITH 200
	alpm = 0.1967*(-1.0*v+19.88)/(exp((-1.0*v+19.88)/10.0)-1.0)
}

FUNCTION betm(v(mV)) {
	TABLE FROM -150 TO 150 WITH 200
	betm = 0.046*exp(-v/22.73)
}

UNITSON
LOCAL facm,fach

:if state_cagk is called from hoc, garbage or segmentation violation will
:result because range variables won't have correct pointer.  This is because
: only BREAKPOINT sets up the correct pointers to range variables.
PROCEDURE states() {     : exact when v held constant; integrates over dt step
        rates(v)
        m = m + facm*(minf - m)
        h = h + fach*(hinf - h)
        VERBATIM
        return 0;
        ENDVERBATIM
}

PROCEDURE rates(v (mV)) { :callable from hoc
        LOCAL a
        a = alpm(v)
        taum = 1/(tfa*(a + betm(v))) : estimation of activation tau
        minf =  a/(a+betm(v))        : estimation of activation steady state
        facm = (1 - exp(-dt/taum))
        a = alph(v)
        tauh = 1/(tfi*(a + beth(v))) : estimation of inactivation tau
        hinf = a/(a+beth(v))         : estimation of inactivation steady state
        fach = (1 - exp(-dt/tauh))
}