CA1 pyramidal neuron: effects of R213Q and R312W Kv7.2 mutations (Miceli et al. 2013)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:148094
NEURON mod files from the paper: Miceli et al, Genotype–phenotype correlations in neonatal epilepsies caused by mutations in the voltage sensor of Kv7.2 potassium channel subunits, PNAS 2013 Feb 25. [Epub ahead of print] In this paper, functional studies revealed that in homomeric or heteromeric configuration with KV7.2 and/or KV7.3 subunits, R213W and R213Q mutations markedly destabilized the open state, causing a dramatic decrease in channel voltage sensitivity. Modeling these channels in CA1 hippocampal pyramidal cells revealed that both mutations increased cell firing frequency, with the R213Q mutation prompting more dramatic functional changes compared with the R213W mutation.
Reference:
1 . Miceli F, Soldovieri MV, Ambrosino P, Barrese V, Migliore M, Cilio MR, Taglialatela M (2013) Genotype-phenotype correlations in neonatal epilepsies caused by mutations in the voltage sensor of K(v)7.2 potassium channel subunits. Proc Natl Acad Sci U S A 110:4386-91 [PubMed]
Model Information (Click on a link to find other models with that property)
Model Type: Channel/Receptor; Dendrite;
Brain Region(s)/Organism: Hippocampus;
Cell Type(s): Hippocampus CA1 pyramidal cell;
Channel(s): I Na,t; I A; I K; I M; I Calcium;
Gap Junctions:
Receptor(s):
Gene(s):
Transmitter(s):
Simulation Environment: NEURON;
Model Concept(s): Active Dendrites; Action Potentials; Epilepsy;
Implementer(s): Migliore, Michele [Michele.Migliore at Yale.edu];
Search NeuronDB for information about:  Hippocampus CA1 pyramidal cell; I Na,t; I A; I K; I M; I Calcium;
/
kv72-R213QW-mutations
readme.html
cacumm.mod
cad.mod
cagk.mod *
cal2.mod *
cat.mod *
h.mod *
kadist.mod *
KahpM95.mod *
kaprox.mod *
kdrca1.mod *
kv72wt73wt.mod *
kv72wt73wt72R213Q.mod
kv72wt73wt72R213W.mod
na3n.mod *
naxn.mod *
fig4a.hoc
fixnseg.hoc *
geo9068802.hoc *
mosinit.hoc *
                            
TITLE decay of internal calcium concentration
:
: Internal calcium concentration due to calcium currents and pump.
: Differential equations.
:
: Simple model of ATPase pump with 3 kinetic constants (Destexhe 92)
:     Cai + P <-> CaP -> Cao + P  (k1,k2,k3)
: A Michaelis-Menten approximation is assumed, which reduces the complexity
: of the system to 2 parameters: 
:       kt = <tot enzyme concentration> * k3  -> TIME CONSTANT OF THE PUMP
:	kd = k2/k1 (dissociation constant)    -> EQUILIBRIUM CALCIUM VALUE
: The values of these parameters are chosen assuming a high affinity of 
: the pump to calcium and a low transport capacity (cfr. Blaustein, 
: TINS, 11: 438, 1988, and references therein).  
:
: Units checked using "modlunit" -> factor 10000 needed in ca entry
:
: VERSION OF PUMP + DECAY (decay can be viewed as simplified buffering)
:
: All variables are range variables
:
:
: This mechanism was published in:  Destexhe, A. Babloyantz, A. and 
: Sejnowski, TJ.  Ionic mechanisms for intrinsic slow oscillations in
: thalamic relay neurons. Biophys. J. 65: 1538-1552, 1993)
:
: Written by Alain Destexhe, Salk Institute, Nov 12, 1992
:
: This file was modified by Yiota Poirazi (poirazi@LNC.usc.edu) on April 18, 2001 to account for the sharp
: Ca++ spike repolarization observed in: Golding, N. Jung H-Y., Mickus T. and Spruston N
: "Dendritic Calcium Spike Initiation and Repolarization are controlled by distinct potassium channel
: subtypes in CA1 pyramidal neurons". J. of Neuroscience 19(20) 8789-8798, 1999.
:
:  factor 10000 is replaced by 10000/18 needed in ca entry
:  taur --rate of calcium removal-- is replaced by taur*7 (7 times faster) 

: 20150524 NTC
: Fixed ca initialization by inserting cai = ca into INITIAL block.
: Changed integration method from euler to derivimplicit
: which is appropriate for simple ion accumulation mechanisms.
: See
: Integration methods for SOLVE statements
: http://www.neuron.yale.edu/phpBB/viewtopic.php?f=28&t=592

NEURON {
	SUFFIX cad
	USEION ca READ ica, cai WRITE cai	
        RANGE ca
	GLOBAL depth,cainf,taur
}

UNITS {
	(molar) = (1/liter)			: moles do not appear in units
	(mM)	= (millimolar)
	(um)	= (micron)
	(mA)	= (milliamp)
	(msM)	= (ms mM)
	FARADAY = (faraday) (coulomb)
}


PARAMETER {
	depth	= .1	(um)		: depth of shell
	taur	= 200	(ms)		: rate of calcium removal
	cainf	= 50e-6(mM)
	cai		(mM)
}

STATE {
	ca		(mM) 
}

INITIAL {
	ca = cainf
  cai = ca
}

ASSIGNED {
	ica		(mA/cm2)
	drive_channel	(mM/ms)
}
	
BREAKPOINT {
	SOLVE state METHOD derivimplicit
}

DERIVATIVE state { 
	drive_channel =  - (10000) * ica / (2 * FARADAY * depth)
	if (drive_channel <= 0.) { drive_channel = 0.  }   : cannot pump inward 
         
	ca' = drive_channel/18 + (cainf-ca)/(taur*7)
      : ca' = drive_channel/20 + (cainf -ca)/(taur*9)
	cai = ca
}


Loading data, please wait...