Factors contribution to GDP-induced [Cl-]i transients (Lombardi et al 2019)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:253369
This models are used to evaluate which factors influence the GDP (giant depolarizing potential) induced [Cl-]I transients based on a initial model of P. Jedlicka
Reference:
1 . Lombardi A, Jedlicka P, Luhmann HJ, Kilb W (2019) Interactions Between Membrane Resistance, GABA-A Receptor Properties, Bicarbonate Dynamics and Cl-Transport Shape Activity-Dependent Changes of Intracellular Cl- Concentration Int J of Mol Sci [PubMed]
Citations  Citation Browser
Model Information (Click on a link to find other models with that property)
Model Type: Neuron or other electrically excitable cell; Dendrite; Synapse;
Brain Region(s)/Organism: Mouse; Hippocampus;
Cell Type(s): Hippocampus CA3 pyramidal GLU cell;
Channel(s):
Gap Junctions:
Receptor(s): GabaA;
Gene(s):
Transmitter(s): Gaba;
Simulation Environment: NEURON;
Model Concept(s): Synaptic Plasticity;
Implementer(s):
Search NeuronDB for information about:  Hippocampus CA3 pyramidal GLU cell; GabaA; Gaba;
/
LombardiEtAl2019
Isolated_Dendrite_pGABA _HCO3__Fig5u7
cldif_CA3.mod *
cldif_CA3_NKCC1_HCO3.mod *
gabaA_Cl_HCO3.mod *
VDpas.mod *
vecevent.mod *
cell_isolated_dendrite.hoc *
GABA-Stim_PSC_isolated_dendrite_gGABA-0.000789_Var_pGABA.hoc *
GABA-Stim_PSC_isolated_dendrite_gGABA-0.0789_pGABA-018_Cli-30-var_tauHCO3_spatiotemp.hoc
GABA-Stim_PSC_isolated_dendrite_gGABA-0.0789_var-tauHCO3_Var-pGABA.hoc
GABA-Stim_PSC_isolated_dendrite_tauHCO3-10min_gGABA-0.00789_Var_pGABA.hoc
GABA-Stim_PSC_isolated_dendrite_tauHCO3-10min_gGABA-0.0789_Var_pGABA .hoc
GABA-Stim_PSC_isolated_dendrite_tauHCO3-10min_Var-gGABA_Var-pGABA.hoc
GABA-Stim_PSC_isolated_dendrite_tauHCO3-1s_gGABA-0.00789_Var_pGABA.hoc
GABA-Stim_PSC_isolated_dendrite_tauHCO3-1s_gGABA-0.0789_Var_pGABA.hoc
GABA-Stim_PSC_isolated_dendrite_tauHCO3-5ms_gGABA-0.00789_Var_pGABA.hoc
GABA-Stim_PSC_isolated_dendrite_tauHCO3-5ms_gGABA-0.0789_Var_pGABA.hoc
GABA-Stim_PSC_isolated_dendrite_Var_pGABA.hoc *
GABA-Stim_PSC_isolated_dendrite_woCl_gGABA-0.000789_Var_pGABA.hoc
GABA-Stim_PSC_isolated_dendrite_woCl_gGABA-0.00789_Var_pGABA.hoc
GABA-Stim_PSC_isolated_dendrite_woCl_gGABA-0.0789_Var_pGABA.hoc
GABA-Stim_PSC_isolated_dendrite_woHCO3_gGABA-0.000789_Var_pGABA.hoc
GABA-Stim_PSC_isolated_dendrite_woHCO3_gGABA-0.00789_Var_pGABA.hoc
GABA-Stim_PSC_isolated_dendrite_woHCO3_Var-gGABA_Var-pGABA.hoc
init_Cldif_isolated_dendrite.hoc *
init_Cldif_woHCO3_isolated_dendrite.hoc
Isolated_Dendrite.ses *
start_GABA-Stim_PSC_isolated_dendrite_gGABA-0.0789_pGABA-018_Cli-30-var_tauHCO3_spatiotemp.hoc
start_GABA-Stim_PSC_isolated_dendrite_gGABA-0.0789_var-tauHCO3_Var-pGABA.hoc
start_GABA-Stim_PSC_isolated_dendrite_tauHCO3-10min__Var_pGABA.hoc
start_GABA-Stim_PSC_isolated_dendrite_tauHCO3-10min_Var-gGABA_Var-pGABA.hoc
start_GABA-Stim_PSC_isolated_dendrite_tauHCO3-1s__Var_pGABA.hoc
start_GABA-Stim_PSC_isolated_dendrite_tauHCO3-5ms__Var_pGABA.hoc
start_GABA-Stim_PSC_isolated_dendrite_woCl_gGABA-0.0789_Var_pGABA.hoc
start_GABA-Stim_PSC_isolated_dendrite_woCl_Var_pGABA.hoc
start_GABA-Stim_PSC_isolated_dendrite_woHCO3_Var_pGABA.hoc
start_GABA-Stim_PSC_isolated_dendrite_woHCO3_Var-gGABA_Var-pGABA.hoc
                            
COMMENT

Chloride accumulation and diffusion with decay (time constant tau) to resting level cli0.
The decay approximates a reversible chloride pump with first order kinetics.
To eliminate the chloride pump, just use this hoc statement
To make the time constant effectively "infinite".
tau and the resting level are both RANGE variables

Diffusion model is modified from Ca diffusion model in Hines & Carnevale: 
Expanding NEURON with NMODL, Neural Computation 12: 839-851, 2000 (Example 8)

ENDCOMMENT

NEURON {
	SUFFIX cldif_CA3
	USEION cl READ icl WRITE cli VALENCE -1
	USEION hco3 READ hco3i, hco3o VALENCE -1
	GLOBAL vrat		:vrat must be GLOBAL
	RANGE tau, cli0, clo0, egaba, delta_egaba, init_egaba, ehco3_help, ecl_help
}

DEFINE Nannuli 4

UNITS {
	(molar) = (1/liter)
	(mM) = (millimolar)
	(um) = (micron)
	(mA) = (milliamp)
	(mV)    = (millivolt)
	FARADAY = (faraday) (10000 coulomb)
	PI = (pi) (1)
	F = (faraday) (coulombs)
	R = (k-mole)  (joule/degC)
}

PARAMETER {
	DCl = 2 (um2/ms) : Kuner & Augustine, Neuron 27: 447
	tau = 174000 (ms) : According to our results
	cli0 = 8 (mM)
	clo0 = 133.5 (mM)
	hco3i0 = 16	(mM)
	hco3o0 = 26	(mM)
	P_help = 0.18
	celsius = 37    (degC)

}

ASSIGNED {
	diam 	(um)
	icl 	(mA/cm2)
	cli 	(mM)
	hco3i	(mM)
	hco3o	(mM)
	vrat[Nannuli]	: numeric value of vrat[i] equals the volume
			: of annulus i of a 1um diameter cylinder
			: multiply by diam^2 to get volume per um length
	egaba 	(mV)
	ehco3_help 	(mV)
	ecl_help	(mV)
	init_egaba  (mV)
	delta_egaba (mV)
}

STATE {
	: cl[0] is equivalent to cli
	: cl[] are very small, so specify absolute tolerance
	cl[Nannuli]	(mM) <1e-10>
}


BREAKPOINT { 
		SOLVE state METHOD sparse
		ecl_help = log(cli/clo0)*(1000)*(celsius + 273.15)*R/F
		egaba = P_help*ehco3_help + (1-P_help)*ecl_help
		delta_egaba = egaba - init_egaba
}

LOCAL factors_done

INITIAL {
	if (factors_done == 0) {  	: flag becomes 1 in the first segment	
		factors_done = 1	: all subsequent segments will have
		factors()		: vrat = 0 unless vrat is GLOBAL
	}
	cli = cli0
	hco3i = hco3i0
	hco3o = hco3o0
	FROM i=0 TO Nannuli-1 {
		cl[i] = cli
	}
	ehco3_help = log(hco3i/hco3o)*(1000)*(celsius + 273.15)*R/F
	ecl_help = log(cli/clo0)*(1000)*(celsius + 273.15)*R/F
	egaba = P_help*ehco3_help + (1-P_help)*ecl_help
	init_egaba = egaba
	delta_egaba = egaba - init_egaba 
}

LOCAL frat[Nannuli]	: scales the rate constants for model geometry

PROCEDURE factors() {
	LOCAL r, dr2
	r = 1/2			: starts at edge (half diam), diam = 1, length = 1
	dr2 = r/(Nannuli-1)/2	: full thickness of outermost annulus,
				: half thickness of all other annuli
	vrat[0] = 0
	frat[0] = 2*r		: = diam
	FROM i=0 TO Nannuli-2 {
		vrat[i] = vrat[i] + PI*(r-dr2/2)*2*dr2	: interior half
		r = r - dr2
		frat[i+1] = 2*PI*r/(2*dr2)	: outer radius of annulus Ai+1/delta_r=2PI*r*1/delta_r
						: div by distance between centers 
		r = r - dr2
		vrat[i+1] = PI*(r+dr2/2)*2*dr2	: outer half of annulus
	}
}

KINETIC state {
	COMPARTMENT i, diam*diam*vrat[i] {cl}
	LONGITUDINAL_DIFFUSION i, DCl*diam*diam*vrat[i] {cl}
	~ cl[0] << ((icl*PI*diam/FARADAY) + (diam*diam*vrat[0]*(cli0 - cl[0])/tau)) : icl is Cl- influx 
	FROM i=0 TO Nannuli-2 {
		~ cl[i] <-> cl[i+1]	(DCl*frat[i+1], DCl*frat[i+1])
	}
	cli = cl[0]
}