Current Dipole in Laminar Neocortex (Lee et al. 2013)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:151685
Laminar neocortical model in NEURON/Python, adapted from Jones et al 2009. https://bitbucket.org/jonescompneurolab/corticaldipole
Reference:
1 . Lee S, Jones SR (2013) Distinguishing mechanisms of gamma frequency oscillations in human current source signals using a computational model of a laminar neocortical network. Front Hum Neurosci 7:869 [PubMed]
Citations  Citation Browser
Model Information (Click on a link to find other models with that property)
Model Type: Realistic Network;
Brain Region(s)/Organism: Neocortex;
Cell Type(s):
Channel(s): I Na,t; I K; I M; I Calcium; I h; I T low threshold; I K,Ca;
Gap Junctions:
Receptor(s): GabaA; GabaB; AMPA; NMDA;
Gene(s):
Transmitter(s):
Simulation Environment: NEURON (web link to model); Python (web link to model); NEURON; Python;
Model Concept(s): Magnetoencephalography; Temporal Pattern Generation; Activity Patterns; Gamma oscillations; Oscillations; Current Dipole; Touch;
Implementer(s): Lee, Shane [shane_lee at brown.edu];
Search NeuronDB for information about:  GabaA; GabaB; AMPA; NMDA; I Na,t; I T low threshold; I K; I M; I h; I K,Ca; I Calcium;
TITLE Anomalous rectifier current

COMMENT
    RD Traub, J Neurophysiol 89:909-921, 2003
    Implemented by Maciej Lazarewicz 2003 (mlazarew@seas.upenn.edu)
ENDCOMMENT

INDEPENDENT { t FROM 0 TO 1 WITH 1 (ms) }

UNITS {
    (mV) = (millivolt)
    (mA) = (milliamp)
}

NEURON {
    SUFFIX ar
    NONSPECIFIC_CURRENT i
    RANGE gbar, i
}

PARAMETER {
    gbar = 0.0  (mho/cm2)
    v           (mV)
    erev = -35  (mV)
}

ASSIGNED {
    i           (mA/cm2)
    minf        (1)
    mtau        (ms)
}

STATE {
    m
}

BREAKPOINT {
    SOLVE states METHOD cnexp
    i = gbar * m * ( v - erev )
}

INITIAL {
    settables(v)
    m = minf
    m = 0.25
}

DERIVATIVE states {
    settables(v)
    m' = ( minf - m ) / mtau
}

UNITSOFF
PROCEDURE settables(v) {
    TABLE minf, mtau FROM -120 TO 40 WITH 641
    minf  = 1 / ( 1 + exp( ( v + 75 ) / 5.5 ) )
    mtau = 1 / ( exp( -14.6 - 0.086 * v ) + exp( -1.87 + 0.07 * v ) )
}
UNITSON