Dentate gyrus granule cell: calcium and calcium-dependent conductances (Aradi and Holmes 1999)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:116740
We have constructed a detailed model of a hippocampal dentate granule (DG) cell that includes nine different channel types. Channel densities and distributions were chosen to reproduce reported physiological responses observed in normal solution and when blockers were applied. The model was used to explore the contribution of each channel type to spiking behavior with particular emphasis on the mechanisms underlying postspike events. ... The model was used to predict changes in channel densities that could lead to epileptogenic burst discharges and to predict the effect of altered buffering capacity on firing behavior. We conclude that the clustered spatial distributions of calcium related channels, the presence of slow delayed rectifier potassium currents in dendrites, and calcium buffering properties, together, might explain the resistance of DG cells to the development of epileptogenic burst discharges.
Reference:
1 . Aradi I, Holmes WR (1999) Role of multiple calcium and calcium-dependent conductances in regulation of hippocampal dentate granule cell excitability. J Comput Neurosci 6:215-35 [PubMed]
Model Information (Click on a link to find other models with that property)
Model Type: Neuron or other electrically excitable cell;
Brain Region(s)/Organism: Dentate gyrus;
Cell Type(s): Dentate gyrus granule GLU cell;
Channel(s): I L high threshold; I N; I T low threshold; I A; I K; I K,Ca; I Calcium; I Potassium;
Gap Junctions:
Receptor(s):
Gene(s):
Transmitter(s):
Simulation Environment: NEURON;
Model Concept(s): Bursting; Calcium dynamics;
Implementer(s): Nakhoul, Hani [hnakho at lsuhsc.edu];
Search NeuronDB for information about:  Dentate gyrus granule GLU cell; I L high threshold; I N; I T low threshold; I A; I K; I K,Ca; I Calcium; I Potassium;
: Ca-dependent K channels (BK and SK)


NEURON {
	SUFFIX CadepK
	USEION ca READ ica
	USEION k READ ek WRITE ik
	RANGE gbkbar, gskbar
	GLOBAL ca0, tau, stau
}

UNITS {
	(molar) = (1/liter)
	(mM) = (millimolar)
	(mV) = (millivolt)
	(mA) = (milliamp)
	(S) = (siemens)
	B = .26 (mM-cm2/mA-ms)
}

PARAMETER {
	gbkbar = .01	(S/cm2)	: maximum permeability
	gskbar = .01	(S/cm2)	: maximum permeability
	ca0 = .00007	(mM)
	tau = 9		(ms)
	alphar = 7.5	(/ms)
	stau = 10		(ms)
}

ASSIGNED {
	v		(mV)
	ek		(mV)
	ik		(mA/cm2)
	ica		(mA/cm2)
	area		(microm2)
      gbk		(S/cm2)
      gsk		(S/cm2)
}

STATE { ca_i (mM) q r s }

BREAKPOINT {
	SOLVE state METHOD cnexp
	gbk = gbkbar*r*s*s
	gsk = gskbar*q*q
	ik = (gbk+gsk)*(v - ek)
}

DERIVATIVE state {	: exact when v held constant; integrates over dt step
	ca_i' = -B*ica-(ca_i-ca0)/tau
	q' = alphaq(ca_i)*(1-q)-betaq(ca_i)*q
	r' = alphar*(1-r)-betar(v)*r
	s' = (sinf(ca_i)-s)/stau
}

INITIAL {
	ca_i = ca0
	q = alphaq(ca_i)/(alphaq(ca_i)+betaq(ca_i))
	r = alphar/(alphar+betar(v))
      s = sinf(ca_i)
}

FUNCTION exp1(A (/ms), d, k, x (mM)) (/ms) {
	UNITSOFF
	exp1 = A/exp((12*log10(x)+d)/k)
	UNITSON
}

FUNCTION alphaq(x (mM)) (/ms) {
	alphaq = exp1(0.00246,28.48,-4.5,x)
}

FUNCTION betaq(x (mM)) (/ms) {
	betaq = exp1(0.006,60.4,35,x)
}

FUNCTION betar(v (mV)) (/ms) {
	UNITSOFF
	betar = 0.11/exp((v-35)/14.9)
	UNITSON
}

FUNCTION sinf(x (mM)) {
	UNITSOFF
	sinf = 1/(1+4/(1000*x))
	UNITSON
}

Loading data, please wait...