Nav1.6 sodium channel model in globus pallidus neurons (Mercer et al. 2007)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:105385
Model files for the paper Mercer JN, Chan CS, Tkatch T, Held J, Surmeier DJ. Nav1.6 sodium channels are critical to pacemaking and fast spiking in globus pallidus neurons.,J Neurosci. 2007 Dec 5;27(49):13552-66.
Reference:
1 . Mercer JN, Chan CS, Tkatch T, Held J, Surmeier DJ (2007) Nav1.6 sodium channels are critical to pacemaking and fast spiking in globus pallidus neurons. J Neurosci 27:13552-66 [PubMed]
Model Information (Click on a link to find other models with that property)
Model Type: Neuron or other electrically excitable cell;
Brain Region(s)/Organism:
Cell Type(s): Globus pallidus neuron;
Channel(s): I Na,p; I Na,t; I K; I h; I K,Ca; I Sodium; I Calcium; I Potassium;
Gap Junctions:
Receptor(s):
Gene(s): Nav1.6 SCN8A;
Transmitter(s):
Simulation Environment: NEURON;
Model Concept(s): Action Potential Initiation; Action Potentials; Parkinson's;
Implementer(s): Held, Joshua [j-held at northwestern.edu];
Search NeuronDB for information about:  I Na,p; I Na,t; I K; I h; I K,Ca; I Sodium; I Calcium; I Potassium;
NEURON {
	SUFFIX cap_gp
	USEION ca READ cai, cao WRITE ica
	RANGE gbar, ica
	GLOBAL minf,mtau
	GLOBAL monovalConc, monovalPerm
}

UNITS {
	(mV) = (millivolt)
	(mA) = (milliamp)
	(mM) = (milli/liter)
	(S) = (siemens)
	F = 9.6485e4   (coul)
	R = 8.3145 (joule/degC)
	(mC) = (millicoul)
}

PARAMETER {
	v			(mV)

	gbar = 1		(cm/s)
	monovalConc = 140	(mM)
	monovalPerm = 0

	cai			(mM)
	cao			(mM)
	celsius (degC)
}

ASSIGNED {
	ica	(mA/cm2)
        minf
	mtau	(ms)
	T	(degC)
	E	(volts)
	g 	(cm/s)
}

STATE {
	m
}

INITIAL {
	rates(v)
	m = minf
}

BREAKPOINT {
	SOLVE states METHOD cnexp
	g = gbar * m
	ica = g * ghk(v, cai, cao, 2)
}

DERIVATIVE states {
	rates(v)
	m' = (minf - m)/mtau
}

FUNCTION ghk( v(mV), ci(mM), co(mM), z)  (mC/cm3) { LOCAL Ci
	T = 22 + 273.19  : Kelvin
        E = v * 1e-3 (volts/mV)
        Ci = ci + (monovalPerm) * (monovalConc)        : Monovalent permeability
	if (fabs(1-exp(-z*(F*E)/(R*T))) < 1e-6) { : denominator is small -> Taylor series
		ghk = (1e-3) * z * F * (Ci-co*exp(-z*(F*E)/(R*T)))*(1-(z*(F*E)/(R*T)))
	} else {
		ghk = (1e-3) * z^2*(E*F^2)/(R*T)*(Ci-co*exp(-z*(F*E)/(R*T)))/(1-exp(-z*(F*E)/(R*T)))
	}
}

PROCEDURE rates (v (mV)) {
	LOCAL q10
	minf = 1/(1+exp(-(v + 19 (mV) ) / 5.5 (mV)))
	q10 = 3^((celsius - 22 (degC))/10 (degC) )
	mtau = q10*(mtau_func(v)) * 1e3
}

FUNCTION mtau_func( v (mV) ) (ms) {
        if (v > -50) {
            mtau_func = .000191 (ms) + .00376 (ms) *exp(-((v+41.9 (mV))/27.8 (mV) )^2)
        } else {
            mtau_func = .00026367 (ms) + .1278 (ms) * exp(v* .10327 (1/mV))
        }
}

Loading data, please wait...