Human Cortical L5 Pyramidal Cell (Rich et al. 2021)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:266984
This paper presents a full spiking, biophysically detailed multi-compartment model of a human cortical layer 5 (L5) pyramidal cell, where model development was primarily based on morphological and electrophysiological data from the same neuron. Focus was placed on capturing distinctly human dynamics of the h-channel and led to the articulation of a novel model of this channel's dynamics in humans. This led to an explanation for the surprising lack of subthreshold resonance seen in these cells in the human as opposed to rodent setting.
Reference:
1 . Rich S, Moradi Chameh H, Sekulic V, Valiante TA, Skinner FK (2021) Modeling Reveals Human-Rodent Differences in H-Current Kinetics Influencing Resonance in Cortical Layer 5 Neurons. Cereb Cortex 31:845-872 [PubMed]
Citations  Citation Browser
Model Information (Click on a link to find other models with that property)
Model Type: Neuron or other electrically excitable cell;
Brain Region(s)/Organism: Neocortex;
Cell Type(s): Neocortex layer 5 pyramidal cell; Hodgkin-Huxley neuron;
Channel(s): I h; I M; I Na,p; I Na,t; I K; I Calcium;
Gap Junctions:
Receptor(s):
Gene(s):
Transmitter(s):
Simulation Environment: NEURON;
Model Concept(s): Active Dendrites; Detailed Neuronal Models;
Implementer(s): Rich, Scott [sbrich at umich.edu];
Search NeuronDB for information about:  I Na,p; I Na,t; I K; I M; I h; I Calcium;
/
HumanCellOrganized_v2
readme.html
Ca_HVA.mod *
Ca_LVAst.mod *
CaDynamics_E2.mod *
Ih.mod
Ih_Kole.mod
Ih_me.mod
Ih_original.mod
Ih_shifted.mod
Im.mod *
izap.mod
K_Pst.mod
K_Tst.mod *
Nap_Et2.mod
NaTa_t.mod
NaTs2_t.mod *
SK_E2.mod *
SKv3_1.mod
CurrentClampSetup.hoc
DefineProcs.hoc
init_final.hoc
L5_params_exponential.hoc
ModelSetup.hoc
SimulationParameters_PlusSomeDefinitions.hoc
VoltageAndCurrentTrace.ses
VoltageAndcurrentTrace_noise_full.ses
VoltageAndcurrentTrace_zap.ses
VoltageAndcurrentTrace_zap_laptop.ses
                            
: $Id: izap.mod,v 1.4 2015/05/28 02:42:00 ted Exp ted $

COMMENT
izap.mod

Delivers an oscillating current that starts at t = del >= 0.
The frequency of the oscillation increases linearly with time
from f0 at t == del to f1 at t == del + dur, 
where both del and dur are > 0.

Uses event delivery system to ensure compatibility with adaptive integration.

Original implementation 12/4/2008 NTC
ENDCOMMENT

NEURON {
  POINT_PROCESS Izap
  RANGE del, dur, f0, f1, amp, f, i
  ELECTRODE_CURRENT i
}

UNITS {
  (nA) = (nanoamp)
  PI = (pi) (1)
}

PARAMETER {
  del (ms)
  dur (ms)
  f0 (1/s)  : frequency is in Hz
  f1 (1/s)
  amp (nA)
}

ASSIGNED {
  f (1/s)
  i (nA)
  on (1)
}

INITIAL {
  f = 0
  i = 0
  on = 0

  if (del<0) { del=0 }
  if (dur<0) { dur=0 }
  if (f0<=0) { f0=0 (1/s) }
  if (f1<=0) { f1=0 (1/s) }

  : do nothing if dur == 0
  if (dur>0) {
    net_send(del, 1)  : to turn it on and start frequency ramp
  }
}

COMMENT
The angular velocity in radians/sec is w = 2*PI*f, 
where f is the instantaneous frequency in Hz.

Assume for the moment that the frequency ramp starts at t = 0.
f = f0 + (f1 - f0)*t/dur

Then the angular displacement is
theta = 2*PI * ( f0*t + (f1 - f0)*(t^2)/(2*dur) ) 
      = 2*PI * t * (f0 + (f1 - f0)*t/(2*dur))
But the ramp starts at t = del, so just substitute t-del for every occurrence of t
in the formula for theta.
ENDCOMMENT

BREAKPOINT {
  if (on==0) {
    f = 0
    i = 0
  } else {
    f = f0 + (f1 - f0)*(t-del)/dur
    i = amp * sin( 2*PI * (t-del) * (f0 + (f1 - f0)*(t-del)/(2*dur)) * (0.001) )
  }
}

NET_RECEIVE (w) {
  : respond only to self-events with flag > 0
  if (flag == 1) {
    if (on==0) {
      on = 1  : turn it on
      net_send(dur, 1)  : to stop frequency ramp, freezing frequency at f1
    } else {
      on = 0  : turn it off
    }
  }
}