Gamma oscillations in hippocampal interneuron networks (Wang, Buzsaki 1996)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:26997
The authors investigated the hypothesis that 20-80Hz neuronal (gamma) oscillations can emerge in sparsely connected network models of GABAergic fast-spiking interneurons. They explore model NN synchronization and compare their results to anatomical and electrophysiological data from hippocampal fast spiking interneurons.
Reference:
1 . Wang XJ, Buzsáki G (1996) Gamma oscillation by synaptic inhibition in a hippocampal interneuronal network model. J Neurosci 16:6402-13 [PubMed]
Citations  Citation Browser
Model Information (Click on a link to find other models with that property)
Model Type: Realistic Network;
Brain Region(s)/Organism: Hippocampus;
Cell Type(s): Abstract Wang-Buzsaki neuron;
Channel(s): I Na,t; I K;
Gap Junctions:
Receptor(s): GabaA;
Gene(s):
Transmitter(s):
Simulation Environment: NEURON;
Model Concept(s): Activity Patterns; Oscillations; Synchronization;
Implementer(s): Hines, Michael [Michael.Hines at Yale.edu]; Lytton, William [bill.lytton at downstate.edu];
Search NeuronDB for information about:  GabaA; I Na,t; I K;
: $Id: fvpre.mod,v 1.10 2003/07/29 23:37:22 billl Exp $
COMMENT
synapse taken from Wang, X.-J. and Buzsaki G. (1996) Gamma oscillations by
synaptic inhibition in a hippocampal interneuronal network.  
J. Neurosci. 16, 6402-6413.
ENDCOMMENT
					       
NEURON {
  POINT_PROCESS fvpre
  RANGE gmax, g, i
  GLOBAL alpha,beta,thetasyn,e
  NONSPECIFIC_CURRENT i
  POINTER vpre
}

UNITS {
  (nA) = (nanoamp)
  (mV) = (millivolt)
  (uS) = (microsiemens)
}

PARAMETER {
  gmax=1e-4 (uS)
  alpha=12 (/ms)
  beta=0.1 (/ms)
  e=-75	   (mV)
  thetasyn=0 (mV) 
}

ASSIGNED { vpre (mV) v (mV) i (nA)  g (uS)}

STATE { s }

INITIAL {
  s =  alpha*F(vpre)/(alpha*F(vpre)+beta)
}

BREAKPOINT {
  SOLVE state METHOD cnexp
  g = gmax * s
  i = g*(v - e)
}

DERIVATIVE state {
  s' = alpha*F(vpre)*(1-s) - beta*s
}

FUNCTION F (v1 (mV)) {
  F = 1/(1 + exp(-(v1-thetasyn)/2))
}