A multi-compartment model for interneurons in the dLGN (Halnes et al. 2011)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:140249
This model for dLGN interneurons is presented in two parameterizations (P1 & P2), which were fitted to current-clamp data from two different interneurons (IN1 & IN2). The model qualitatively reproduces the responses in IN1 & IN2 under 8 different experimental condition, and quantitatively reproduces the I/O-relations (#spikes elicited as a function of injected current).
Reference:
1 . Halnes G, Augustinaite S, Heggelund P, Einevoll GT, Migliore M (2011) A multi-compartment model for interneurons in the dorsal lateral geniculate nucleus. PLoS Comput Biol 7:e1002160 [PubMed]
Model Information (Click on a link to find other models with that property)
Model Type: Neuron or other electrically excitable cell;
Brain Region(s)/Organism:
Cell Type(s): Thalamus lateral geniculate nucleus interneuron;
Channel(s): I L high threshold; I T low threshold; I CAN; I Sodium; I Mixed; I Potassium; I_AHP;
Gap Junctions:
Receptor(s):
Gene(s):
Transmitter(s):
Simulation Environment: NEURON;
Model Concept(s): Activity Patterns; Active Dendrites; Detailed Neuronal Models; Rebound firing;
Implementer(s): Halnes, Geir [geir.halnes at nmbu.no];
Search NeuronDB for information about:  I L high threshold; I T low threshold; I CAN; I Sodium; I Mixed; I Potassium; I_AHP;
/
dLGN_modelDB
readme.html
Cad.mod *
HH_traub.mod *
iahp.mod *
iar.mod *
ical.mod *
Ican.mod *
it2.mod *
091008A2.hoc *
fixnseg.hoc *
INmodel.hoc
INmodel.ses
mosinit.hoc
Parameters1.hoc
Parameters2.hoc
screenshot1.jpg
screenshot2.jpg
screenshot3.jpg
screenshot4.jpg
                            
TITLE anomalous rectifier channel
:
: Anomalous Rectifier Ih - cation (Na/K) channel for geniculate interneurons
: Differential equations
:
: Written by Jun Zhu, Univ. Wisconsin, Jan 1996
: Modified by Geir Halnes, Norwegian University of Life Sciences, June 2011
: Fitted to data from mice dLGN interneurons.

INDEPENDENT {t FROM 0 TO 1 WITH 1 (ms)}

NEURON {
	SUFFIX iar
	USEION other WRITE iother VALENCE 1
        RANGE ghbar,  iother
	GLOBAL h_inf, tauh, erev, stp,  shift
}


UNITS {
	(molar)	= (1/liter)
	(mM)	= (millimolar)
	(mA) 	= (milliamp)
	(mV) 	= (millivolt)
	(msM)	= (ms mM)
}


PARAMETER {
      v               (mV)
	erev	= -44	(mV)
	celsius = 36	(degC)
	ghbar	= 1.1e-5 (mho/cm2) : Set from hoc-file
	shift   =  0    (mV)

	: Kinetics fitted to new data from mice dLGN interneurons.
	: Halnes et al. 2011
      stp     = 10	
	a0 = 96
	a1 = 250
	a2 = 30.7
	a3 = 78.8
	a4 = 5.78
}


STATE {
        h
}


ASSIGNED {
	i	(mA/cm2)
	iother 	(mA/cm2)
	h_inf
	tauh	(ms)
	tadj
}


BREAKPOINT {
	SOLVE state METHOD cnexp
	iother = ghbar * h * (v - erev)
}

DERIVATIVE state  {
	evaluate_fct(v)
      h' = (h_inf - h) / tauh
}
UNITSOFF

INITIAL {
	evaluate_fct(v)
      h = h_inf
}


PROCEDURE evaluate_fct(v (mV)) {
	h_inf = 1 / ( 1 + exp((v+shift+a0)/stp) )
	tauh = exp((v+shift+a1)/a2) / ( 1 + exp((v+shift+a3)/a4))
}



UNITSON


Loading data, please wait...