Circadian rhythmicity shapes astrocyte morphology and neuronal function in CA1 (McCauley et al 2020)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:257027
Most animal species operate according to a 24-hour period set by the suprachiasmatic nucleus (SCN) of the hypothalamus. The rhythmic activity of the SCN modulates hippocampal-dependent memory, but the molecular and cellular mechanisms that account for this effect remain largely unknown. In McCauley et al. 2020 [1], we identify cell-type specific structural and functional changes that occur with circadian rhythmicity in neurons and astrocytes in hippocampal area CA1. Pyramidal neurons change the surface expression of NMDA receptors. Astrocytes change their proximity clustered excitatory synaptic inputs, ultimately shaping hippocampal-dependent learning in vivo. We identify to synapses. Together, these phenomena alter glutamate clearance, receptor activation and integration of temporally corticosterone as a key contributor to changes in synaptic strength. These findings highlight important mechanisms through which neurons and astrocytes modify the molecular composition and structure of the synaptic environment, contribute to the local storage of information in the hippocampus and alter the temporal dynamics of cognitive processing. [1] "Circadian modulation of neurons and astrocytes controls synaptic plasticity in hippocampal area CA1" by J.P. McCauley, M.A. Petroccione, L.Y. D’Brant, G.C. Todd, N. Affinnih, J.J. Wisnoski, S. Zahid, S. Shree, A.A. Sousa, R.M. De Guzman, R. Migliore, A. Brazhe, R.D. Leapman, A. Khmaladze, A. Semyanov, D.G. Zuloaga, M. Migliore and A. Scimemi. Cell Reports (2020), https://doi.org/10.1016/j.celrep.2020.108255
Reference:
1 . McCauley JP, Petroccione MA, D'Brant LY, Todd GC, Affinnih N, Wisnoski JJ, Zahid S, Shree S, Sousa AA, De Guzman RM, Migliore R, Brazhe A, Leapman RD, Khmaladze A, Semyanov A, Zuloaga DG, Migliore M, Scimemi A (2020) Circadian Modulation of Neurons and Astrocytes Controls Synaptic Plasticity in Hippocampal Area CA1. Cell Rep 33:108255 [PubMed]
Citations  Citation Browser
Model Information (Click on a link to find other models with that property)
Model Type: Synapse; Channel/Receptor;
Brain Region(s)/Organism: Hippocampus;
Cell Type(s): Hippocampus CA1 pyramidal GLU cell; Astrocyte;
Channel(s): I A; I h; I M; I K; I K,Ca; Ca pump; I Calcium; I CAN; I Na,t;
Gap Junctions:
Receptor(s): AMPA; NMDA;
Gene(s):
Transmitter(s): Glutamate;
Simulation Environment: NEURON;
Model Concept(s): Synaptic Integration; Synaptic Plasticity; Detailed Neuronal Models;
Implementer(s): Migliore, Rosanna [rosanna.migliore at cnr.it]; Migliore, Michele [Michele.Migliore at Yale.edu];
Search NeuronDB for information about:  Hippocampus CA1 pyramidal GLU cell; AMPA; NMDA; I Na,t; I A; I K; I M; I h; I K,Ca; I CAN; I Calcium; Ca pump; Glutamate;
/
modelDB-Migliore-Scimemi-2020
morph
readme_file
readme.htm
cacumm.mod *
cagk.mod *
cal2.mod *
can2.mod *
cat.mod *
h.mod *
kadist.mod *
kaprox.mod *
kca.mod *
kdrca1.mod *
kmb.mod *
ltpltd.mod *
naxn.mod *
netstims.mod *
nmdanet.mod
tmgsynday.mod
cell_seed6_0_mouse1-AS.hoc
fig6C.hoc
mosinit.hoc
sim-day.ses
                            
TITLE Slow Ca-dependent potassium current
                            :
                            :   Ca++ dependent K+ current IC responsible for slow AHP
                            :   Differential equations
                            :
                            :   Model based on a first order kinetic scheme
                            :
                            :       + n cai <->     (alpha,beta)
                            :
                            :   Following this model, the activation fct will be half-activated at 
                            :   a concentration of Cai = (beta/alpha)^(1/n) = cac (parameter)
                            :
                            :   The mod file is here written for the case n=2 (2 binding sites)
                            :   ---------------------------------------------
                            :
                            :   This current models the "slow" IK[Ca] (IAHP): 
                            :      - potassium current
                            :      - activated by intracellular calcium
                            :      - NOT voltage dependent
                            :
                            :   A minimal value for the time constant has been added
                            :
                            :   Ref: Destexhe et al., J. Neurophysiology 72: 803-818, 1994.
                            :   See also: http://www.cnl.salk.edu/~alain , http://cns.fmed.ulaval.ca
                            :   modifications by Yiota Poirazi 2001 (poirazi@LNC.usc.edu)
			    :   taumin = 0.5 ms instead of 0.1 ms	

                            NEURON {
                                    SUFFIX kca
                                    USEION k READ ek WRITE ik
                                    USEION ca READ cai
                                    RANGE gk, gbar, m_inf, tau_m,ik
                                    GLOBAL beta, cac
                            }


                            UNITS {
                                    (mA) = (milliamp)
                                    (mV) = (millivolt)
                                    (molar) = (1/liter)
                                    (mM) = (millimolar)
                            }


                            PARAMETER {
                                    v               (mV)
                                    celsius = 36    (degC)
                                    ek      = -80   (mV)
                                    cai     = 2.4e-5 (mM)           : initial [Ca]i
                                    gbar    = 0.01   (mho/cm2)
                                    beta    = 0.03   (1/ms)          : backward rate constant
                                    cac     = 0.00035  (mM)            : middle point of activation fct
       				    taumin  = 0.5    (ms)            : minimal value of the time cst
                                    gk
                                  }


                            STATE {m}        : activation variable to be solved in the DEs       

                            ASSIGNED {       : parameters needed to solve DE 
                                    ik      (mA/cm2)
                                    m_inf
                                    tau_m   (ms)
                                    tadj
                            }
                            BREAKPOINT { 
                                    SOLVE states METHOD derivimplicit
                                    gk = gbar*m*m*m     : maximum channel conductance
                                    ik = gk*(v - ek)    : potassium current induced by this channel
                            }

                            DERIVATIVE states { 
                                    evaluate_fct(v,cai)
                                    m' = (m_inf - m) / tau_m
                            }

                            UNITSOFF
                            INITIAL {
                            :
                            :  activation kinetics are assumed to be at 22 deg. C
                            :  Q10 is assumed to be 3
                            :
                                    tadj = 3 ^ ((celsius-22.0)/10) : temperature-dependent adjastment factor
                                    evaluate_fct(v,cai)
                                    m = m_inf
                            }

                            PROCEDURE evaluate_fct(v(mV),cai(mM)) {  LOCAL car
                                    car = (cai/cac)^4
                                    m_inf = car / ( 1 + car )      : activation steady state value
                                    tau_m =  1 / beta / (1 + car) / tadj
                                    if(tau_m < taumin) { tau_m = taumin }   : activation min value of time cst
                            }
                            UNITSON