Cerebellar cortex oscil. robustness from Golgi cell gap jncs (Simoes de Souza and De Schutter 2011)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:139656
" ... Previous one-dimensional network modeling of the cerebellar granular layer has been successfully linked with a range of cerebellar cortex oscillations observed in vivo. However, the recent discovery of gap junctions between Golgi cells (GoCs), which may cause oscillations by themselves, has raised the question of how gap-junction coupling affects GoC and granular-layer oscillations. To investigate this question, we developed a novel two-dimensional computational model of the GoC-granule cell (GC) circuit with and without gap junctions between GoCs. ..."
Reference:
1 . Simões de Souza F, De Schutter E (2011) Robustness effect of gap junctions between Golgi cells on cerebellar cortex oscillations Neural Systems & Circuits 1:7:1-19
Model Information (Click on a link to find other models with that property)
Model Type: Realistic Network;
Brain Region(s)/Organism: Cerebellum;
Cell Type(s): Cerebellum interneuron granule cell; Cerebellum golgi cell;
Channel(s):
Gap Junctions: Gap junctions;
Receptor(s): GabaA; AMPA; NMDA;
Gene(s): HCN1; HCN2;
Transmitter(s):
Simulation Environment: NEURON;
Model Concept(s): Oscillations; Synchronization; Action Potentials;
Implementer(s): Simoes-de-Souza, Fabio [fabio.souza at ufabc.edu.br];
Search NeuronDB for information about:  Cerebellum interneuron granule cell; GabaA; AMPA; NMDA;
/
network
data
README.txt
gap.mod
Golgi_BK.mod *
Golgi_Ca_HVA.mod *
Golgi_Ca_LVA.mod *
Golgi_CALC.mod *
Golgi_CALC_ca2.mod *
Golgi_hcn1.mod *
Golgi_hcn2.mod *
Golgi_KA.mod *
Golgi_KM.mod *
Golgi_KV.mod *
Golgi_lkg.mod *
Golgi_Na.mod *
Golgi_NaP.mod *
Golgi_NaR.mod *
Golgi_SK2.mod *
GRC_CA.mod *
GRC_CALC.mod *
GRC_KA.mod *
GRC_KCA.mod *
GRC_KIR.mod *
GRC_KM.mod *
GRC_KV.mod *
GRC_LKG1.mod *
GRC_LKG2.mod *
GRC_NA.mod *
K_conc.mod *
Na_conc.mod *
Golgi_ComPanel.hoc *
Golgi_template.hoc
granule_template.hoc
MF_template.hoc
mosinit.hoc
network.hoc
utils.hoc *
                            
TITLE Cerebellum Granule Cell Model

COMMENT
        CaHVA channel
   
	Author: E.DAngelo, T.Nieus, A. Fontana
	Last revised: 8.5.2000
ENDCOMMENT
 
NEURON { 
	SUFFIX Golgi_Ca_HVA
	USEION ca READ eca WRITE ica 
	RANGE gcabar, ica, g
	:RANGE alpha_s, beta_s, alpha_u, beta_u 
	:RANGE Aalpha_s, Kalpha_s, V0alpha_s
	:RANGE Abeta_s, Kbeta_s, V0beta_s
	:RANGE Aalpha_u, Kalpha_u, V0alpha_u
	:RANGE Abeta_u, Kbeta_u, V0beta_u
	RANGE s_inf, tau_s, u_inf, tau_u
	RANGE s, u, tcorr
} 
 
UNITS { 
	(mA) = (milliamp) 
	(mV) = (millivolt) 
} 
 
PARAMETER {
	Aalpha_s = 0.04944 (/ms)
	Kalpha_s =  15.87301587302 (mV)
	V0alpha_s = -29.06 (mV)
	
	Abeta_s = 0.08298 (/ms)
	Kbeta_s =  -25.641 (mV)
	V0beta_s = -18.66 (mV)

	Aalpha_u = 0.0013 (/ms)
	Kalpha_u =  -18.183 (mV)
	V0alpha_u = -48 (mV)
		
	Abeta_u = 0.0013 (/ms)
	Kbeta_u =   83.33 (mV)
	V0beta_u = -48 (mV)

	v (mV) 
	gcabar= 460e-6 (mho/cm2) 
	eca (mV) 
	celsius (degC)
	Q10 = 3 
} 

STATE { 
	s 
	u 
} 

ASSIGNED { 
	ica (mA/cm2) 
	s_inf 
	u_inf 
	tau_s (ms) 
	tau_u (ms) 
	g (mho/cm2) 
	alpha_s (/ms)
	beta_s (/ms)
	alpha_u (/ms)
	beta_u (/ms)
	tcorr	(1)
} 
 
INITIAL { 
	rate(v) 
	s = s_inf 
	u = u_inf 
} 
 
BREAKPOINT { 
	SOLVE states METHOD derivimplicit 
	g = gcabar*s*s*u 
	ica = g*(v - eca) 
	alpha_s = alp_s(v)
	beta_s = bet_s(v)
	alpha_u = alp_u(v)
	beta_u = bet_u(v)
}
 
DERIVATIVE states { 
	rate(v) 
	s' =(s_inf - s)/tau_s 
	u' =(u_inf - u)/tau_u 
} 

FUNCTION alp_s(v(mV))(/ms) { 
	tcorr = Q10^((celsius-20(degC))/10(degC))
	alp_s = tcorr*Aalpha_s*exp((v-V0alpha_s)/Kalpha_s) 
} 
 
FUNCTION bet_s(v(mV))(/ms) { 
	tcorr = Q10^((celsius-20(degC))/10(degC))
	bet_s = tcorr*Abeta_s*exp((v-V0beta_s)/Kbeta_s) 
} 
 
FUNCTION alp_u(v(mV))(/ms) { 
	tcorr = Q10^((celsius-20(degC))/10(degC))
	alp_u = tcorr*Aalpha_u*exp((v-V0alpha_u)/Kalpha_u) 
} 
 
FUNCTION bet_u(v(mV))(/ms) { 
	tcorr = Q10^((celsius-20(degC))/10(degC))
	bet_u = tcorr*Abeta_u*exp((v-V0beta_u)/Kbeta_u) 
} 
 
PROCEDURE rate(v (mV)) {LOCAL a_s, b_s, a_u, b_u 
	TABLE s_inf, tau_s, u_inf, tau_u 
	DEPEND Aalpha_s, Kalpha_s, V0alpha_s, 
	       Abeta_s, Kbeta_s, V0beta_s,
               Aalpha_u, Kalpha_u, V0alpha_u,
               Abeta_u, Kbeta_u, V0beta_u, celsius FROM -100 TO 30 WITH 13000 
	a_s = alp_s(v)  
	b_s = bet_s(v) 
	a_u = alp_u(v)  
	b_u = bet_u(v) 
	s_inf = a_s/(a_s + b_s) 
	tau_s = 1/(a_s + b_s) 
	u_inf = a_u/(a_u + b_u) 
	tau_u = 1/(a_u + b_u) 
}


Loading data, please wait...