CA1 pyramidal neuron synaptic integration (Li and Ascoli 2006, 2008)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:71312
The model shows how different input patterns (irregular & asynchronous, irregular & synchronous, regular & asynchronous, regular & synchronous) affect the neuron's output rate when 1000 synapses are distributed in the proximal apical dendritic tree of a hippocampus CA1 pyramidal neuron.
Reference:
1 . Li X, Ascoli GA (2006) Computational simulation of the input-output relationship in hippocampal pyramidal cells. J Comput Neurosci 21:191-209 [PubMed]
2 . Li X, Ascoli GA (2008) Effects of synaptic synchrony on the neuronal input-output relationship. Neural Comput 20:1717-31 [PubMed]
Citations  Citation Browser
Model Information (Click on a link to find other models with that property)
Model Type: Neuron or other electrically excitable cell;
Brain Region(s)/Organism:
Cell Type(s): Hippocampus CA1 pyramidal cell;
Channel(s): I Na,t; I A; I K; I h;
Gap Junctions:
Receptor(s): AMPA; NMDA;
Gene(s):
Transmitter(s):
Simulation Environment: NEURON;
Model Concept(s): Detailed Neuronal Models; Synaptic Integration;
Implementer(s): Li, Xiaoshen [xsli2 at yahoo.com];
Search NeuronDB for information about:  Hippocampus CA1 pyramidal cell; AMPA; NMDA; I Na,t; I A; I K; I h;
/
xiaoshenli
readme.txt
distr.mod *
h.mod *
kadist.mod *
kaprox.mod *
kdrca1.mod *
na3n.mod *
naxn.mod *
c20466.hoc
createNewSyn.hoc
createNewSyn2.hoc
exec.hoc
fig4A.hoc
fixnseg.hoc *
ModelTypeC.hoc
ModelTypeI.hoc
mosinit.hoc
NregNsyn.hoc
Nregsyn.hoc
regNsyn.hoc *
                            
TITLE K-DR channel
: from Klee Ficker and Heinemann
: modified to account for Dax et al.
: M.Migliore 1997

UNITS {
	(mA) = (milliamp)
	(mV) = (millivolt)

}

PARAMETER {
	v (mV)
        ek (mV)		: must be explicitely def. in hoc
	celsius		(degC)
	gkdrbar=.003 (mho/cm2)
        vhalfn=13   (mV)
        a0n=0.02      (/ms)
        zetan=-3    (1)
        gmn=0.7  (1)
	nmax=2  (1)
	q10=1
}


NEURON {
	SUFFIX kdr
	USEION k READ ek WRITE ik
        RANGE gkdr,gkdrbar
	GLOBAL ninf,taun
}

STATE {
	n
}

ASSIGNED {
	ik (mA/cm2)
        ninf
        gkdr
        taun
}

BREAKPOINT {
	SOLVE states METHOD cnexp
	gkdr = gkdrbar*n
	ik = gkdr*(v-ek)

}

INITIAL {
	rates(v)
	n=ninf
}


FUNCTION alpn(v(mV)) {
  alpn = exp(1.e-3*zetan*(v-vhalfn)*9.648e4/(8.315*(273.16+celsius))) 
}

FUNCTION betn(v(mV)) {
  betn = exp(1.e-3*zetan*gmn*(v-vhalfn)*9.648e4/(8.315*(273.16+celsius))) 
}

DERIVATIVE states {     : exact when v held constant; integrates over dt step
        rates(v)
        n' = (ninf - n)/taun
}

PROCEDURE rates(v (mV)) { :callable from hoc
        LOCAL a,qt
        qt=q10^((celsius-24)/10)
        a = alpn(v)
        ninf = 1/(1+a)
        taun = betn(v)/(qt*a0n*(1+a))
	if (taun<nmax) {taun=nmax}
}