Dentate gyrus network model (Tejada et al 2014)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:155568
" ... Here we adapted an existing computational model of the dentate gyrus (J Neurophysiol 93: 437-453, 2005) by replacing the reduced granule cell models with morphologically detailed models coming from (3D) reconstructions of mature cells. ... Different fractions of the mature granule cell models were replaced by morphologically reconstructed models of newborn dentate granule cells from animals with PILO-induced Status Epilepticus, which have apical dendritic alterations and spine loss, and control animals, which do not have these alterations. This complex arrangement of cells and processes allowed us to study the combined effect of mossy fiber sprouting, altered apical dendritic tree and dendritic spine loss in newborn granule cells on the excitability of the dentate gyrus model. Our simulations suggest that alterations in the apical dendritic tree and dendritic spine loss in newborn granule cells have opposing effects on the excitability of the dentate gyrus after Status Epilepticus. Apical dendritic alterations potentiate the increase of excitability provoked by mossy fiber sprouting while spine loss curtails this increase. "
References:
1 . Tejada J, Garcia-Cairasco N, Roque AC (2014) Combined role of seizure-induced dendritic morphology alterations and spine loss in newborn granule cells with mossy fiber sprouting on the hyperexcitability of a computer model of the dentate gyrus. PLoS Comput Biol 10:e1003601 [PubMed]
2 . Tejada J, Arisi GM, Garci­a-Cairasco N, Roque AC (2012) Morphological alterations in newly born dentate gyrus granule cells that emerge after status epilepticus contribute to make them less excitable. PLoS One 7:e40726-78 [PubMed]
Model Information (Click on a link to find other models with that property)
Model Type: Realistic Network;
Brain Region(s)/Organism: Dentate gyrus;
Cell Type(s): Dentate gyrus granule cell; Dentate gyrus mossy cell; Dentate gyrus basket cell; Dentate gyrus hilar cell;
Channel(s): I L high threshold; I T low threshold; I K; I h; I K,Ca; I Calcium; I Potassium;
Gap Junctions:
Receptor(s):
Gene(s):
Transmitter(s):
Simulation Environment: NEURON;
Model Concept(s): Activity Patterns; Spatio-temporal Activity Patterns; Epilepsy; Neurogenesis;
Implementer(s): Tejada, Julian [julian.tejada at gmail.com];
Search NeuronDB for information about:  Dentate gyrus granule cell; I L high threshold; I T low threshold; I K; I h; I K,Ca; I Calcium; I Potassium;
/
TejadaEtAl2014
readme.html
bgka.mod *
CaBK.mod *
ccanl.mod *
Gfluct2.mod *
gskch.mod *
hyperde3.mod *
ichan2.mod *
LcaMig.mod *
nca.mod *
tca.mod *
BasketCell.hoc
DG.hoc
HIPPCell.hoc
init.hoc
mosinit.hoc
MossyCell.hoc
n01.hoc
n02.hoc
n03.hoc
n04.hoc
n05.hoc
n06.hoc
n07.hoc
n08.hoc
n09.hoc
n10.hoc
n100.hoc
n101.hoc
n102.hoc
n103.hoc
n104.hoc
n105.hoc
n106.hoc
n107.hoc
n108.hoc
n109.hoc
n11.hoc
n110.hoc
n111.hoc
n112.hoc
n113.hoc
n114.hoc
n115.hoc
n116.hoc
n117.hoc
n118.hoc
n12.hoc
n13.hoc
n14.hoc
n15.hoc
n16.hoc
n17.hoc
n18.hoc
n19.hoc
n20.hoc
n21.hoc
n22.hoc
n23.hoc
n24.hoc
n25.hoc
n26.hoc
n27.hoc
n28.hoc
n29.hoc
n30.hoc
n31.hoc
n32.hoc
n33.hoc
n34.hoc
n35.hoc
n36.hoc
n37.hoc
n38.hoc
n39.hoc
n40.hoc
n41.hoc
n42.hoc
n43.hoc
n44.hoc
n45.hoc
n46.hoc
n47.hoc
n48.hoc
n49.hoc
n50.hoc
n51.hoc
n52.hoc
n53.hoc
n54.hoc
n55.hoc
n56.hoc
n57.hoc
n58.hoc
n59.hoc
n60.hoc
n61.hoc
n62.hoc
n63.hoc
n64.hoc
n65.hoc
n66.hoc
n67.hoc
n68.hoc
n69.hoc
n70.hoc
n71.hoc
n72.hoc
n73.hoc
n74.hoc
n75.hoc
n76.hoc
n77.hoc
n78.hoc
n79.hoc
n80.hoc
n81.hoc
n82.hoc
n83.hoc
n84.hoc
n85.hoc
n86.hoc
n87.hoc
n88.hoc
n89.hoc
n90.hoc
n91.hoc
n92.hoc
n93.hoc
n94.hoc
n95.hoc
n96.hoc
n97.hoc
n98.hoc
n99.hoc
NumberOfDendrites.dat
Sample_100A0Y.dat
Sample_50A50P.dat
Sample_50A50Y.dat
screenshot.png
SimCtrl.ses
                            
TITLE Fluctuating conductances

COMMENT
-----------------------------------------------------------------------------

	Fluctuating conductance model for synaptic bombardment
	======================================================

THEORY

  Synaptic bombardment is represented by a stochastic model containing
  two fluctuating conductances g_e(t) and g_i(t) descibed by:

     Isyn = g_e(t) * [V - E_e] + g_i(t) * [V - E_i]
     d g_e / dt = -(g_e - g_e0) / tau_e + sqrt(D_e) * Ft
     d g_i / dt = -(g_i - g_i0) / tau_i + sqrt(D_i) * Ft

  where E_e, E_i are the reversal potentials, g_e0, g_i0 are the average
  conductances, tau_e, tau_i are time constants, D_e, D_i are noise diffusion
  coefficients and Ft is a gaussian white noise of unit standard deviation.

  g_e and g_i are described by an Ornstein-Uhlenbeck (OU) stochastic process
  where tau_e and tau_i represent the "correlation" (if tau_e and tau_i are 
  zero, g_e and g_i are white noise).  The estimation of OU parameters can
  be made from the power spectrum:

     S(w) =  2 * D * tau^2 / (1 + w^2 * tau^2)

  and the diffusion coeffient D is estimated from the variance:

     D = 2 * sigma^2 / tau


NUMERICAL RESOLUTION

  The numerical scheme for integration of OU processes takes advantage 
  of the fact that these processes are gaussian, which led to an exact
  update rule independent of the time step dt (see Gillespie DT, Am J Phys 
  64: 225, 1996):

     x(t+dt) = x(t) * exp(-dt/tau) + A * N(0,1)

  where A = sqrt( D*tau/2 * (1-exp(-2*dt/tau)) ) and N(0,1) is a normal
  random number (avg=0, sigma=1)


IMPLEMENTATION

  This mechanism is implemented as a nonspecific current defined as a
  point process.


PARAMETERS

  The mechanism takes the following parameters:

     E_e = 0  (mV)		: reversal potential of excitatory conductance
     E_i = -75 (mV)		: reversal potential of inhibitory conductance

     g_e0 = 0.0121 (umho)	: average excitatory conductance
     g_i0 = 0.0573 (umho)	: average inhibitory conductance

     std_e = 0.0030 (umho)	: standard dev of excitatory conductance
     std_i = 0.0066 (umho)	: standard dev of inhibitory conductance

     tau_e = 2.728 (ms)		: time constant of excitatory conductance
     tau_i = 10.49 (ms)		: time constant of inhibitory conductance


Gfluct2: conductance cannot be negative


REFERENCE

  Destexhe, A., Rudolph, M., Fellous, J-M. and Sejnowski, T.J.  
  Fluctuating synaptic conductances recreate in-vivo--like activity in
  neocortical neurons. Neuroscience 107: 13-24 (2001).

  (electronic copy available at http://cns.iaf.cnrs-gif.fr)


  A. Destexhe, 1999

-----------------------------------------------------------------------------
ENDCOMMENT



INDEPENDENT {t FROM 0 TO 1 WITH 1 (ms)}

NEURON {
	POINT_PROCESS Gfluct2
	RANGE g_e, g_i, E_e, E_i, g_e0, g_i0, g_e1, g_i1
	RANGE std_e, std_i, tau_e, tau_i, D_e, D_i
	RANGE new_seed
	NONSPECIFIC_CURRENT i
}

UNITS {
	(nA) = (nanoamp) 
	(mV) = (millivolt)
	(umho) = (micromho)
}

PARAMETER {
	dt		(ms)

	E_e	= 0 	(mV)	: reversal potential of excitatory conductance
	E_i	= -75 	(mV)	: reversal potential of inhibitory conductance

	g_e0	= 0.0121 (umho)	: average excitatory conductance
	g_i0	= 0.0573 (umho)	: average inhibitory conductance

	std_e	= 0.0030 (umho)	: standard dev of excitatory conductance
	std_i	= 0.0066 (umho)	: standard dev of inhibitory conductance

	tau_e	= 2.728	(ms)	: time constant of excitatory conductance
	tau_i	= 10.49	(ms)	: time constant of inhibitory conductance
}

ASSIGNED {
	v	(mV)		: membrane voltage
	i 	(nA)		: fluctuating current
	g_e	(umho)		: total excitatory conductance
	g_i	(umho)		: total inhibitory conductance
	g_e1	(umho)		: fluctuating excitatory conductance
	g_i1	(umho)		: fluctuating inhibitory conductance
	D_e	(umho umho /ms) : excitatory diffusion coefficient
	D_i	(umho umho /ms) : inhibitory diffusion coefficient
	exp_e
	exp_i
	amp_e	(umho)
	amp_i	(umho)
}

INITIAL {
	g_e1 = 0
	g_i1 = 0
	if(tau_e != 0) {
		D_e = 2 * std_e * std_e / tau_e
		exp_e = exp(-dt/tau_e)
		amp_e = std_e * sqrt( (1-exp(-2*dt/tau_e)) )
	}
	if(tau_i != 0) {
		D_i = 2 * std_i * std_i / tau_i
		exp_i = exp(-dt/tau_i)
		amp_i = std_i * sqrt( (1-exp(-2*dt/tau_i)) )
	}
}

BREAKPOINT {
	SOLVE oup
	if(tau_e==0) {
	   g_e = std_e * normrand(0,1)
	}
	if(tau_i==0) {
	   g_i = std_i * normrand(0,1)
	}
	g_e = g_e0 + g_e1
	if(g_e < 0) { g_e = 0 }
	g_i = g_i0 + g_i1
	if(g_i < 0) { g_i = 0 }
	i = g_e * (v - E_e) + g_i * (v - E_i)
}


PROCEDURE oup() {		: use Scop function normrand(mean, std_dev)
   if(tau_e!=0) {
	g_e1 =  exp_e * g_e1 + amp_e * normrand(0,1)
   }
   if(tau_i!=0) {
	g_i1 =  exp_i * g_i1 + amp_i * normrand(0,1)
   }
}


PROCEDURE new_seed(seed) {		: procedure to set the seed
	set_seed(seed)
	VERBATIM
	  printf("Setting random generator with seed = %g\n", _lseed);
	ENDVERBATIM
}


Loading data, please wait...