A Fast Rhythmic Bursting Cell: in vivo cell modeling (Lee 2007)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:125857
One of the cellular mechanisms underlying the generation of gamma oscillations is a type of cortical pyramidal neuron named fast rhythmic bursting (FRB) cells. After cells from cats' primary visual cortices were filled with Neurobiotin, the brains were cut, and the cells were photographed. One FRB cell was chosen to be confocaled, reconstructed with Neurolucida software, and generated a detailed multi-compartmental model in the NEURON program. We explore firing properties of FRB cells and the role of enhanced Na+ conductance.
Reference:
1 . Lee, J (2007) Fast Rhythmic Bursting Cells: The Horizontal Fiber System in the Cat’s Primary Visual Cortex Penn McNair Research Journal 1(1):1
Model Information (Click on a link to find other models with that property)
Model Type: Neuron or other electrically excitable cell;
Brain Region(s)/Organism: Neocortex;
Cell Type(s):
Channel(s): I Na,p; I Na,t; I K,Ca; I Sodium; I Calcium; I Potassium; I_Na,Ca; I_K,Na;
Gap Junctions:
Receptor(s):
Gene(s):
Transmitter(s): Glutamate;
Simulation Environment: NEURON;
Model Concept(s): Activity Patterns; Bursting; Spatio-temporal Activity Patterns; Action Potentials; Vision;
Implementer(s): Lee, Jin [jin3 at sas.upenn.edu];
Search NeuronDB for information about:  I Na,p; I Na,t; I K,Ca; I Sodium; I Calcium; I Potassium; I_Na,Ca; I_K,Na; Glutamate;
/
FRB
readme.html
cacurrent.mod
cadecay.mod
kaf.mod
kahp.mod
kc.mod
kdr.mod
leak.mod
naf.mod
nap.mod
2FRB.hoc
FRB_12_19.hoc
FRB_12_21.hoc
frb_session.ses
FRB3.hoc
kaf_taum.dat *
kaf_vtau.dat *
mosinit.hoc
nap_tauh.dat *
nap_vtau.dat *
NlData.BK1
NlData.BK2
screenshot.jpg
screenshot2.jpg
variable_dt.ses
                            
TITLE NaP - persistent sodium current for nucleus accumbens 

COMMENT
Magistretti J, Alonso A (1999). "Biophysical properties and slow
voltage-dependent inactivation of a sustained sodium current in entorhinal
cortex layer-II principal neurons." J Gen Phys, 114: 491-509.

Traub RD, Buhl EH et al (2003). "Fast rhythmic bursting can be induced in
layer 2/3 cortical neurons by enhancing persistent na+ conductance or by
blocking BK channels." J Neurophys 89: 909-921.

Jason Moyer 2004 - jtmoyer@seas.upenn.edu
ENDCOMMENT

UNITS {
        (mA) = (milliamp)
        (mV) = (millivolt)
        (S)  = (siemens)
}
 
NEURON {
        SUFFIX nap
        USEION na READ ena WRITE ina
        RANGE  gnabar
}
 
PARAMETER {
	gnabar   =   4e-5 (S/cm2)	: 4e-5 in soma; 1.3802e-7 in dends

	mvhalf = -52.6		(mV)	: Magistretti 1999, Fig 4
	mslope = -4.6		(mV)	: Magistretti 1999, Fig 4

	hvhalf = -48.8		(mV)	: Magistretti 1999, Fig 4
	hslope = 10.0		(mV)	: Magistretti 1999, Fig 4

	qfact = 3
}
 
STATE { m h }
 
ASSIGNED {
	ena		(mV)
        v 		(mV)
        ina		(mA/cm2)
        gna		(S/cm2)

        minf
	hinf	

	taum	(ms)			: Traub 2003, Table A2
   }
 
BREAKPOINT {
        SOLVE state METHOD cnexp
        gna = gnabar * m * h  
        ina = gna * ( v - ena )
:        VERBATIM
:        	printf("Ena is %g\n", ena);
:        ENDVERBATIM
}
 

 
INITIAL {
	rates(v)
	
	m = minf
	h = hinf
}

FUNCTION_TABLE tauh(v(mV))  (ms)		: Magistretti 1999, Fig 8A

DERIVATIVE state { 
        rates(v)
        m' = (minf - m) / taum
        h' = (hinf - h) / (tauh(v)/qfact)    
}
 
PROCEDURE rates(v (mV)) {  
	TABLE minf, hinf, taum
		FROM -200 TO 200 WITH 201

		minf = 1 / (1 + exp( (v - mvhalf) / mslope))
		hinf = 1 / (1 + exp( (v - hvhalf) / hslope))
		
		UNITSOFF
		if (v < -40) {			: Traub 2003, Table A2
			taum = 0.025 + 0.14 * exp( (v + 40 ) / 10)
		} else {
			taum = 0.02 + 0.145 * exp( (-v - 40) / 10)
		}
		UNITSON
}
 
 

Loading data, please wait...