The APP in C-terminal domain alters CA1 neuron firing (Pousinha et al 2019)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:256388
"The amyloid precursor protein (APP) is central to AD pathogenesis and we recently showed that its intracellular domain (AICD) could modify synaptic signal integration. We now hypothezise that AICD modifies neuron firing activity, thus contributing to the disruption of memory processes. Using cellular, electrophysiological and behavioural techniques, we showed that pathological AICD levels weakens CA1 neuron firing activity through a gene transcription-dependent mechanism. Furthermore, increased AICD production in hippocampal neurons modifies oscillatory activity, specifically in the gamma frequency range, and disrupts spatial memory task. Collectively, our data suggest that AICD pathological levels, observed in AD mouse models and in human patients, might contribute to progressive neuron homeostatic failure, driving the shift from normal ageing to AD."
Reference:
1 . Pousinha PA, Mouska X, Bianchi D, Temido-Ferreira M, Rajão-Saraiva J, Gomes R, Fernandez SP, Salgueiro-Pereira AR, Gandin C, Raymond EF, Barik J, Lopes LV, Migliore M, Goutagny R, Bethus I, Marie H (2019) The Amyloid Precursor Protein C-terminal domain alters CA1 neuron firing, modifying hippocampus oscillations and impairing spatial memory encoding Cell Reports, in press
Citations  Citation Browser
Model Information (Click on a link to find other models with that property)
Model Type: Neuron or other electrically excitable cell;
Brain Region(s)/Organism: Hippocampus;
Cell Type(s): Hippocampus CA1 pyramidal GLU cell;
Channel(s): I Na,t; I A; I K; I M; I h; I L high threshold; I_AHP;
Gap Junctions:
Receptor(s): NMDA;
Gene(s):
Transmitter(s): Glutamate;
Simulation Environment: NEURON;
Model Concept(s): Aging/Alzheimer`s; Oscillations; Action Potentials; Memory;
Implementer(s): Bianchi, Daniela [danielabianchi12 -at- gmail.com];
Search NeuronDB for information about:  Hippocampus CA1 pyramidal GLU cell; NMDA; I Na,t; I L high threshold; I A; I K; I M; I h; I_AHP; Glutamate;
/
PousinhaMouskaBianchiEtAl2019
readme.txt
ANsyn.mod *
bgka.mod *
burststim2.mod *
cad.mod *
cagk.mod
cal.mod *
calH.mod *
car.mod *
cat.mod *
ccanl.mod *
d3.mod *
gskch.mod *
h.mod *
IA.mod
ichan2.mod *
Ih.mod *
kadist.mod *
kaprox.mod *
Kaxon.mod *
kca.mod *
Kdend.mod *
kdr.mod *
kdrax.mod *
km.mod *
Ksoma.mod *
LcaMig.mod *
my_exp2syn.mod *
na3.mod *
na3dend.mod *
na3notrunk.mod *
Naaxon.mod *
Nadend.mod *
nap.mod *
Nasoma.mod *
nax.mod *
nca.mod *
nmdanet.mod *
regn_stim.mod *
somacar.mod *
STDPE2Syn2.mod *
mosinit.hoc
pyramidal_cell4b.hoc
ranstream.hoc *
ses.ses
stim_cell.hoc *
testcell.hoc
                            
TITLE simple NMDA receptors

: Modified from the original AMPA.mod, M.Migliore Mar 2012
: NetCon weight of 1e-3 gives 1nS peak conductance in 0Mg

COMMENT
-----------------------------------------------------------------------------

	Simple model for glutamate AMPA receptors
	=========================================

  - FIRST-ORDER KINETICS, FIT TO WHOLE-CELL RECORDINGS

    Whole-cell recorded postsynaptic currents mediated by AMPA/Kainate
    receptors (Xiang et al., J. Neurophysiol. 71: 2552-2556, 1994) were used
    to estimate the parameters of the present model; the fit was performed
    using a simplex algorithm (see Destexhe et al., J. Computational Neurosci.
    1: 195-230, 1994).

  - SHORT PULSES OF TRANSMITTER (0.3 ms, 0.5 mM)

    The simplified model was obtained from a detailed synaptic model that 
    included the release of transmitter in adjacent terminals, its lateral 
    diffusion and uptake, and its binding on postsynaptic receptors (Destexhe
    and Sejnowski, 1995).  Short pulses of transmitter with first-order
    kinetics were found to be the best fast alternative to represent the more
    detailed models.

  - ANALYTIC EXPRESSION

    The first-order model can be solved analytically, leading to a very fast
    mechanism for simulating synapses, since no differential equation must be
    solved (see references below).



References

   Destexhe, A., Mainen, Z.F. and Sejnowski, T.J.  An efficient method for
   computing synaptic conductances based on a kinetic model of receptor binding
   Neural Computation 6: 10-14, 1994.  

   Destexhe, A., Mainen, Z.F. and Sejnowski, T.J. Synthesis of models for
   excitable membranes, synaptic transmission and neuromodulation using a 
   common kinetic formalism, Journal of Computational Neuroscience 1: 
   195-230, 1994.


-----------------------------------------------------------------------------
ENDCOMMENT



NEURON {
	POINT_PROCESS NMDA
	RANGE R, g, mg, gNMDAmax,i
	NONSPECIFIC_CURRENT i
	GLOBAL Cdur, Alpha, Beta, Erev, Rinf, Rtau
}
UNITS {
	(nA) = (nanoamp)
	(mV) = (millivolt)
	(umho) = (micromho)
	(mM) = (milli/liter)
}

PARAMETER {
      gNMDAmax=1  (umho)
	Cdur	= 1		(ms)	: transmitter duration (rising phase)
	Alpha	= 0.35		(/ms)	: forward (binding) rate
	Beta	= 0.015		(/ms)	: backward (unbinding) rate
:	Beta	= 0.035		(/ms)	: backward (unbinding) rate
:	Alpha	= 0.072		(/ms)	: forward (binding) rate
:	Beta	= 0.0066		(/ms)	: backward (unbinding) rate
	Erev	= 0	(mV)		: reversal potential
	mg	= 1    (mM)		: external magnesium concentration
}


ASSIGNED {
	v		(mV)		: postsynaptic voltage
	i 		(nA)		: current = g*(v - Erev)
	g 		(umho)		: conductance
	Rinf				: steady state channels open
	Rtau		(ms)		: time constant of channel binding
	synon
}

STATE {Ron Roff}

INITIAL {
	Rinf = Alpha / (Alpha + Beta)
	Rtau = 1 / (Alpha + Beta)
	synon = 0
}

BREAKPOINT {
	SOLVE release METHOD cnexp
	g = 3.4*mgblock(v)*(Ron + Roff)*1(umho)
	i = g*(v - Erev)		
}

DERIVATIVE release {
	Ron' = (synon*Rinf - Ron)/Rtau
	Roff' = -Beta*Roff
}

: following supports both saturation from single input and
: summation from multiple inputs
: if spike occurs during CDur then new off time is t + CDur
: ie. transmitter concatenates but does not summate
: Note: automatic initialization of all reference args to 0 except first


FUNCTION mgblock(v(mV)) {
	TABLE 
	DEPEND mg
	FROM -140 TO 80 WITH 1000

	: from Jahr & Stevens

	mgblock = 1 / (1 + exp(0.062 (/mV) * -v) * (mg / 3.57 (mM)))
}


NET_RECEIVE(weight, on, nspike, r0, t0 (ms)) {
	: flag is an implicit argument of NET_RECEIVE and  normally 0
        if (flag == 0) { : a spike, so turn on if not already in a Cdur pulse
		nspike = nspike + 1
		if (!on) {
			r0 = r0*exp(-Beta*(t - t0))
			t0 = t
			on = 1
			synon = synon + weight
			state_discontinuity(Ron, Ron + r0)
			state_discontinuity(Roff, Roff - r0)
		}
		: come again in Cdur with flag = current value of nspike
		net_send(Cdur, nspike)
        }
	if (flag == nspike) { : if this associated with last spike then turn off
		r0 = weight*Rinf + (r0 - weight*Rinf)*exp(-(t - t0)/Rtau)
		t0 = t
		synon = synon - weight
		state_discontinuity(Ron, Ron - r0)
		state_discontinuity(Roff, Roff + r0)
		on = 0
	}
}