Mathematical model for windup (Aguiar et al. 2010)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:128559
"Windup is characterized as a frequency-dependent increase in the number of evoked action potentials in dorsal horn neurons in response to electrical stimulation of afferent C-fibers. ... The approach presented here relies on mathematical and computational analysis to study the mechanism(s) underlying windup. From experimentally obtained windup profiles, we extract the time scale of the facilitation mechanisms that may support the characteristics of windup. Guided by these values and using simulations of a biologically realistic compartmental model of a wide dynamic range (WDR) neuron, we are able to assess the contribution of each mechanism for the generation of action potentials windup. ..."
Reference:
1 . Aguiar P, Sousa M, Lima D (2010) NMDA channels together with L-type calcium currents and calcium-activated nonspecific cationic currents are sufficient to generate windup in WDR neurons. J Neurophysiol 104:1155-66 [PubMed]
Model Information (Click on a link to find other models with that property)
Model Type: Neuron or other electrically excitable cell;
Brain Region(s)/Organism:
Cell Type(s): Wide dynamic range neuron;
Channel(s): I Na,p; I Na,t; I L high threshold; I N; I K; I K,Ca;
Gap Junctions:
Receptor(s): GabaA; AMPA; NMDA;
Gene(s):
Transmitter(s):
Simulation Environment: NEURON; MATLAB;
Model Concept(s): Activity Patterns; Action Potentials;
Implementer(s):
Search NeuronDB for information about:  GabaA; AMPA; NMDA; I Na,p; I Na,t; I L high threshold; I N; I K; I K,Ca;
/
WDR-Model
readme.html
AMPA_DynSyn.mod
CaIntraCellDyn.mod
GABAa_DynSyn.mod *
GABAb_DynSyn.mod *
HH2.mod *
iCaAN.mod *
iCaL.mod *
iKCa.mod *
iNaP.mod *
mGluR_DynSyn.mod
NK1_DynSyn.mod *
NMDA_DynSyn.mod *
herreroscatter.m
interneuron.hoc *
loadsynapticcurrents.m
mosinit.hoc
screenshot.jpg
WDR.hoc
wdr_spike_times.dat *
wdr-complete-model.hoc
wdr-complete-model.ses
wdr-complete-model-exportsyns.hoc
                            
TITLE  NMDA receptor with Ca influx and pre-synaptic short-term plasticity


COMMENT
Dynamic presynaptic activity based on Fuhrmann et al, 2002: "Coding of temporal information by activity-dependent synapses" 

Written by Paulo Aguiar and Mafalda Sousa, IBMC, May 2008
pauloaguiar@fc.up.pt ; mafsousa@ibmc.up.pt
ENDCOMMENT


NEURON {
	POINT_PROCESS NMDA_DynSyn
	USEION ca WRITE ica	
	USEION mg READ mgo VALENCE 2
	RANGE tau_rise, tau_decay
	RANGE U1, tau_rec, tau_fac
	RANGE i, g, e, mg, inon, ica, ca_ratio
	NONSPECIFIC_CURRENT inon
    }
    
UNITS {
	(nA) = (nanoamp)
	(mV) = (millivolt)
	(molar) = (1/liter)
	(mM) = (millimolar)
    }    
    
    PARAMETER {
  	tau_rise  = 5.0   (ms)  : dual-exponential conductance profile
	tau_decay = 70.0  (ms)  : IMPORTANT: tau_rise < tau_decay
	U1        = 1.0   (1)   : The parameter U1, tau_rec and tau_fac define
	tau_rec   = 0.1   (ms)  : the pre-synaptic SP short-term plasticity
	tau_fac   = 0.1   (ms)  : mechanism (see Fuhrmann et al, 2002)
	e         = 0.0   (mV)  : synapse reversal potential
	mgo		  = 1.0   (mM)  : external magnesium concentration
	ca_ratio  = 0.1   (1)   : ratio of calcium current to total current( Burnashev/Sakmann J Phys 1995 485 403-418)
    }
    
    
ASSIGNED {
	v		(mV)
	i		(nA)
	g		(umho)
	factor	(1)
	ica		(nA)
	inon	(nA)
}

STATE {
	A
	B
}

INITIAL{
	LOCAL tp
	A = 0
	B = 0
	tp = (tau_rise*tau_decay)/(tau_decay-tau_rise)*log(tau_decay/tau_rise)
	factor = -exp(-tp/tau_rise)+exp(-tp/tau_decay)
	factor = 1/factor
}

BREAKPOINT {
	SOLVE state METHOD cnexp
	g = B-A
	i = g*mgblock(v)*(v-e)
	ica = ca_ratio*i
	inon = (1-ca_ratio)*i
	:printf("\nt=%f\tinon=%f\tica=%f\ti=%f\tmgb=%f",t, inon, ica, i, mgblock(v))
}

DERIVATIVE state{
	A' = -A/tau_rise
	B' = -B/tau_decay
}

FUNCTION mgblock(v(mV)) {
	: from Jahr & Stevens 1990
	mgblock = 1 / (1 + exp(0.062 (/mV) * -v) * (mgo / 3.57 (mM)))
}

NET_RECEIVE (weight, Pv, P, Use, t0 (ms)){
	INITIAL{
		P=1
		Use=0
		t0=t
	}	

	Use = Use * exp(-(t-t0)/tau_fac)
	Use = Use + U1*(1-Use) 
	P = 1-(1- P) * exp(-(t-t0)/tau_rec)
	Pv= Use * P
	P = P - Use * P
	
	t0=t
	
	A=A + weight*factor*Pv
	B=B + weight*factor*Pv
}


Loading data, please wait...