CA1 pyramidal neuron: functional significance of axonal Kv7 channels (Shah et al. 2008)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:112546
The model used in this paper confirmed the experimental findings suggesting that axonal Kv7 channels are critically and uniquely required for determining the inherent spontaneous firing of hippocampal CA1 pyramids, independently of alterations in synaptic activity. The model predicts that the axonal Kv7 density could be 3-5 times that at the soma.
Reference:
1 . Shah MM, Migliore M, Valencia I, Cooper EC, Brown DA (2008) Functional significance of axonal Kv7 channels in hippocampal pyramidal neurons. Proc Natl Acad Sci U S A 105(22):7869-7874 [PubMed]
Model Information (Click on a link to find other models with that property)
Model Type: Neuron or other electrically excitable cell; Axon; Channel/Receptor;
Brain Region(s)/Organism:
Cell Type(s): Hippocampus CA1 pyramidal cell;
Channel(s): I Na,t; I T low threshold; I A; I K; I M; I Calcium;
Gap Junctions:
Receptor(s):
Gene(s):
Transmitter(s):
Simulation Environment: NEURON;
Model Concept(s): Action Potential Initiation; Detailed Neuronal Models; Axonal Action Potentials; Action Potentials;
Implementer(s): Migliore, Michele [Michele.Migliore at Yale.edu];
Search NeuronDB for information about:  Hippocampus CA1 pyramidal cell; I Na,t; I T low threshold; I A; I K; I M; I Calcium;
/
km
readme.html
cacumm.mod *
cagk.mod
cal2.mod
can2.mod
cat.mod *
h.mod *
kadist.mod *
KahpM95.mod *
kaprox.mod *
kdrca1.mod *
km.mod *
na3n.mod *
naxn.mod *
fig4a.hoc
fixnseg.hoc *
geo9068802.hoc *
mosinit.hoc *
screenshot.jpg
                            
TITLE CaGk
: Calcium activated K channel.
: Modified from Moczydlowski and Latorre (1983) J. Gen. Physiol. 82

UNITS {
	(molar) = (1/liter)
}

UNITS {
	(mV) =	(millivolt)
	(mA) =	(milliamp)
	(mM) =	(millimolar)
}


NEURON {
	SUFFIX cagk
	USEION ca READ cai
	USEION k READ ek WRITE ik
	RANGE gbar,gkca,ik
	GLOBAL oinf, tau
}

UNITS {
	FARADAY = (faraday)  (kilocoulombs)
	R = 8.313424 (joule/degC)
}

PARAMETER {
	celsius		(degC)
	v		(mV)
	gbar=.01	(mho/cm2)	: Maximum Permeability
	cai=50e-6 		(mM)	
	ek		(mV)

	d1 = .84
	d2 = 1.
	k1 = .48e-3	(mM)
	k2 = .13e-6	(mM)
	abar = .28	(/ms)
	bbar = .48	(/ms)
        st=1            (1)
}

ASSIGNED {
	ik		(mA/cm2)
	oinf
	tau		(ms)
        gkca          (mho/cm2)
}

INITIAL {
        rate(v,cai)
        o=oinf
}

STATE {	o }		: fraction of open channels

BREAKPOINT {
	SOLVE state METHOD cnexp
	gkca = gbar*o^st
	ik = gkca*(v - ek)
}

DERIVATIVE state {	: exact when v held constant; integrates over dt step
	rate(v, cai)
	o' = (oinf - o)/tau
}

FUNCTION alp(v (mV), c (mM)) (1/ms) { :callable from hoc
	alp = c*abar/(c + exp1(k1,d1,v))
}

FUNCTION bet(v (mV), c (mM)) (1/ms) { :callable from hoc
	bet = bbar/(1 + c/exp1(k2,d2,v))
}

FUNCTION exp1(k (mM), d, v (mV)) (mM) { :callable from hoc
	exp1 = k*exp(-2*d*FARADAY*v/R/(273.15 + celsius))
}

PROCEDURE rate(v (mV), c (mM)) { :callable from hoc
	LOCAL a
	a = alp(v,c)
	tau = 1/(a + bet(v, c))
	oinf = a*tau
	if (oinf<1.e-6) {oinf=0}
}


Loading data, please wait...