Striatal Output Neuron (Mahon, Deniau, Charpier, Delord 2000)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:150621
Striatal output neurons (SONs) integrate glutamatergic synaptic inputs originating from the cerebral cortex. In vivo electrophysiological data have shown that a prior depolarization of SONs induced a short-term (1 sec)increase in their membrane excitability, which facilitated the ability of corticostriatal synaptic potentials to induce firing. Here we propose, using a computational model of SONs, that the use-dependent, short-term increase in the responsiveness of SONs mainly results from the slow kinetics of a voltage-dependent, slowly inactivating potassium A-current. This mechanism confers on SONs a form of intrinsic short-term memory that optimizes the synaptic input–output relationship as a function of their past activation.
Reference:
1 . Mahon S, Deniau JM, Charpier S, Delord B (2000) Role of a striatal slowly inactivating potassium current in short-term facilitation of corticostriatal inputs: a computer simulation study. Learn Mem 7:357-62 [PubMed]
Model Information (Click on a link to find other models with that property)
Model Type: Neuron or other electrically excitable cell;
Brain Region(s)/Organism:
Cell Type(s): Neostriatum spiny direct pathway neuron; Abstract Wang-Buzsaki neuron;
Channel(s): I Na,p; I Na,t; I K; I_Ks; I Krp;
Gap Junctions:
Receptor(s):
Gene(s):
Transmitter(s):
Simulation Environment: NEURON;
Model Concept(s): Action Potential Initiation; Ion Channel Kinetics; Short-term Synaptic Plasticity;
Implementer(s): Biddell, Kevin [kevin.biddell at gmail.com];
Search NeuronDB for information about:  Neostriatum spiny direct pathway neuron; I Na,p; I Na,t; I K; I_Ks; I Krp;
/
MahonEtAl2000
README.html
KAfm.mod *
KAsm.mod *
Kirm.mod
Km.mod *
Krpm.mod *
Leakm.mod
Nam.mod *
NaPm.mod *
NaSm.mod *
figure2a.ses
figure3a.ses
Figures2B3B.xls
init.hoc
kmb.mahon.1.hoc
mosinit.hoc *
screenshot2A.png
screenshot3Aa.png
screenshot3Ab.png
                            
TITLE A Slow A-type Potassium current
 
COMMENT
  Used in Role of a Striatal Slowly Inactivating Potassion Current in Short-term 
  Facilitation of Corticostriatal Inputs" A computer Simulation Study" (Mahon et al. 2000)
  Implemented by Kevin M. Biddell kevin.biddell@gmail.com
  7/13/06
NOTE: 1S=1mho Neuron wants the units in mhos not millisiemens, please note the conversion!
ENDCOMMENT
 
UNITS {
        (mA) = (milliamp)
        (mV) = (millivolt)
}
 
NEURON {
 	SUFFIX KAsm
	USEION k WRITE ik
	RANGE gkasmbar, gkasm, minf, hinf, mtau, htau
}
 
INDEPENDENT {t FROM 0 TO 1 WITH 1 (ms)}
 
PARAMETER {
  	
	ek	= -85	(mV)
	gkasmbar= 0.00032 (mho/cm2) :0.32mS
	Etemp	= 22  : Delord correspondence 11/15/06 and fitting

	Vsm	= -25.6
	ksm	= 13.3
	Vsh	= -78.8
	ksh	= -10.4
	tom	= 131.4
	Vtm	= -37.4
	ktm	= 27.3
	Vth	= -38.2
	kth	= 28
	hint	= 0.46     : Delord correspondence 11/15/06 = 0.2968

}
 
STATE {
        m h
}
 
ASSIGNED {
	v  (mV)
        ik (mA/cm2)
	celsius		(degC)
 	minf
	hinf
	mtau
	htau
	gkasm
}
 
BREAKPOINT {
        SOLVE states METHOD cnexp
        gkasm = gkasmbar*m*h
        ik = gkasm*(v - ek)
  
}
 
UNITSOFF
 
INITIAL {
	rates(v)
	m= minf
	h= hint
}

DERIVATIVE states {  :Computes states variable m at the current v and dt.
        rates(v)      
       
	m' = ( minf - m ) / mtau
	h' = (hinf - h ) / htau
}
 
PROCEDURE rates(v) {  :Computes rate and other constants at current v. Call once from HOC to initialize inf at resting v.
        LOCAL  q10, tadj
        q10 = 2.5
	tadj=q10^((celsius-Etemp)/10)
        minf=1/(1+exp(-(v-Vsm)/ksm))
	hinf=1/(1+exp(-(v-Vsh)/ksh))
	mtau=tom/(exp(-(v-Vtm)/ktm)+exp((v-Vtm)/ktm))/tadj
	htau=(1790+2930*exp(-((v-Vth)/kth)^2)*((v-Vth)/kth))/tadj
	      
}
 
UNITSON


Loading data, please wait...