Dendritic Impedance in Neocortical L5 PT neurons (Kelley et al. accepted)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:266851
We simulated chirp current stimulation in the apical dendrites of 5 biophysically-detailed multi-compartment models of neocortical pyramidal tract neurons and found that a combination of HCN channels and TASK-like channels produced the best fit to experimental measurements of dendritic impedance. We then explored how HCN and TASK-like channels can shape the dendritic impedance as well as the voltage response to synaptic currents.
Reference:
1 . Kelley C, Dura-Bernal S, Neymotin SA, Antic SD, Carnevale NT, Migliore M, Lytton WW (2021) Effects of Ih and TASK-like shunting current on dendritic impedance in layer 5 pyramidal-tract neurons. J Neurophysiology (accepted)
Citations  Citation Browser
Model Information (Click on a link to find other models with that property)
Model Type: Neuron or other electrically excitable cell;
Brain Region(s)/Organism:
Cell Type(s): Neocortex L5/6 pyramidal GLU cell; Neocortex M1 L5B pyramidal pyramidal tract GLU cell;
Channel(s): I h; TASK channel;
Gap Junctions:
Receptor(s):
Gene(s):
Transmitter(s):
Simulation Environment: NEURON; Python; NetPyNE;
Model Concept(s): Impedance;
Implementer(s): Kelley, Craig;
Search NeuronDB for information about:  Neocortex L5/6 pyramidal GLU cell; Neocortex M1 L5B pyramidal pyramidal tract GLU cell; I h; TASK channel;
/
L5PYR_Resonance-master
models
Neymotin
mod
ar_traub.mod *
cadad.mod *
cadyn.mod *
cagk.mod *
cal_mh.mod *
cal_mig.mod *
can_mig.mod *
canin.mod *
cat_mig.mod *
cat_traub.mod *
catcb.mod *
gabab.mod *
h_BS.mod *
h_harnett.mod
h_kole.mod *
h_migliore.mod *
HCN1.mod *
hin.mod *
IC.mod *
ican_sidi.mod *
IKsin.mod *
kadist.mod *
kap_BS.mod *
kapcb.mod *
kapin.mod *
kBK.mod *
kctin.mod *
kdmc_BS.mod *
kdr_BS.mod *
kdrin.mod *
MyExp2SynBB.mod *
MyExp2SynNMDABB.mod *
nafx.mod *
nap_sidi.mod *
nax_BS.mod *
savedist.mod *
vecstim.mod *
ghk.inc *
misc.h
parameters.multi *
                            
: $Id: HCN1.mod,v 1.4 2013/01/02 15:01:55 samn Exp $ 

TITLE HCN1 

UNITS {
  (mA) = (milliamp)
  (mV) = (millivolt)
}
 
NEURON {
  SUFFIX HCN1
  NONSPECIFIC_CURRENT ih
  RANGE gbar, g, e, v50, htau, hinf
  RANGE gfactor, htaufactor
}
 
PARAMETER {
  celsius	(degC)
  gbar = 0.0001	(mho/cm2)
  e= -30	(mV)
  v50= -73	(mV)
  gfactor = 1
  htaufactor = 1.0 : 4.78
}
 
STATE {
  h
}
 
ASSIGNED {
  ih	  (mA/cm2) 
  hinf
  htau    (ms)
  v	  (mV)
  g       (mho/cm2)
}

PROCEDURE giassign () { 
  : ih=g*h*(v-e)*gfactor 
  g = gbar*h*gfactor
  ih = g*(v-e)
}
 
BREAKPOINT {
  SOLVE states METHOD cnexp
  giassign()
}
 
DERIVATIVE states { 
  rates(v)
  h'= (hinf- h)/ htau
}

INITIAL { 
  rates(v)
  h = hinf
  giassign()
}

PROCEDURE rates(v (mV)) {
  UNITSOFF
  : HCN1
  hinf = 1/(1+exp(0.151*(v-v50)))
  htau = htaufactor*exp((0.033*(v+75)))/(0.011*(1+exp(0.083*(v+75))))
  UNITSON
}