Dendritic Impedance in Neocortical L5 PT neurons (Kelley et al. accepted)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:266851
We simulated chirp current stimulation in the apical dendrites of 5 biophysically-detailed multi-compartment models of neocortical pyramidal tract neurons and found that a combination of HCN channels and TASK-like channels produced the best fit to experimental measurements of dendritic impedance. We then explored how HCN and TASK-like channels can shape the dendritic impedance as well as the voltage response to synaptic currents.
Reference:
1 . Kelley C, Dura-Bernal S, Neymotin SA, Antic SD, Carnevale NT, Migliore M, Lytton WW (2021) Effects of Ih and TASK-like shunting current on dendritic impedance in layer 5 pyramidal-tract neurons. J Neurophysiology (accepted)
Citations  Citation Browser
Model Information (Click on a link to find other models with that property)
Model Type: Neuron or other electrically excitable cell;
Brain Region(s)/Organism:
Cell Type(s): Neocortex L5/6 pyramidal GLU cell; Neocortex M1 L5B pyramidal pyramidal tract GLU cell;
Channel(s): I h; TASK channel;
Gap Junctions:
Receptor(s):
Gene(s):
Transmitter(s):
Simulation Environment: NEURON; Python; NetPyNE;
Model Concept(s): Impedance;
Implementer(s): Kelley, Craig;
Search NeuronDB for information about:  Neocortex L5/6 pyramidal GLU cell; Neocortex M1 L5B pyramidal pyramidal tract GLU cell; I h; TASK channel;
/
L5PYR_Resonance-master
models
DuraBernal
mod
ar_traub.mod *
cadad.mod *
cadyn.mod *
cagk.mod *
cal_mh.mod *
cal_mig.mod *
can_mig.mod *
canin.mod *
cat_mig.mod *
cat_traub.mod *
catcb.mod *
gabab.mod *
h_BS.mod *
h_harnett.mod
h_kole.mod *
h_migliore.mod *
HCN1.mod *
hin.mod *
IC.mod *
ican_sidi.mod *
IKsin.mod *
kap_BS.mod *
kapcb.mod *
kapin.mod *
kBK.mod *
kctin.mod *
kdmc_BS.mod *
kdr_BS.mod *
kdrin.mod *
MyExp2SynBB.mod *
MyExp2SynNMDABB.mod *
nafx.mod *
nap_sidi.mod *
nax_BS.mod *
savedist.mod *
vecstim.mod *
ghk.inc *
misc.h
parameters.multi *
                            
TITLE I-h channel from Harnett 2015 - J Neurosci

UNITS {
    (mA) = (milliamp)
    (mV) = (millivolt)
}

PARAMETER {
    v                       (mV)
    celsius                 (degC)
    erev     = -30          (mV)
    gbar     = 0.0001       (mho/cm2)
    vhalf    = -100.6       (mV)
    k        = 6.4
    bAct       = 9.63 : for activation tau - (note - only 1 tau)
    bD       = 1.30 : for deactivation tau
    mAct       = 0.0458 : for activation tau
    mD       = -0.0447 : for deactivation tau
    q10      = 2.2
    taumin	= 2.0	(ms)		: minimal value of time constant
}

NEURON {
    SUFFIX h15
    NONSPECIFIC_CURRENT i
    RANGE gbar, g, m
    GLOBAL taumin, k, bAct, bD, mAct, mD, vhalf, minf, tau
}

STATE {
    m
}

ASSIGNED {
    i       (mA/cm2)
    minf
    tau
    g
}

INITIAL {
    rate(v)
    m = minf
}

BREAKPOINT {
    SOLVE states METHOD cnexp
    g       = gbar*m
    i       = g*(v-erev)
}

DERIVATIVE states {     : exact when v held constant; integrates over dt step
    rate(v)
    m' = (minf - m) / tau
}

PROCEDURE rate(v (mV)) { :callable from hoc - leads to segfault in python
    LOCAL qt
    qt = q10^((celsius-26.0)/10.0)

    if(v <= -92.0046199111992) {
      tau = exp(bAct + mAct * v) / qt 
    } else {
      tau = exp(bD + mD * v) / qt
    }
    if(tau < taumin) { tau = taumin }

    minf = 1.0/(1.0 + exp((v-vhalf)/k))
}