Single compartment Dorsal Lateral Medium Spiny Neuron w/ NMDA and AMPA (Biddell and Johnson 2013)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:150556
A biophysical single compartment model of the dorsal lateral striatum medium spiny neuron is presented here. The model is an implementation then adaptation of a previously described model (Mahon et al. 2002). The model has been adapted to include NMDA and AMPA receptor models that have been fit to dorsal lateral striatal neurons. The receptor models allow for excitation by other neuron models.
Reference:
1 . Biddell K, Johnson J (2013) A Biophysical Model of Cortical Glutamate Excitation of Medium Spiny Neurons in the Dorsal Lateral Striatum 56th IEEE Midwest Symposium on Circuits and Systems
Model Information (Click on a link to find other models with that property)
Model Type: Neuron or other electrically excitable cell; Connectionist Network;
Brain Region(s)/Organism: Basal ganglia;
Cell Type(s): Neostriatum medium spiny direct pathway neuron; Neostriatum spiny neuron;
Channel(s): I Na,p; I K; I K,leak; I A, slow; I_Ks; I Krp; I Na, leak;
Gap Junctions:
Receptor(s): AMPA; NMDA;
Gene(s):
Transmitter(s): Glutamate;
Simulation Environment: NEURON;
Model Concept(s): Detailed Neuronal Models; Short-term Synaptic Plasticity; Parkinson's; Learning; Deep brain stimulation; Olfaction;
Implementer(s): Biddell, Kevin [kevin.biddell at gmail.com];
Search NeuronDB for information about:  Neostriatum medium spiny direct pathway neuron; AMPA; NMDA; I Na,p; I K; I K,leak; I A, slow; I_Ks; I Krp; I Na, leak; Glutamate;
TITLE Basic sodium current
 
COMMENT
 from "Gamma Oscillation by Synaptic Inhibition in a Hippocampal Interneuronal Network Model" (Wang and Buzsaki 1996)
 Used in Role of a Striatal Slowly Inactivating Potassion Current in Short-term Facilitation of Corticostriatal Inputs" A computer Simulation Study" (Mahon et al. 2000)
Implemented by Kevin M. Biddell kevin.biddell@gmail.com
7/11/06

NOTE: 1S=1mho Neuron wants the units in mhos not millisiemens, please note the conversion!

Phi =5 and no q10 or temp adjustment according to Bruno Delord 11/13/06

ENDCOMMENT
 
UNITS {
        (mA) = (milliamp)
        (mV) = (millivolt)
	
}
 
NEURON {
 	SUFFIX Nam
	USEION na WRITE ina
	RANGE gnabar, gna, minf, hinf, ah, Bh
}
 
INDEPENDENT {t FROM 0 TO 1 WITH 1 (ms)}
 
PARAMETER {
  	
	ena	= 55	(mV)
	gnabar	= 0.035 (mho/cm2) : 35mS
	phi	= 5 < 0, 1e9 > : from delord 11/13/06 
	Vam	= -28 :NOT the original value from wang and Buzsaki
	Kam	= 1
	Vbm	= -53 :NOT the original value from wang and Buzsaki
	Kbm	= 18
	Vah	= -51 :NOT the original value from wang and Buzsaki
	Kah	= 20
	Vbh	= -21 :NOT the original value from wang and Buzsaki
	Kbh	= 1
	       
}
 
STATE {
        m h
}
 
ASSIGNED {
        v  (mV)
	ina (mA/cm2)
	celsius		(degC)
 	minf
	hinf
	ah
	Bh
        gna
}
 
BREAKPOINT {
        SOLVE states METHOD cnexp
        gna = gnabar*m^3*h
        ina = gna*(v - ena)
  
}
 
UNITSOFF
 
INITIAL {
	rates(v)
	m = minf
	h= hinf
}

DERIVATIVE states {  :Computes states variable m and h
        rates(v)      :             at the current v and dt.
       
	h'=phi*(ah*(1-h)-Bh*h)

}
 
PROCEDURE rates(v) {  :Computes rate and other constants at current v.
                      :Call once from HOC to initialize inf at resting v.
        LOCAL  am, Bm
        
        
	am = (-0.1*(v-Vam)/Kam/(exp(-0.1*(v-Vam)/Kam)-1))
        Bm = 4*exp(-(v-Vbm)/Kbm)
        ah = 0.07*exp(-(v-Vah)/Kah)
        Bh=  1/(1+exp(-0.1*(v-Vbh)/Kbh))
        minf = am/(am+Bm)
 	hinf = ah/(ah+Bh)
	m=minf      
}
 
UNITSON


Loading data, please wait...