Channel density variability among CA1 neurons (Migliore et al. 2018)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:244688
The peak conductance of many ion channel types measured in any given animal is highly variable across neurons, both within and between neuronal populations. The current view is that this occurs because a neuron needs to adapt its intrinsic electrophysiological properties either to maintain the same operative range in the presence of abnormal inputs or to compensate for the effects of pathological conditions. Limited experimental and modeling evidence suggests this might be implemented via the correlation and/or degeneracy in the function of multiple types of conductances. To study this mechanism in hippocampal CA1 neurons and interneurons, we systematically generated a set of morphologically and biophysically accurate models. We then analyzed the ensembles of peak conductance obtained for each model neuron. The results suggest that the set of conductances expressed in the various neuron types may be divided into two groups: one group is responsible for the major characteristics of the firing behavior in each population and the other more involved with degeneracy. These models provide experimentally testable predictions on the combination and relative proportion of the different conductance types that should be present in hippocampal CA1 pyramidal cells and interneurons.
Reference:
1 . Migliore R, Lupascu CA, Bologna LL, Romani A, Courcol JD, Antonel S, Van Geit WAH, Thomson AM, Mercer A, Lange S, Falck J, Roessert CA, Shi Y, Hagens O, Pezzoli M, Freund TF, Kali S, Muller EB, Schuermann F, Markram H, Migliore M (2018) The physiological variability of channel density in hippocampal CA1 pyramidal cells and interneurons explored using a unified data-driven modeling workflow PLOS Computational Biology
Citations  Citation Browser
Model Information (Click on a link to find other models with that property)
Model Type: Neuron or other electrically excitable cell;
Brain Region(s)/Organism: Hippocampus;
Cell Type(s): Hippocampus CA1 pyramidal GLU cell;
Channel(s): I h; Ca pump; I K; I K,Ca; I Calcium; I CAN; I M; I Na,t; I A; I_KD; I T low threshold; I L high threshold;
Gap Junctions:
Receptor(s):
Gene(s):
Transmitter(s):
Simulation Environment: NEURON; BluePyOpt ;
Model Concept(s): Activity Patterns; Action Potentials; Detailed Neuronal Models; Methods; Parameter Fitting;
Implementer(s): Migliore, Rosanna [rosanna.migliore at cnr.it]; Migliore, Michele [Michele.Migliore at Yale.edu];
Search NeuronDB for information about:  Hippocampus CA1 pyramidal GLU cell; I Na,t; I L high threshold; I T low threshold; I A; I K; I M; I h; I K,Ca; I CAN; I Calcium; I_KD; Ca pump;
/
MiglioreEtAl2018PLOSCompBiol2018
morphologies
readme_file
readme.htm
cacumm.mod *
cacummb.mod
cagk.mod *
cal2.mod *
can2.mod *
cat.mod *
h.mod
kadist.mod *
kaprox.mod *
kca.mod
kdb.mod
kdrbca1.mod
kdrca1.mod *
kmb.mod *
na3n.mod
naxn.mod
cell_seed1_0-bac-10.hoc
cell_seed1_0-cnac-04.hoc
cell_seed2_0-bac-06.hoc
cell_seed2_0-cnac-08.hoc
cell_seed3_0-pyr-08.hoc
cell_seed4_0-cac-06.hoc
cell_seed4_0-pyr-04.hoc
cell_seed7_0-cac-04.hoc
fig4A-model.hoc
fig4A-model.ses
mosinit.hoc
                            
TITLE nax
: Na current for axon. No slow inact.
: M.Migliore Jul. 1997
: added sh to account for higher threshold M.Migliore, Apr.2002
: WVG @ BBP 2018: add ttx sensitivity

NEURON {
	SUFFIX nax
	USEION na READ ena WRITE ina
    USEION ttx READ ttxo, ttxi VALENCE 1
	RANGE  gbar, sh
	GLOBAL minf, hinf, mtau, htau,thinf, qinf
}

PARAMETER {
	sh   = 0	(mV)
	gbar = 0.010   	(mho/cm2)	
								
	tha  =  -30	(mV)		: v 1/2 for act	
	qa   = 7.2	(mV)		: act slope (4.5)		
	Ra   = 0.4	(/ms)		: open (v)		
	Rb   = 0.124 	(/ms)		: close (v)		

	thi1  = -45	(mV)		: v 1/2 for inact 	
	thi2  = -45 	(mV)		: v 1/2 for inact 	
	qd   = 1.5	(mV)	        : inact tau slope
	qg   = 1.5      (mV)
	mmin=0.02	
	hmin=0.5			
	q10=2
	Rg   = 0.01 	(/ms)		: inact recov (v) 	
	Rd   = .03 	(/ms)		: inact (v)	

	thinf  = -50 	(mV)		: inact inf slope	
	qinf  = 4 	(mV)		: inact inf slope 

	ena		(mV)            : must be explicitly def. in hoc
	celsius
	v 		(mV)
}


UNITS {
	(mA) = (milliamp)
	(mV) = (millivolt)
	(pS) = (picosiemens)
	(um) = (micron)
} 

ASSIGNED {
    ttxo        (mM)
    ttxi        (mM)
	ina 		(mA/cm2)
	thegna		(mho/cm2)
	minf 		hinf 		
	mtau (ms)	htau (ms) 	
}
 

STATE { m h}

BREAKPOINT {
        SOLVE states METHOD cnexp
        thegna = gbar*m*m*m*h
	ina = thegna * (v - ena)
} 

INITIAL {
    if (ttxi == 0.015625 && ttxo > 1e-12) {
        minf = 0.0
        mtau = 1e-12
        hinf = 1.0
        htau = 1e-12
    } else {
        trates(v,sh)      
    }

	m=minf  
	h=hinf
}

DERIVATIVE states {   
    if (ttxi == 0.015625 && ttxo > 1e-12) {
        minf = 0.0
        mtau = 1e-12
        hinf = 1.0
        htau = 1e-12
    } else {
        trates(v,sh)      
    }
    
        m' = (minf-m)/mtau
        h' = (hinf-h)/htau
}

PROCEDURE trates(vm,sh2) {  
        LOCAL  a, b, qt
        qt=q10^((celsius-24)/10)
	a = trap0(vm,tha+sh2,Ra,qa)
	b = trap0(-vm,-tha-sh2,Rb,qa)
	mtau = 1/(a+b)/qt
        if (mtau<mmin) {mtau=mmin}
	minf = a/(a+b)

	a = trap0(vm,thi1+sh2,Rd,qd)
	b = trap0(-vm,-thi2-sh2,Rg,qg)
	htau =  1/(a+b)/qt
        if (htau<hmin) {htau=hmin}
	hinf = 1/(1+exp((vm-thinf-sh2)/qinf))
}

FUNCTION trap0(v,th,a,q) {
	if (fabs(v-th) > 1e-6) {
	        trap0 = a * (v - th) / (1 - exp(-(v - th)/q))
	} else {
	        trap0 = a * q
 	}
}