Microcircuits of L5 thick tufted pyramidal cells (Hay & Segev 2015)

 Download zip file 
Help downloading and running models
Accession:156780
"... We simulated detailed conductance-based models of TTCs (Layer 5 thick tufted pyramidal cells) forming recurrent microcircuits that were interconnected as found experimentally; the network was embedded in a realistic background synaptic activity. ... Our findings indicate that dendritic nonlinearities are pivotal in controlling the gain and the computational functions of TTCs microcircuits, which serve as a dominant output source for the neocortex. "
Reference:
1 . Hay E, Segev I (2015) Dendritic excitability and gain control in recurrent cortical microcircuits Cerebral Cortex 25(10):3561-3571 [PubMed]
Model Information (Click on a link to find other models with that property)
Model Type: Realistic Network; Dendrite;
Brain Region(s)/Organism: Neocortex;
Cell Type(s): Neocortex V1 L6 pyramidal corticothalamic cell;
Channel(s): I Na,p; I Na,t; I L high threshold; I T low threshold; I A; I M; I h; I K,Ca; I A, slow;
Gap Junctions:
Receptor(s): GabaA; AMPA; NMDA; Glutamate;
Gene(s):
Transmitter(s): Gaba; Glutamate;
Simulation Environment: NEURON;
Model Concept(s): Dendritic Action Potentials; Active Dendrites; Detailed Neuronal Models; Laminar Connectivity; Orientation selectivity;
Implementer(s): Hay, Etay [etay.hay at mail.huji.ac.il];
Search NeuronDB for information about:  Neocortex V1 L6 pyramidal corticothalamic cell; GabaA; AMPA; NMDA; Glutamate; I Na,p; I Na,t; I L high threshold; I T low threshold; I A; I M; I h; I K,Ca; I A, slow; Gaba; Glutamate;
/
HaySegev2014
models
readme.txt
Ca_HVA.mod *
Ca_LVAst.mod *
CaDynamics_E2.mod *
epsp.mod *
Ih.mod *
Im.mod *
K_Pst.mod *
K_Tst.mod *
Nap_Et2.mod *
NaTa_t.mod *
NaTs2_t.mod *
ProbAMPANMDA2.mod
ProbUDFsyn2.mod *
SK_E2.mod *
SKv3_1.mod *
cell1.asc *
microcircuit.hoc
                            
:Comment : The persistent component of the K current
:Reference : :		Voltage-gated K+ channels in layer 5 neocortical pyramidal neurones from young rats:subtypes and gradients,Korngreen and Sakmann, J. Physiology, 2000
:Comment : shifted -10 mv to correct for junction potential
:Comment: corrected rates using q10 = 2.3, target temperature 34, orginal 21


NEURON	{
	SUFFIX K_Pst
	USEION k READ ek WRITE ik
	RANGE gK_Pstbar, gK_Pst, ik
}

UNITS	{
	(S) = (siemens)
	(mV) = (millivolt)
	(mA) = (milliamp)
}

PARAMETER	{
	gK_Pstbar = 0.00001 (S/cm2)
}

ASSIGNED	{
	v	(mV)
	ek	(mV)
	ik	(mA/cm2)
	gK_Pst	(S/cm2)
	mInf
	mTau
	hInf
	hTau
}

STATE	{
	m
	h
}

BREAKPOINT	{
	SOLVE states METHOD cnexp
	gK_Pst = gK_Pstbar*m*m*h
	ik = gK_Pst*(v-ek)
}

DERIVATIVE states	{
	rates()
	m' = (mInf-m)/mTau
	h' = (hInf-h)/hTau
}

INITIAL{
	rates()
	m = mInf
	h = hInf
}

PROCEDURE rates(){
  LOCAL qt
  qt = 2.3^((34-21)/10)
	UNITSOFF
		v = v + 10
		mInf =  (1/(1 + exp(-(v+1)/12)))
        if(v<-50){
		    mTau =  (1.25+175.03*exp(-v * -0.026))/qt
        }else{
            mTau = ((1.25+13*exp(-v*0.026)))/qt
        }
		hInf =  1/(1 + exp(-(v+54)/-11))
		hTau =  (360+(1010+24*(v+55))*exp(-((v+75)/48)^2))/qt
		v = v - 10
	UNITSON
}

Loading data, please wait...