Inferring connection proximity in electrically coupled networks (Cali et al. 2007)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:94321
In order to explore electrical coupling in the nervous system and its network-level organization, it is imperative to map the electrical synaptic microcircuits, in analogy with in vitro studies on monosynaptic and disynaptic chemical coupling. However, walking from cell to cell over large distances with a glass pipette is challenging, and microinjection of (fluorescent) dyes diffusing through gap-junctions remains so far the only method available to decipher such microcircuits even though technical limitations exist. Based on circuit theory, we derived analytical descriptions of the AC electrical coupling in networks of isopotential cells. We then proposed an operative electrophysiological protocol to distinguish between direct electrical connections and connections involving one or more intermediate cells. This method allows inferring the number of intermediate cells, generalizing the conventional coupling coefficient, which provides limited information. We provide here some analysis and simulation scripts that used to test our method through computer simulations, in vitro recordings, theoretical and numerical methods. Key words: Gap-Junctions; Electrical Coupling; Networks; ZAP current; Impedance.
Reference:
1 . Calì C, Berger TK, Pignatelli M, Carleton A, Markram H, Giugliano M (2008) Inferring connection proximity in networks of electrically coupled cells by subthreshold frequency response analysis. J Comput Neurosci 24:330-45 [PubMed]
Citations  Citation Browser
Model Information (Click on a link to find other models with that property)
Model Type: Neuron or other electrically excitable cell; Glia;
Brain Region(s)/Organism:
Cell Type(s):
Channel(s): I Na,t; I K; I Potassium;
Gap Junctions: Gap junctions;
Receptor(s):
Gene(s):
Transmitter(s):
Simulation Environment: NEURON; MATLAB; PSpice; Sspice Symbolic SPICE;
Model Concept(s): Methods;
Implementer(s): Giugliano, Michele [mgiugliano at gmail.com];
Search NeuronDB for information about:  I Na,t; I K; I Potassium; 
TITLE ZAP current

COMMENT
-----------------------------------------------------------------------------

    ZAP current model for membrane impedance analysis
    ==================================================

 IMPLEMENTATION

  This mechanism is implemented as a nonspecific current defined as a
  point process, mimicking a current-clamp stimulation protocol, injecting
  a sinusoidally oscillating waveform I(t), with instantaneous frequency
  changing in time (i.e. chirp or ZAP waveform).
  
  I(t) = A * sin (2 pi (f(t) - Fstart) ( t - ttstart) / 2 )
  
  f(t) = Fstart + (Fstop - Fstart) * ( t - ttstart) / ( ttstop - ttstart)
  A(t) = Astart + (Astop - Astart) * ( t - ttstart) / ( ttstop - ttstart)
 
  Note: Although counterintuitive at a first glance, the above expression of I(t)
        indeed correspond to a sinusoid starting with the initial frequency Fstart
        that is linearly increasing up to Fstop while the time goes from ttstart to
        ttstop.

  Note: 
  Since this is an electrode current, positive values of i depolarize the cell and in the
  presence of the extracellular mechanism there will be a change in vext since i is not a
  transmembrane current but a current injected directly to the inside of the cell.
 
  Refer to: Cali' et al. (2007)

 PARAMETERS

  This mechanism takes the following parameters:

  Ioff      = 0. (nA) : initial current offset.
  Astart    = 0. (nA) : initial value of the (linearly changing) amplitude of the ZAP current.
  Astop     = 0. (nA) : final value of the (linearly changing) amplitude of the ZAP current.
  ttstart   = 0. (ms) : starting time of the stimulation.
  ttstop    = 0. (ms) : final time of the stimulation.
  Fstart    = 0. (Hz) : initial value of the (linearly changing) frequency of the ZAP current.
  Fstop     = 0. (Hz) : final value of the (linearly changing) frequency of the ZAP current.

 Written by M. Giugliano and C. Cali', Brain Mind Institute, EPFL, March 2006

-----------------------------------------------------------------------------
ENDCOMMENT


INDEPENDENT {t FROM 0 TO 1 WITH 1 (ms)}

NEURON {
    POINT_PROCESS Izap
    RANGE Astart, Astop, ttstart, ttstop, Fstart, Fstop, Ioff
    NONSPECIFIC_CURRENT i
}

UNITS {
    (nA) = (nanoamp) 
    (mV) = (millivolt)
}

PARAMETER {
  Ioff      = 0. (nA) : initial current offset
  Astart    = 0. (nA) : initial value of the (linearly changing) amplitude of the ZAP current
  Astop     = 0. (nA) : final value of the (linearly changing) amplitude of the ZAP current
  ttstart   = 0. (ms) : starting time of the stimulation..
  ttstop    = 0. (ms) : final time of the stimulation..
  Fstart    = 0. (Hz) : initial value of the (linearly changing) frequency of the ZAP current
  Fstop     = 0. (Hz) : final value of the (linearly changing) frequency of the ZAP current
}

ASSIGNED {
    i     (nA)        : fluctuating current
}


BREAKPOINT {
    if ((t < ttstart) || (t > ttstop)) {  i = - Ioff }
    else { 
    i    = - (Ioff + (  ((Astart*(ttstop-t)/(ttstop-ttstart)) + ((t-ttstart)/(ttstop-ttstart)) * Astop)) * sin(  (0.0062831853071795866 * Fstart + ((t-ttstart)/(ttstop-ttstart)) * 0.5 * 0.0062831853071795866 * (Fstop - Fstart) ) * (t-ttstart)))        
    }
}