NN activity impact on neocortical pyr. neurons integrative properties in vivo (Destexhe & Pare 1999)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:262115
"During wakefulness, neocortical neurons are subjected to an intense synaptic bombardment. To assess the consequences of this background activity for the integrative properties of pyramidal neurons, we constrained biophysical models with in vivo intracellular data obtained in anesthetized cats during periods of intense network activity similar to that observed in the waking state. In pyramidal cells of the parietal cortex (area 5–7), synaptic activity was responsible for an approximately fivefold decrease in input resistance (Rin), a more depolarized membrane potential (Vm), and a marked increase in the amplitude of Vm fluctuations, as determined by comparing the same cells before and after microperfusion of tetrodotoxin (TTX). ..."
Reference:
1 . Destexhe A, Paré D (1999) Impact of network activity on the integrative properties of neocortical pyramidal neurons in vivo. J Neurophysiol 81:1531-47 [PubMed]
Citations  Citation Browser
Model Information (Click on a link to find other models with that property)
Model Type: Neuron or other electrically excitable cell;
Brain Region(s)/Organism: Neocortex;
Cell Type(s): Neocortex L2/3 pyramidal GLU cell; Neocortex L5/6 pyramidal GLU cell;
Channel(s): I Na,t; I K; I M;
Gap Junctions:
Receptor(s):
Gene(s):
Transmitter(s):
Simulation Environment: NEURON;
Model Concept(s): Synaptic Integration;
Implementer(s): Destexhe, Alain [Destexhe at iaf.cnrs-gif.fr];
Search NeuronDB for information about:  Neocortex L5/6 pyramidal GLU cell; Neocortex L2/3 pyramidal GLU cell; I Na,t; I K; I M;
/
demo_destexhe-pare-1999
README.html
corrgen8.mod
corrgen8.mod.windows
IKd_traub.mod
IM_zach.mod
INa_traub_shifted.mod
multiAMPA.mod
multiGABAa.mod
multiNMDA.mod
add_just_axon.oc
demo_bombardment_active_coarse.oc
demo_bombardment_active_precise.oc
demo_bombardment_passive_coarse.oc
demo_bombardment_passve_precise.oc
Electrode.oc
init.hoc
layer6.geo
localize_currents_M.oc
localize_synapses_corrgen_mul.oc
mosinit.hoc *
screenshot.png
                            
//------------------------------------------------------------------------
//
//  Procedures to localize mechanisms in dendritic compartments
//
//  Simple version with minimal set of currents:
//	- potassium currents: IKd Traub, IM Zach
//	- INa current: Traub
//	- IKd in dendrites
//
//  Procedures to localize currents as a function of distance
//  (use the path distance function of NEURON)
//
//------------------------------------------------------------------------

strdef sect

soma distance(0,0.5)	// initialize path distances to center of soma

//
//  Procedures to insert mechanisms
//
proc insert_ina() {			// sodium channels
	   insert inaT
	   ena = 50
	   vtraub_inaT = -63			// threshold of -55
	   gnabar_inaT = 3			// zach init segment
	   gnabar_inaT = 20e-4			// zach dendrites & soma
}
proc insert_ikd() {			// delayed-rectifier	
	   insert ikdT
	   ek = -90
	   vtraub_ikdT = -63			// threshold of IKd
	   gkbar_ikdT = 2000e-4			// zach init segment
	   gkbar_ikdT = 200e-4			// zach soma
}
proc insert_im() {			// ca-dependent K+ current
	   insert imZ
	   ek = -90
	   gkbar_imZ = 3e-4			// zach dendrites & soma
}





//
//  Procedure to insert currents in soma, dendrites and axon
//
proc insert_currents() { 

   forsec "dend" {	// dendrites
	insert_ina()		// sodium channels
	insert_im()		// M-channels
	insert_ikd()		// delayed rectifier
   }

   soma {		// soma
	insert_ina()		// sodium channels
	insert_im()		// M-channels
	insert_ikd()		// delayed rectifier
   }

   axon {		// axon
	insert_ina()		// sodium channels
	insert_ikd()		// delayed rectifier
   }
}



//
//  Procedure to set conductances in the soma
//  arguments: 1=gNa, 2=gKd, 3=gM
//
proc set_soma() {

   print " "
   print "Set somatic currents:"
   print " "
   print " Sodium cnannels:  ",$1
   print " IKd channels:     ",$2
   print " IM channels:      ",$3
   print " "

   soma {
	gnabar_inaT = $1	// sodium channels
	gkbar_imZ = $3		// M-channels
	gkbar_ikdT = $2		// delayed rectifier
	if(DEBUG) {
	   sectionname(sect)
	   print "INa, IKd, IM inserted in ",sect
	}
   }
}



//
//  Procedure to set conductances in the axon
//  arguments: 1=gNa, 2=gKd
//
proc set_axon() {

   print " "
   print "Set axonal currents:"
   print " "
   print " Sodium cnannels:  ",$1
   print " IKd channels:     ",$2
   print " "

   axon {
	gnabar_inaT = $1	// sodium channels
	gkbar_ikdT = $2		// delayed rectifier
	if(DEBUG) {
	   sectionname(sect)
	   print "INa, IKd inserted in ",sect
	}
   }
}




//
//  Procedure to set conductances in the dendrites
//  arguments: 1=gNa, 2=gKd, 3=gM
//
proc set_dendrites() {

   print " "
   print "Set dendritic currents:"
   print " "
   print " Sodium cnannels:  ",$1
   print " IKd channels:     ",$2
   print " IM channels:      ",$3
   print " "

   forsec "dend" {
	gnabar_inaT = $1	// sodium channels
	gkbar_imZ = $3		// M-channels
	gkbar_ikdT = $2		// delayed rectifier
	if(DEBUG) {
	   sectionname(sect)
	   print "INa, IKd, IM inserted in ",sect
	}
   }

   forsec "myelin" {
	gnabar_inaT = $1	// sodium channels in myelin are idem dendrites
	if(DEBUG) {
	   sectionname(sect)
	   print "INa inserted in ",sect
	}
   }
}






//
//  Procedure to localize conductances in the dendrites
//  arguments: 1=gNa, 2=gKd, 3=gM, 4=min distance, 5=max distance
//
proc localize_dendrites() {	local i

   print " "
   print "Localize dendritic currents:"
   print " "
   print " Sodium cnannels:  ",$1
   print " IKd channels:     ",$2
   print " IM channels:      ",$3
   print " distance range: ",$4," to ",$5
   print " "

   i=0
   forsec "dend" {
     if( (distance(0.5) >= $4) && (distance(0.5) <= $5) ) {
	gnabar_inaT = $1	// sodium channels
	gkbar_imZ = $3		// M-channels
	gkbar_ikdT = $2		// delayed rectifier
	if(DEBUG) {
	   sectionname(sect)
	   print "INa, IKd, IM inserted in ",sect
	}
     }
     i=i+1
   }
}