Kv4.3, Kv1.4 encoded K(+) channel in heart cells (Greenstein et al 2000) (XPP)

 Download zip file 
Help downloading and running models
Accession:62287
A model of canine I:(to1) (the Ca(2+)-independent transient outward current) is formulated as the combination of Kv4.3 and Kv1.4 currents and is incorporated into an existing canine ventricular myocyte model. Simulations demonstrate strong coupling between L-type Ca(2+) current and I:(Kv4.3) and predict a bimodal relationship between I:(Kv4.3) density and APD whereby perturbations in I:(Kv4.3) density may produce either prolongation or shortening of APD, depending on baseline I:(to1) current level. The model files were submitted by: Dr. Sheng-Nan Wu, Dr. Ruey J. Sung, Ya-Jean Wang and Jiun-Shian Wu e-mail: snwu@mail.ncku.edu.tw
Reference:
1 . Greenstein JL, Wu R, Po S, Tomaselli GF, Winslow RL (2000) Role of the calcium-independent transient outward current I(to1) in shaping action potential morphology and duration. Circ Res 87:1026-33 [PubMed]
Citations  Citation Browser
Model Information (Click on a link to find other models with that property)
Model Type: Channel/Receptor;
Brain Region(s)/Organism:
Cell Type(s):
Channel(s): I A;
Gap Junctions:
Receptor(s):
Gene(s): Kv4.3 KCND3; Kv1.4 KCNA4;
Transmitter(s):
Simulation Environment: XPP;
Model Concept(s): Ion Channel Kinetics; Heart disease;
Implementer(s): Wu, Sheng-Nan [snwu at mail.ncku.edu.tw]; Wu, Jiun-Shian [coolneon at gmail.com]; Sung, Ruey J ; Wang, Ya-Jean ;
Search NeuronDB for information about:  I A;
/
hKv4x
readme.html
hKv4x.jpg
hKv4x.ode
                            
# Markovian model for human hKv4.3-2 in heart cells which is responsible for the early phase of cardiac repolarization
# Greenstein JL et al., Role of the calcium-independent tranisent outward current Ito1 in shaping action 
#  potential morphology and duration.  Circ Res 2000;87:1026-1033
# The results are similar to figure 3A of the paper.
# Notably, current traces shown in figure 2A were displaced for the the sake of clarity. 
# Model parameters appears in http://circres.ahajournals.org/cgi/data/87/11/1026/DC1/1.
# The model was implemented by Dr. Sheng-Nan Wu, Dr. Ruey J. Sung, Ya-Jean Wang and Jiun-Shian Wu

# Initial values
init c0=1, c1=0, c2=0, c3=0
init ci0=0, ci1=0, ci2=0, ci3=0
init o=0, oi=0

# Voltage clamp protocols (double-pulse protocol)
par vhold=-80, vtest_1=20, vtest_2=-80
par ton=10, toff=160, toff_r=170
v = vhold+heav(t-ton)*heav(toff-t)*(vtest_1-vhold)+heav(t-toff)*heav(toff_r-t)*(vtest_2-vhold)

# Values of the model parameters
par aa0=0.6347, aa=0.02912, ba0=0.1243, ba=0.0323, ai0=0.05388, ai=4.944e-6, bi0=2.825e-4, bi=4.096e-8
par f1=2.303, f2=16.4, f3=265.833, f4=259.12, b1=1.1653, b2=1.5137, b3=13.072, b4=529.125
par scale=1

# Expressions
Ek=-80.0
par gkbar=0.0075
aaa = aa0*exp(aa*v)
baa = ba0*exp(-ba*v)
aia = ai0*exp(-ai*v)
bia = bi0*exp(bi*v)

# Gating functions
c0' = c1*baa + ci0*aia -c0*(4*aaa + bia)
c1' = c0*4*aaa + c2*2*baa + ci1*aia/b1 - c1*(baa + 3*aaa + f1*bia)
c2' = c1*3*aaa +c3*3*baa + ci2*aia/b2  - c2*(2*baa +2*aaa + f2*bia)
c3' = c2*2*aaa + o*4*baa + ci3*aia/b3 - c3*(3*baa + aaa + f3*bia)
o' = c3*aaa + oi*aia/b4 - o*(4*baa + f4*bia)
ci0' = c0*bia + ci1*baa/f1 - ci0*(aia + b1*4*aaa)
ci1' = c1*f1*bia + ci0* b1*4*aaa +ci2*f1*2*baa/f2 - ci1*(baa/f1 + aia/b1 + b2*3*aaa/b1)
ci2' = c2*f2*bia + ci1*b2*3*aaa/b1 + ci3*f2*3*baa/f3  - ci2*(f1*2**baa/f2 + aia/b2 +b3*2*aaa/b2) 
ci3' = c3*f3*bia + ci2*b3*2*aaa/b2 + oi*f3*4*baa/f4 -ci3*(f2*3*baa/f3 + aia/b3 +b4*aaa/b3)
oi' = o*f4*bia  - oi*f3*4*baa/f4

aux ika = gkbar*(o+oi)*(v-Ek)/scale
aux prop = o+oi

# XPP parameters
@ meth=Euler, dt=.01, total=170
@ xplot=t, yplot=ika, yhi=1.1, ylo=-0.1, xlo=-0, xhi=170, bound=500

done