CA1 pyramidal neuron: depolarization block (Bianchi et al. 2012)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:143719
NEURON files from the paper: On the mechanisms underlying the depolarization block in the spiking dynamics of CA1 pyramidal neurons by D.Bianchi, A. Marasco, A.Limongiello, C.Marchetti, H.Marie,B.Tirozzi, M.Migliore (2012). J Comput. Neurosci. In press. DOI: 10.1007/s10827-012-0383-y. Experimental findings shown that under sustained input current of increasing strength neurons eventually stop firing, entering a depolarization block. We analyze the spiking dynamics of CA1 pyramidal neuron models using the same set of ionic currents on both an accurate morphological reconstruction and on its reduction to a single-compartment. The results show the specic ion channel properties and kinetics that are needed to reproduce the experimental findings, and how their interplay can drastically modulate the neuronal dynamics and the input current range leading to depolarization block.
Reference:
1 . Bianchi D, Marasco A, Limongiello A, Marchetti C, Marie H, Tirozzi B, Migliore M (2012) On the mechanisms underlying the depolarization block in the spiking dynamics of CA1 pyramidal neurons. J Comput Neurosci 33:207-25 [PubMed]
Model Information (Click on a link to find other models with that property)
Model Type: Neuron or other electrically excitable cell;
Brain Region(s)/Organism: Hippocampus;
Cell Type(s): Hippocampus CA1 pyramidal GLU cell;
Channel(s): I Na,t; I A; I K; I M; I h; I K,Ca; I_AHP;
Gap Junctions:
Receptor(s): GabaA; AMPA; NMDA;
Gene(s):
Transmitter(s): Gaba; Glutamate;
Simulation Environment: NEURON; Mathematica;
Model Concept(s): Simplified Models; Depolarization block; Bifurcation;
Implementer(s): Bianchi, Daniela [danielabianchi12 -at- gmail.com]; Limongiello, Alessandro [alessandro.limongiello at unina.it];
Search NeuronDB for information about:  Hippocampus CA1 pyramidal GLU cell; GabaA; AMPA; NMDA; I Na,t; I A; I K; I M; I h; I K,Ca; I_AHP; Gaba; Glutamate;
/
Ca1_Bianchi
experiment
cad.mod *
cagk.mod *
cal.mod *
calH.mod *
car.mod *
cat.mod *
d3.mod *
h.mod *
kadist.mod *
kaprox.mod *
kca.mod *
kdr.mod *
km.mod *
na3.mod *
na3dend.mod *
na3notrunk.mod *
nap.mod *
nax.mod *
somacar.mod *
cell-setup.hoc
mosinit.hoc
sessio.ses
Simulation.hoc
                            
TITLE Slow Ca-dependent potassium current
                            :
                            :   Ca++ dependent K+ current IC responsible for slow AHP
                            :   Differential equations
                            :
                            :   Model based on a first order kinetic scheme
                            :
                            :       + n cai <->     (alpha,beta)
                            :
                            :   Following this model, the activation fct will be half-activated at 
                            :   a concentration of Cai = (beta/alpha)^(1/n) = cac (parameter)
                            :
                            :   The mod file is here written for the case n=2 (2 binding sites)
                            :   ---------------------------------------------
                            :
                            :   This current models the "slow" IK[Ca] (IAHP): 
                            :      - potassium current
                            :      - activated by intracellular calcium
                            :      - NOT voltage dependent
                            :
                            :   A minimal value for the time constant has been added
                            :
                            :   Ref: Destexhe et al., J. Neurophysiology 72: 803-818, 1994.
                            :   See also: http://www.cnl.salk.edu/~alain , http://cns.fmed.ulaval.ca
                            :   modifications by Yiota Poirazi 2001 (poirazi@LNC.usc.edu)
			    :   taumin = 0.5 ms instead of 0.1 ms	

                            NEURON {
                                    SUFFIX kca
                                    USEION k READ ek WRITE ik
                                    USEION ca READ cai
                                    RANGE gk, gbar, m_inf, tau_m,ik
                                    GLOBAL beta, cac
                            }


                            UNITS {
                                    (mA) = (milliamp)
                                    (mV) = (millivolt)
                                    (molar) = (1/liter)
                                    (mM) = (millimolar)
                            }


                            PARAMETER {
                                    v               (mV)
                                    celsius = 36    (degC)
                                    ek      = -80   (mV)
                                    cai     = 2.4e-5 (mM)           : initial [Ca]i
                                    gbar    = 0.01   (mho/cm2)
                                    beta    = 0.03   (1/ms)          : backward rate constant
                                    cac     = 0.025  (mM)            : middle point of activation fct
       				    taumin  = 0.5    (ms)            : minimal value of the time cst
                                    gk
                                  }


                            STATE {m}        : activation variable to be solved in the DEs       

                            ASSIGNED {       : parameters needed to solve DE 
                                    ik      (mA/cm2)
                                    m_inf
                                    tau_m   (ms)
                                    tadj
                            }
                            BREAKPOINT { 
                                    SOLVE states METHOD derivimplicit
                                    gk = gbar*m*m*m     : maximum channel conductance
                                    ik = gk*(v - ek)    : potassium current induced by this channel
                            }

                            DERIVATIVE states { 
                                    evaluate_fct(v,cai)
                                    m' = (m_inf - m) / tau_m
                            }

                            UNITSOFF
                            INITIAL {
                            :
                            :  activation kinetics are assumed to be at 22 deg. C
                            :  Q10 is assumed to be 3
                            :
                                    tadj = 3 ^ ((celsius-22.0)/10) : temperature-dependent adjastment factor
                                    evaluate_fct(v,cai)
                                    m = m_inf
                            }

                            PROCEDURE evaluate_fct(v(mV),cai(mM)) {  LOCAL car
                                    car = (cai/cac)^2
                                    m_inf = car / ( 1 + car )      : activation steady state value
                                    tau_m =  1 / beta / (1 + car) / tadj
                                    if(tau_m < taumin) { tau_m = taumin }   : activation min value of time cst
                            }
                            UNITSON

Loading data, please wait...