Effects of synaptic location and timing on synaptic integration (Rall 1964)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:116981
Reproduces figures 5 - 8 from Rall, W. Theoretical significance of dendritic trees for neuronal input-output relations. In: Neural Theory and Modeling, ed. Reiss, R.F., Palo Alto: Stanford University Press (1964).
References:
1 . Rall W (1964) Theoretical significance of dendritic trees for neuronal input output relations Neural Theory and Modeling, Reiss RF, ed. pp.73
2 . Rall W (1964) Theoretical significance of dendritic trees for neuronal input-output relations The Theoretical Foundation of Dendritic Function: Selected Papers of Wilfrid Rall with Commentaries, Segev I:Rinzel J:Shephard G, ed. pp.122
Model Information (Click on a link to find other models with that property)
Model Type: Dendrite;
Brain Region(s)/Organism: Unknown;
Cell Type(s):
Channel(s):
Gap Junctions:
Receptor(s):
Gene(s):
Transmitter(s):
Simulation Environment: NEURON;
Model Concept(s): Simplified Models; Synaptic Integration; Electrotonus;
Implementer(s): Carnevale, Ted [Ted.Carnevale at Yale.edu];
/
rall1964
readme.html
gpulse.mod
cell.hoc
init.hoc
mosinit.hoc *
rig.ses
screenshot.jpg
                            
COMMENT
gpulse1.mod, patterned after ipulse1.mod
Generates a train of conductance pulses
with a specified reversal potential, 
as if it were a triggerable membrane conductance.
User specifies duration of pulse, interpulse interval (ton and toff),
and number of pulses.
5/27/2008 NTC
ENDCOMMENT

NEURON {
	POINT_PROCESS Gpulse1
	RANGE del, ton, toff, num, e, gmax, g, i
	NONSPECIFIC_CURRENT i
}

UNITS {
	(mV) = (millivolt)
	(nA) = (nanoamp)
	(uS) = (microsiemens)
}

PARAMETER {
	del (ms)
	ton (ms) <0, 1e9>	: duration of ON phase
	toff (ms) <0, 1e9>	: duration of OFF phase
	num			: how many to deliver
	e (mV)			: reversal potential
	gmax (uS) <0, 1e9>	: how big
}

ASSIGNED {
	v (mV)
	g (uS)		: conductance at present time
:	ival (nA)
	i (nA)
	on
	tally		: how many more to deliver
}

INITIAL {
	g = 0
	i = 0
:	ival = 0
	tally = num
	if (tally > 0) {
		net_send(del, 1)
		on = 0
		tally = tally - 1
	}
}

BREAKPOINT {
: printf("%g\n", t)
	i = g*(v-e)
}

NET_RECEIVE (w) {
	: ignore any but self-events with flag == 1
	if (flag == 1) {
		if (on == 0) {
			: turn it on
:			ival = amp
			g = gmax
			on = 1
			: prepare to turn it off
			net_send(ton, 1)
		} else {
			: turn it off
:			ival = 0
			g = 0
			on = 0
			if (tally > 0) {
				: prepare to turn it on again
				net_send(toff, 1)
				tally = tally - 1
			}
		}
	}
}

Loading data, please wait...