DRt neuron model (Sousa et al., 2014)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:151949
Despite the importance and significant clinical impact of understanding information processing in the nociceptive system, the functional properties of neurons in many parts of this system are still unknown. In this work we performed whole-cell patch-clamp recording in rat brainstem blocks to characterize the electrophysiological properties of neurons in the dorsal reticular nucleus (DRt), a region known to be involved in pronociceptive modulation. We also compared properties of DRt neurons with those in the adjacent parvicellular reticular nucleus (PCRt) and in neighboring regions outside the reticular formation. We found that neurons in the DRt and PCRt had similar electrophysiological properties and exhibited mostly tonic-like firing patterns, whereas neurons outside the reticular formation showed a larger diversity of firing-patterns. The dominance of tonic neurons in the DRt supports previous conclusions that these neurons encode stimulus intensity through their firing frequency.
Reference:
1 . Sousa M, Szucs P, Lima D, Aguiar P (2014) The pronociceptive dorsal reticular nucleus contains mostly tonic neurons and shows a high prevalence of spontaneous activity in block preparation. J Neurophysiol 111:1507-18 [PubMed]
Model Information (Click on a link to find other models with that property)
Model Type: Neuron or other electrically excitable cell;
Brain Region(s)/Organism:
Cell Type(s): Hodgkin-Huxley neuron;
Channel(s): I Na,t; I K; I K,Ca; I Calcium;
Gap Junctions:
Receptor(s):
Gene(s):
Transmitter(s):
Simulation Environment: NEURON;
Model Concept(s): Activity Patterns;
Implementer(s): Aguiar, Paulo [pauloaguiar at fc.up.pt];
Search NeuronDB for information about:  I Na,t; I K; I K,Ca; I Calcium;
TITLE Slow Ca-dependent cation current
:
:   Ca++ dependent nonspecific cation current ICAN
:   Differential equations
:
:   Model based on a first order kinetic scheme
:
:      <closed> + n cai <-> <open>	(alpha,beta)
:
:   Following this model, the activation fct will be half-activated at 
:   a concentration of Cai = (beta/alpha)^(1/n) = cac (parameter)
:
:   The mod file is here written for the case n=2 (2 binding sites)
:   ---------------------------------------------
:
:   Kinetics based on: Partridge & Swandulla, TINS 11: 69-72, 1988.
:
:   This current has the following properties:
:      - inward current (non specific for cations Na, K, Ca, ...)
:      - activated by intracellular calcium
:      - NOT voltage dependent
:
:   A minimal value for the time constant has been added
:
:   Ref: Destexhe et al., J. Neurophysiology 72: 803-818, 1994.
:
:   Modifications by Arthur Houweling for use in MyFirstNEURON
:
:   Some parameter changes by Paulo Aguiar (pauloaguiar@fc.up.pt):
:   tau_factor = 40 => parameter beta	changes from 2.0e-3 to 5.0e-5
:		cac = 0.5e-3 (before was 1.0e-3)

INDEPENDENT {t FROM 0 TO 1 WITH 1 (ms)}

NEURON {
	SUFFIX iCaAN
	USEION can READ ecan WRITE ican VALENCE 1
	USEION ca READ cai
        RANGE gbar, m_inf, tau_m
	RANGE ican
	GLOBAL beta, cac, taumin
}


UNITS {
	(mA) = (milliamp)
	(mV) = (millivolt)
	(molar) = (1/liter)
	(mM) = (millimolar)
}


PARAMETER {
	v		  (mV)
	celsius		  (degC)
        dt                (ms)
	ecan	= -20	  (mV)		: reversal potential
	cai		  (mM)
	gbar	= 0.00025 (mho/cm2)
	beta	= 2.0e-3  (1/ms)	: backward rate constant (original value)

	tau_factor = 40         : scaling factor allowing tuning

	:cac	= 1.0e-3  (mM)		: middle point of activation fct  (original value)
	cac		= 5e-4	  (mM)		: middle point of activation fct

	taumin	= 0.1	  (ms)		: minimal value of time constant
	
	:parameter tau_factor and cac were set to produce tau_m ~ 2000(ms) at cai=cac and celsius=36;
	:implications of parameters change when cai=cac:
	: -> BEFORE (beta=2.0e-3;tadj=4.66) => tau_m ~ 50   ms
	: -> AFTER  (beta=5.0e-5;tadj=4.66) => tau_m ~ 2000 ms
	:
	:also cac was reduced to half, from 1.0 uM to 0.5 uM
}


STATE {
	m
}

ASSIGNED {
	ican	(mA/cm2)
	m_inf
	tau_m	(ms)
	tadj
}

BREAKPOINT { 
	SOLVE states :METHOD euler
	ican = gbar * m*m * (v - ecan)
}

:DERIVATIVE states {
:       evaluate_fct(v,cai)
:
:       m'= (m_inf-m) / tau_m 
:}
  
PROCEDURE states() {
        evaluate_fct(v,cai)
	
        m = m + ( 1-exp(-dt/tau_m) )*(m_inf-m)
	:printf("\n iCAN tau_m=%g", tau_m)

}

UNITSOFF
INITIAL {
:
:  activation kinetics are assumed to be at 22 deg. C
:  Q10 is assumed to be 3
:
	tadj = 3.0 ^ ((celsius-22.0)/10)

	evaluate_fct(v,cai)
	m = m_inf
}


PROCEDURE evaluate_fct(v(mV),cai(mM)) {  LOCAL alpha2

	alpha2 = beta * (cai/cac)^2
	
	tau_m = tau_factor / (alpha2 + beta) / tadj		: tau_m = tau_factor / ( beta * (1 + (cai/cac)^2) ) / tadj
	
	m_inf = alpha2 / (alpha2 + beta)							: m_inf = (cai/cac)^2 / ( 1 + (cai/cac)^2 )

	if(tau_m < taumin) { tau_m = taumin }					: min value of time cst

}
UNITSON

Loading data, please wait...