Paired turbulence and light effect on calcium increase in Hermissenda (Blackwell 2004)

 Download zip file 
Help downloading and running models
Accession:53427
The sea slug Hermissenda learns to associate light and hair cell stimulation, but not when the stimuli are temporally uncorrelated...These issues were addressed using a multi-compartmental computer model of phototransduction, calcium dynamics, and ionic currents of the Hermissenda photoreceptor...simulations show that a potassium leak channel, which closes with an increase in calcium, is required to produce both the untrained LLD and the enhanced LLD due to the decrease in voltage dependent potassium currents.
Reference:
1 . Blackwell KT (2004) Paired turbulence and light do not produce a supralinear calcium increase in Hermissenda. J Comput Neurosci 17:81-99 [PubMed]
Citations  Citation Browser
Model Information (Click on a link to find other models with that property)
Model Type: Neuron or other electrically excitable cell; Electrogenic pump;
Brain Region(s)/Organism:
Cell Type(s): Hermissenda photoreceptor Type B;
Channel(s): I A; I K,leak; I h; I K,Ca; I Sodium; I Calcium; I Potassium;
Gap Junctions:
Receptor(s): GabaA; GabaB; IP3;
Gene(s):
Transmitter(s): Gaba;
Simulation Environment: Chemesis;
Model Concept(s): Temporal Pattern Generation; Invertebrate; Signaling pathways; Calcium dynamics;
Implementer(s): Blackwell, Avrama [avrama at gmu.edu];
Search NeuronDB for information about:  GabaA; GabaB; IP3; I A; I K,leak; I h; I K,Ca; I Sodium; I Calcium; I Potassium; Gaba;
//cal-ip3-rhab.g CHEMESIS1.0
//repeat below for each axon compartment, and each branch compartment.

function ca_ip3_rhab (path, ncyls, nshells, radius, shellsize, length, ERfactor, quant, concen, unit)
str path
int ncyls, nshells
float radius, length, ERfactor, shellsize
float unit
int quant, concen

int cyl

/**  ip3 with diffusion and degradation ***/
  comp2D {path}/ip3 {radius} {nshells} {shellsize} {length/ncyls} {ncyls} {ip3init} {quant} {unit}
  /* axial diffusion for rhabdomere core (shell s2) */
  difcompcyl {path}/ip3s2 {ncyls} {ip3dif} {unit}
  /* radial diffusion for all rhabdomere cylinders */
  for (cyl=1; cyl<=ncyls; cyl=cyl+1)
	difsphere {path}/ip3s1[{cyl}] {path}/ip3s2[{cyl}] {path}/ip3s1_raddif[{cyl}] {ip3dif} {unit}
  end
  degrad2D {path} /ip3 {nshells} {ncyls} {ip3degrad}

/***  Calcium, Buffers, diffusion in cytosol ****/
  comp2D {path}/Cacyt {radius} {nshells} {shellsize} {length/ncyls} {ncyls} {Cacyt} {concen} 1e-3
  /* axial diffusion for rhabdomere core (shell s2) */
  difcompcyl {path}/Cacyts2 {ncyls} {Cadif} 1e-3
  /* radial diffusion for all rhabdomere cylinders */
  for (cyl=1; cyl<=ncyls; cyl=cyl+1)
	difsphere {path}/Cacyts1[{cyl}] {path}/Cacyts2[{cyl}] {path}/Cacyts1_raddif[{cyl}] {Cadif} 1e-3
  end
  comp2D {path}/bufcyt {radius} {nshells} {shellsize} {length/ncyls} {ncyls} {bufcyt} {concen} 1e-3
  consv2D {path}/bufbndcyt {nshells} {ncyls} {bufcyttot} {radius} {length/ncyls} {shellsize} {concen} 1e-3
  rxncomp2D {path}/Cacyt {path}/bufcyt {path}/bufbndcyt {path}/Cacyt_buf {nshells} {ncyls} {buf_kf} {buf_kb} 1

/***  Calcium, Buffers, diffusion in in ER ****/
  comp2D {path}/CaER {radius} {nshells} {shellsize} {ERfactor*length/ncyls} {ncyls} {CaER} {concen} 1e-3
  comp2D {path}/bufER {radius} {nshells} {shellsize} {ERfactor*length/ncyls} {ncyls} {bufER} {concen} 1e-3
  consv2D {path}/bufbndER {nshells} {ncyls} {bufERtot} {radius} {ERfactor*length/ncyls} {shellsize} {concen} 1e-3
  rxncomp2D {path}/CaER {path}/bufER {path}/bufbndER {path}/CaER_buf {nshells} {ncyls} {buf_kf} {buf_kb} 1

/* Calcium release through ip3 and ryanodine receptors, also serca and leak */
  makecyt2er {path}/Cacyt {path}/ip3 {path}/CaER {maxiicr} {iicrpower} {maxcicr} {cicrpower} {nshells} {ncyls} {serca} {pumppower} 1e-3

  useclock {path}/ip3s#[] 3
  useclock {path}/ip3s2_axdif[] 3
  useclock {path}/ip3s1_raddif[] 3
  useclock {path}/ip3degrad[] 3
  useclock {path}/Cacyts#[] 0
  useclock {path}/bufcyts#[] 0
  useclock {path}/bufbndcyts#[] 0
  useclock {path}/Cacyt_bufs#[] 0
  useclock {path}/Cacyts2_axdif[] 1
  useclock {path}/Cacyts1_raddif[] 1
  useclock {path}/bufERs#[] 1
  useclock {path}/bufbndERs#[] 1
  useclock {path}/CaERs#[] 1
  useclock {path}/CaER_bufs#[] 1
  useclock {path}/Cacyts#[]/x# 1
  useclock {path}/Cacyts#[]/iicrflux 1
  useclock {path}/Cacyts#[]/x00 2
  useclock {path}/Cacyts#[]/x01 2
  useclock {path}/Cacyts#[]/x10 2
  useclock {path}/Cacyts#[]/x11 2
  useclock {path}/Cacyts#[]/ryanflux 2
  useclock {path}/Cacyts#[]/serca 2
  useclock {path}/Cacyts#[]/leak 2

/* fast clocks required for Cacyt due to speed of buffers and low conc.
 * ER can use slower clock because of higher concentration
 * IICR uses clock 1 because high IP3 conc makes time const rather small
 * CICR uses clock 2 because it has lower time const, so changes slowly
 * pumps and serca use clock 1 to accurately update other calcium inputs
 * IP3 conc is accurately computed with slow clock 3. */

end