Firing neocortical layer V pyramidal neuron (Reetz et al. 2014; Stadler et al. 2014)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:168148
Neocortical Layer V model with firing behaviour adjusted to in vitro observations. The model was used to investigate the effects of IFN and PKC on the excitability of neurons (Stadler et al 2014, Reetz et al. 2014). The model contains new channel simulations for HCN1, HCN2 and the big calcium dependent potassium channel BK.
References:
1 . Stadler K, Bierwirth C, Stoenica L, Battefeld A, Reetz O, Mix E, Schuchmann S, Velmans T, Rosenberger K, Bräuer AU, Lehnardt S, Nitsch R, Budt M, Wolff T, Kole MH, Strauss U (2014) Elevation in type I interferons inhibits HCN1 and slows cortical neuronal oscillations. Cereb Cortex 24:199-210 [PubMed]
2 . Reetz O, Stadler K, Strauss U (2014) Protein kinase C activation mediates interferon-ß-induced neuronal excitability changes in neocortical pyramidal neurons. J Neuroinflammation 11:185 [PubMed]
Model Information (Click on a link to find other models with that property)
Model Type: Neuron or other electrically excitable cell;
Brain Region(s)/Organism: Neocortex;
Cell Type(s): Neocortex L5/6 pyramidal GLU cell;
Channel(s): I Na,p; I Na,t; I L high threshold; I A; I K; I M; I h; I K,Ca; I Sodium; I Calcium; I Mixed; I Potassium; I Q;
Gap Junctions:
Receptor(s):
Gene(s): HCN1; HCN2;
Transmitter(s):
Simulation Environment: NEURON;
Model Concept(s): Activity Patterns; Detailed Neuronal Models; Action Potentials; Signaling pathways;
Implementer(s): Stadler, Konstantin [konstantin.stadler at ntnu.no];
Search NeuronDB for information about:  Neocortex L5/6 pyramidal GLU cell; I Na,p; I Na,t; I L high threshold; I A; I K; I M; I h; I K,Ca; I Sodium; I Calcium; I Mixed; I Potassium; I Q;
:26 Ago 2002 Modification of original channel to allow
: variable time step and to correct an initialization error.
:    Done by Michael Hines(michael.hines@yale.edu) and Ruggero Scorcioni(rscorcio@gmu.edu)
: at EU Advance Course in Computational Neuroscience. Obidos, Portugal

TITLE decay of internal calcium concentration
:
: Internal calcium concentration due to calcium currents and pump.
: Differential equations.
:
: Simple model of ATPase pump with 3 kinetic constants (Destexhe 92)
:     Cai + P <-> CaP -> Cao + P  (k1,k2,k3)
: A Michaelis-Menten approximation is assumed, which reduces the complexity
: of the system to 2 parameters: 
:       kt = <tot enzyme concentration> * k3  -> TIME CONSTANT OF THE PUMP
:	kd = k2/k1 (dissociation constant)    -> EQUILIBRIUM CALCIUM VALUE
: The values of these parameters are chosen assuming a high affinity of 
: the pump to calcium and a low transport capacity (cfr. Blaustein, 
: TINS, 11: 438, 1988, and references therein).  
:
: Units checked using "modlunit" -> factor 10000 needed in ca entry
:
: VERSION OF PUMP + DECAY (decay can be viewed as simplified buffering)
:
: All variables are range variables
:
:
: This mechanism was published in:  Destexhe, A. Babloyantz, A. and 
: Sejnowski, TJ.  Ionic mechanisms for intrinsic slow oscillations in
: thalamic relay neurons. Biophys. J. 65: 1538-1552, 1993)
:
: Written by Alain Destexhe, Salk Institute, Nov 12, 1992
:
: Konstantin Stadler 2010 change: castart for test purposes
:
: 20150525 NTC
: Changed integration method from euler to derivimplicit
: which is appropriate for simple ion accumulation mechanisms.
: See
: Integration methods for SOLVE statements
: http://www.neuron.yale.edu/phpBB/viewtopic.php?f=28&t=592

NEURON {
	SUFFIX cad
	USEION ca READ ica, cai WRITE cai
	RANGE ca
	GLOBAL depth,cainf,taur
}

UNITS {
	(molar) = (1/liter)			: moles do not appear in units
	(mM)	= (millimolar)
	(um)	= (micron)
	(mA)	= (milliamp)
	(msM)	= (ms mM)
	FARADAY = (faraday) (coulomb)
}

PARAMETER {
	depth	= .1	(um)		: depth of shell
	taur	= 200	(ms)		: rate of calcium removal
	cainf	= 100e-6(mM)
	cai		(mM)
	castart = 100e-6(mM)		:for test purposes
}

STATE {
	ca		(mM) <1e-5>
}

INITIAL {
	ca = castart
	cai = ca
}

ASSIGNED {
	ica		(mA/cm2)
	drive_channel	(mM/ms)
}
	
BREAKPOINT {
        SOLVE state METHOD derivimplicit : not euler
    : see http://www.neuron.yale.edu/phpBB/viewtopic.php?f=28&t=592
}

DERIVATIVE state { 
	drive_channel =  - (10000) * ica / (2 * FARADAY * depth)
	if (drive_channel <= 0.) { drive_channel = 0. }	: cannot pump inward

	ca' = drive_channel + (cainf-ca)/taur
	cai = ca
}


Loading data, please wait...