CA1 pyramidal neuron: dendritic spike initiation (Gasparini et al 2004)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:44050
NEURON mod files from the paper: Sonia Gasparini, Michele Migliore, and Jeffrey C. Magee On the initiation and propagation of dendritic spikes in CA1 pyramidal neurons, J. Neurosci., J. Neurosci. 24:11046-11056 (2004).
Reference:
1 . Gasparini S, Migliore M, Magee JC (2004) On the initiation and propagation of dendritic spikes in CA1 pyramidal neurons. J Neurosci 24:11046-56 [PubMed]
Citations  Citation Browser
Model Information (Click on a link to find other models with that property)
Model Type: Dendrite;
Brain Region(s)/Organism:
Cell Type(s): Hippocampus CA1 pyramidal cell;
Channel(s): I Na,t; I A; I K; I h;
Gap Junctions:
Receptor(s): AMPA; NMDA;
Gene(s):
Transmitter(s): Glutamate;
Simulation Environment: NEURON;
Model Concept(s): Action Potential Initiation; Dendritic Action Potentials; Coincidence Detection; Active Dendrites; Detailed Neuronal Models; Action Potentials;
Implementer(s): Migliore, Michele [Michele.Migliore at Yale.edu];
Search NeuronDB for information about:  Hippocampus CA1 pyramidal cell; AMPA; NMDA; I Na,t; I A; I K; I h; Glutamate;
/
gaspiriniEtAl2004
readme.txt *
exp2i.mod *
h.mod *
kadist.mod *
kaprox.mod *
kdrca1.mod *
na3s.mod *
naxn.mod *
netstims.mod *
nmdanet.mod *
forfig5A.hoc *
mosinit.hoc *
n160.nrn *
                            
COMMENT
Two state kinetic scheme described by rise time tau1,
and decay time constant tau2. The normalized peak current is 1nA.
Decay time MUST be greater than rise time.

The solution of A->G->bath with rate constants 1/tau1 and 1/tau2 is
 A = a*exp(-t/tau1) and
 G = a*tau2/(tau2-tau1)*(-exp(-t/tau1) + exp(-t/tau2))
	where tau1 < tau2

If tau2-tau1 -> 0 then we have a alpha-function.
and if tau1 -> 0 then we have just single exponential decay.

The factor is evaluated in the
initial block such that an event of weight 1 generates a
peak current of 1.

Because the solution is a sum of exponentials, the
coupled equations can be solved as a pair of independent equations
by the more efficient cnexp method.

Adapted and modified from the original Exp2Syn mod file.
M.Migliore Jun 2003
ENDCOMMENT

NEURON {
	POINT_PROCESS Exp2i
	RANGE tau1, tau2, i, g
	ELECTRODE_CURRENT i

	GLOBAL total
}

UNITS {
	(nA) = (nanoamp)
}

PARAMETER {
	tau1=.1 (ms) <1e-9,1e9>
	tau2 = 10 (ms) <1e-9,1e9>
}

ASSIGNED {
	i (nA)
	g (nA)
	factor
	total (nA)
}

STATE {
	A (nA)
	B (nA)
}

INITIAL {
	LOCAL tp
	total = 0
	if (tau1/tau2 > .9999) {
		tau1 = .9999*tau2
	}
	A = 0
	B = 0
	tp = (tau1*tau2)/(tau2 - tau1) * log(tau2/tau1)
	factor = -exp(-tp/tau1) + exp(-tp/tau2)
	factor = 1/factor
}

BREAKPOINT {
	SOLVE state METHOD cnexp
	g = B - A
	i = g
}

DERIVATIVE state {
	A' = -A/tau1
	B' = -B/tau2
}

NET_RECEIVE(weight (nA)) {
	state_discontinuity(A, A + weight*factor)
	state_discontinuity(B, B + weight*factor)
	total = total+weight
}