Library of biophysically detailed striatal projection neurons (Lindroos and Hellgren Kotaleski 2020)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:266775
Library of compartmentalized models used to investigate dendritic integration in striatal projection neurons under neuromodulation.
Reference:
1 . Lindroos R, Hellgren Kotaleski J (2020) Predicting complex spikes in striatal projection neurons of the direct pathway following neuromodulation by acetylcholine and dopamine. Eur J Neurosci [PubMed]
Citations  Citation Browser
Model Information (Click on a link to find other models with that property)
Model Type: Neuron or other electrically excitable cell; Synapse;
Brain Region(s)/Organism: Striatum; Hippocampus; Basal ganglia;
Cell Type(s): Neostriatum medium spiny direct pathway GABA cell; Neostriatum medium spiny indirect pathway GABA cell; Striatal projection neuron;
Channel(s): I M; I Potassium;
Gap Junctions:
Receptor(s):
Gene(s):
Transmitter(s): Acetylcholine; Dopamine;
Simulation Environment: NEURON; Python;
Model Concept(s): Active Dendrites; Detailed Neuronal Models; Neuromodulation; Synaptic Plasticity; Activity Patterns; Soma-dendrite cross-talk;
Implementer(s): Lindroos, Robert [robert.lindroos at ki.se]; Filipovic, Marko;
Search NeuronDB for information about:  Neostriatum medium spiny direct pathway GABA cell; Neostriatum medium spiny indirect pathway GABA cell; I M; I Potassium; Acetylcholine; Dopamine;
TITLE Fast delayed rectifier potassium current (Kv3.1/3.2)

NEURON {
    SUFFIX kdr_ms
    USEION k READ ek WRITE ik
    RANGE gbar, gk, ik
}

UNITS {
    (S) = (siemens)
    (mV) = (millivolt)
    (mA) = (milliamp)
}

PARAMETER {
    gbar = 0.0 (S/cm2) 
    q = 1
}

ASSIGNED {
    v (mV)
    ek (mV)
    ik (mA/cm2)
    gk (S/cm2)
    minf
    mtau (ms)
}

STATE { m }

BREAKPOINT {
    SOLVE states METHOD cnexp
    gk = gbar*m
    ik = gk*(v-ek)
}

DERIVATIVE states {
    rates()
    m' = (minf-m)/mtau*q
}

INITIAL {
    rates()
    m = minf
}

PROCEDURE rates() {
    UNITSOFF
    minf = 1/(1+exp((v-(-13))/(-6)))
    mtau = 11.1
    UNITSON
}

COMMENT

Original data and model by Baranauskas et al (1999) [1] for globus
pallidus neurons from young adult rat.  The temperature was not
specified. Potentials were not corrected for the liquid junction
potential, which was estimated to be 1-2 mV.

Kinetics of m^1 type is used as in [2,3]. Room temperature 20-23 C
is assumed.

NEURON implementation by Alexander Kozlov <akozlov@kth.se>.

[1] Baranauskas G, Tkatch T, Surmeier DJ (1999) Delayed rectifier currents
in rat globus pallidus neurons are attributable to Kv2.1 and Kv3.1/3.2
K(+) channels. J Neurosci 19(15):6394-404.

[2] Migliore M, Hoffman DA, Magee JC, Johnston D (1999) Role of an
A-type K+ conductance in the back-propagation of action potentials in the
dendrites of hippocampal pyramidal neurons. J Comput Neurosci 7(1):5-15.

[3] Evans RC, Morera-Herreras T, Cui Y, Du K, Sheehan T, Kotaleski JH,
Venance L, Blackwell KT (2012) The effects of NMDA subunit composition on
calcium influx and spike timing-dependent plasticity in striatal medium
spiny neurons. PLoS Comput Biol 8(4):e1002493.

ENDCOMMENT