Single compartment Dorsal Lateral Medium Spiny Neuron w/ NMDA and AMPA (Biddell and Johnson 2013)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:150556
A biophysical single compartment model of the dorsal lateral striatum medium spiny neuron is presented here. The model is an implementation then adaptation of a previously described model (Mahon et al. 2002). The model has been adapted to include NMDA and AMPA receptor models that have been fit to dorsal lateral striatal neurons. The receptor models allow for excitation by other neuron models.
Reference:
1 . Biddell K, Johnson J (2013) A Biophysical Model of Cortical Glutamate Excitation of Medium Spiny Neurons in the Dorsal Lateral Striatum 56th IEEE Midwest Symposium on Circuits and Systems
Citations  Citation Browser
Model Information (Click on a link to find other models with that property)
Model Type: Neuron or other electrically excitable cell; Connectionist Network;
Brain Region(s)/Organism: Basal ganglia;
Cell Type(s): Neostriatum medium spiny direct pathway GABA cell; Neostriatum spiny neuron;
Channel(s): I Na,p; I K; I K,leak; I A, slow; I_Ks; I Krp; I Na, leak;
Gap Junctions:
Receptor(s): AMPA; NMDA;
Gene(s):
Transmitter(s): Glutamate;
Simulation Environment: NEURON;
Model Concept(s): Detailed Neuronal Models; Short-term Synaptic Plasticity; Parkinson's; Learning; Deep brain stimulation; Olfaction;
Implementer(s): Biddell, Kevin [kevin.biddell at gmail.com];
Search NeuronDB for information about:  Neostriatum medium spiny direct pathway GABA cell; AMPA; NMDA; I Na,p; I K; I K,leak; I A, slow; I_Ks; I Krp; I Na, leak; Glutamate; 
TITLE A fast A-type Potassium current
 
COMMENT
  Used in Role of a Striatal Slowly Inactivating Potassion Current in Short-term 
  Facilitation of Corticostriatal Inputs" A computer Simulation Study" (Mahon et al. 2000)
  Implemented by Kevin M. Biddell kevin.biddell@gmail.com
  7/13/06
NOTE: 1S=1mho Neuron wants the units in mhos not millisiemens, please note the conversion!
ENDCOMMENT
 
UNITS {
        (mA) = (milliamp)
        (mV) = (millivolt)
}
 
NEURON {
 	SUFFIX KAfm
	USEION k WRITE ik
	RANGE gkafmbar, gkafm
}
 
INDEPENDENT {t FROM 0 TO 1 WITH 1 (ms)}
 
PARAMETER {
  	
	ek	= -73	(mV)
	gkafmbar= 0.00009 (mho/cm2) :0.09 mS
	Etemp	= 22 :delord correspondence 11/15/06
	Vsm	= -33.1
	ksm	= 7.5
	tom	= 1
	Vsh	= -70.4
	ksh	= -7.6
	toh	= 25	     
}
 
STATE {
        m h
}
 
ASSIGNED {
        ik (mA/cm2)
 	v  (mV)
	celsius		(degC)
	minf
	hinf
	mtau
	htau
	gkafm
	
}
 
BREAKPOINT {
        SOLVE states METHOD cnexp
        gkafm = gkafmbar*m*h
        ik = gkafm*(v - ek)
  
}
 
UNITSOFF
 
INITIAL {
	rates(v)
	m= minf
	h= hinf
}

DERIVATIVE states {  :Computes states variable m at the current v and dt.
        rates(v)      
       
	m' = ( minf - m ) / mtau
	h' = (hinf - h ) / htau
}
 
PROCEDURE rates(v) {  :Computes rate and other constants at current v. Call once from HOC to initialize inf at resting v.
        LOCAL  q10,tadj  
        q10 = 2.5
	tadj=q10^((celsius-Etemp)/10)
        minf=1/(1+exp(-(v-Vsm)/ksm))
	hinf=1/(1+exp(-(v-Vsh)/ksh))
	mtau=tom/tadj
	htau=toh/tadj	      
}
 
UNITSON