Neocortical Layer I: I-A and I-K (Zhou, Hablitz 1996)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:3660
NEURON mod files for the I-A and I-K currents from the paper: Zhou FM, Hablitz JJ. Layer I neurons of the rat neocortex. II. Voltage-dependent outward currents. J Neurophysiol 1996 76:668-82.
Reference:
1 . Zhou FM, Hablitz JJ (1996) Layer I neurons of the rat neocortex. II. Voltage-dependent outward currents. J Neurophysiol 76:668-82 [PubMed]
Citations  Citation Browser
Model Information (Click on a link to find other models with that property)
Model Type: Channel/Receptor;
Brain Region(s)/Organism:
Cell Type(s): Neocortex L2/3 pyramidal GLU cell;
Channel(s): I A; I K; I Potassium;
Gap Junctions:
Receptor(s):
Gene(s):
Transmitter(s):
Simulation Environment: NEURON;
Model Concept(s): Activity Patterns; Bursting; Ion Channel Kinetics;
Implementer(s): Migliore, Michele [Michele.Migliore at Yale.edu];
Search NeuronDB for information about:  Neocortex L2/3 pyramidal GLU cell; I A; I K; I Potassium;
TITLE K-A
: K-A current for superficial neocortical pyramidal neurons 
: from Zhou and Hablitz (1996)
: M.Migliore Jan. 2002

NEURON {
	SUFFIX kasup
	USEION k READ ek WRITE ik
	RANGE  gbar
	GLOBAL minf, mtau, hinf, htau
}

PARAMETER {
	gbar = 0.0002   	(mho/cm2)	
								
	celsius
	ek		(mV)            : must be explicitly def. in hoc
	v 		(mV)
	a0m=0.04
	vhalfm=-45
	zetam=0.1
	gmm=0.75
	mmin=0.1

	a0h=0.018
	vhalfh=-70
	zetah=0.2
	gmh=0.99

	q10=3
}


UNITS {
	(mA) = (milliamp)
	(mV) = (millivolt)
	(pS) = (picosiemens)
	(um) = (micron)
} 

ASSIGNED {
	ik 		(mA/cm2)
	minf 		mtau (ms)	 	
	hinf 		htau (ms)	 	
}
 

STATE { m h}

BREAKPOINT {
        SOLVE states METHOD cnexp
	ik = gbar*m*h*(v - ek)
} 

INITIAL {
	trates(v)
	m=minf  
	h=hinf  
}

DERIVATIVE states {   
        trates(v)      
        m' = (minf-m)/mtau
        h' = (hinf-h)/htau
}

PROCEDURE trates(v) {  
	LOCAL qt
        qt=q10^((celsius-22)/10)
        minf = 1/(1 + exp(-(v+0.8)/11.6))
	mtau = betm(v)/(qt*a0m*(1+alpm(v)))
	if (mtau<mmin) {mtau=mmin}

        hinf = 1/(1 + exp((v+51.3)/7.9))
	htau = beth(v)/(qt*a0h*(1+alph(v)))
}

FUNCTION alpm(v(mV)) {
  alpm = exp(zetam*(v-vhalfm)) 
}

FUNCTION betm(v(mV)) {
  betm = exp(zetam*gmm*(v-vhalfm)) 
}

FUNCTION alph(v(mV)) {
  alph = exp(zetah*(v-vhalfh)) 
}

FUNCTION beth(v(mV)) {
  beth = exp(zetah*gmh*(v-vhalfh)) 
}