CN bushy, stellate neurons (Rothman, Manis 2003)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:37857
Using kinetic data from three different K+ currents in acutely isolated neurons, a single electrical compartment model representing the soma of a ventral cochlear nucleus (VCN) neuron was created. The K+ currents include a fast transient current (IA), a slow-inactivating low-threshold current (ILT), and a noninactivating high-threshold current (IHT). The model also includes a fast-inactivating Na+ current, a hyperpolarization-activated cation current (Ih), and 1-50 auditory nerve synapses. With this model, the role IA, ILT, and IHT play in shaping the discharge patterns of VCN cells is explored. Simulation results indicate these currents have specific roles in shaping the firing patterns of stellate and bushy CN cells. (see readme.txt and the papers, esp 2003c, for details). Any questions regarding these implementations should be directed to: pmanis@med.unc.edu 2 April 2004 Paul B Manis, Ph.D.
Reference:
1 . Rothman JS, Manis PB (2003) The roles potassium currents play in regulating the electrical activity of ventral cochlear nucleus neurons. J Neurophysiol 89:3097-113 [PubMed]
2 . Rothman JS, Manis PB (2003) Kinetic analyses of three distinct potassium conductances in ventral cochlear nucleus neurons. J Neurophysiol 89:3083-96 [PubMed]
3 . Rothman JS, Manis PB (2003) Differential expression of three distinct potassium currents in the ventral cochlear nucleus. J Neurophysiol 89:3070-82 [PubMed]
Citations  Citation Browser
Model Information (Click on a link to find other models with that property)
Model Type: Neuron or other electrically excitable cell;
Brain Region(s)/Organism:
Cell Type(s): Cochlear nucleus bushy GLU cell; CN stellate cell;
Channel(s): I Na,p; I Na,t; I L high threshold; I A; I K; I K,leak; I Sodium; I Potassium;
Gap Junctions:
Receptor(s):
Gene(s):
Transmitter(s):
Simulation Environment: NEURON;
Model Concept(s): Temporal Pattern Generation; Action Potentials; Audition;
Implementer(s): Manis, Paul B [PManis at med.unc.edu];
Search NeuronDB for information about:  Cochlear nucleus bushy GLU cell; I Na,p; I Na,t; I L high threshold; I A; I K; I K,leak; I Sodium; I Potassium;
TITLE h current for Octopus cells of Cochlear Nucleus
: From Bal and Oertel (2000)
: M.Migliore Oct. 2001

NEURON {
	SUFFIX hcno
	NONSPECIFIC_CURRENT i
	RANGE  gbar
	GLOBAL hinf, tau1,tau2
}

PARAMETER {
	gbar = 0.0005   	(mho/cm2)	
								
	vhalf1  = -50	(mV)		: v 1/2 for forward
	vhalf2  = -84 	(mV)		: v 1/2 for backward	
	gm1   = 0.3	(mV)	        : slope for forward
	gm2   = 0.6      (mV)		: slope for backward
	zeta1   = 3 	(/ms)		
	zeta2   = 3 	(/ms)		
	a01 = 0.008 
	a02 = 0.0029
	frac=0.0


	thinf  = -66 	(mV)		: inact inf slope	
	qinf  = 7 	(mV)		: inact inf slope 

	q10=4.5				: from Magee (1998)

	eh		(mV)            : must be explicitly def. in hoc
	celsius
	v 		(mV)
}


UNITS {
	(mA) = (milliamp)
	(mV) = (millivolt)
	(pS) = (picosiemens)
	(um) = (micron)
} 

ASSIGNED {
	i 		(mA/cm2)
	thegna		(mho/cm2)
	hinf tau1 tau2 
}
 

STATE { h1 h2 }

BREAKPOINT {
        SOLVE states METHOD derivimplicit
        thegna = gbar*(h1*frac + h2*(1-frac))
	i = thegna * (v - eh)
} 

INITIAL {
	trates(v)
	h1=hinf
	h2=hinf
}

DERIVATIVE states {   
        trates(v)      
		h1' = (hinf - h1)/tau1
		h2' = (hinf - h2)/tau2
}

PROCEDURE trates(v) {  
        LOCAL  qt
        qt=q10^((celsius-33)/10)

        tau1 = bet1(v)/(qt*a01*(1+alp1(v)))
        tau2 = bet2(v)/(qt*a02*(1+alp2(v)))

	hinf = 1/(1+exp((v-thinf)/qinf))
}

FUNCTION alp1(v(mV)) {
  alp1 = exp(1.e-3*zeta1*(v-vhalf1)*9.648e4/(8.315*(273.16+celsius))) 
}

FUNCTION bet1(v(mV)) {
  bet1 = exp(1.e-3*zeta1*gm1*(v-vhalf1)*9.648e4/(8.315*(273.16+celsius))) 
}

FUNCTION alp2(v(mV)) {
  alp2 = exp(1.e-3*zeta2*(v-vhalf2)*9.648e4/(8.315*(273.16+celsius))) 
}

FUNCTION bet2(v(mV)) {
  bet2 = exp(1.e-3*zeta2*gm2*(v-vhalf2)*9.648e4/(8.315*(273.16+celsius))) 
}