Pyramidal neuron, fast, regular, and irregular spiking interneurons (Konstantoudaki et al 2014)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:168310
This is a model network of prefrontal cortical microcircuit based primarily on rodent data. It includes 16 pyramidal model neurons, 2 fast spiking interneuron models, 1 regular spiking interneuron model and 1 irregular spiking interneuron model. The goal of the paper was to use this model network to determine the role of specific interneuron subtypes in persistent activity
Reference:
1 . Konstantoudaki X, Papoutsi A, Chalkiadaki K, Poirazi P, Sidiropoulou K (2014) Modulatory effects of inhibition on persistent activity in a cortical microcircuit model. Front Neural Circuits 8:7 [PubMed]
Model Information (Click on a link to find other models with that property)
Model Type: Realistic Network; Neuron or other electrically excitable cell;
Brain Region(s)/Organism:
Cell Type(s): Neocortex fast spiking (FS) interneuron; Neocortex spiking regular (RS) neuron; Neocortex spiking low threshold (LTS) neuron; Neocortex spiking irregular interneuron;
Channel(s): I Na,p; I Na,t; I L high threshold; I T low threshold; I A; I K; I h; I_Ks; I_KD;
Gap Junctions:
Receptor(s): GabaA; GabaB; AMPA; NMDA;
Gene(s):
Transmitter(s): Gaba; Glutamate;
Simulation Environment: NEURON;
Model Concept(s): Activity Patterns; Synchronization; Active Dendrites;
Implementer(s): Sidiropoulou, Kyriaki [sidirop at imbb.forth.gr]; Konstantoudaki, Xanthippi [xeniakons at gmail.com];
Search NeuronDB for information about:  GabaA; GabaB; AMPA; NMDA; I Na,p; I Na,t; I L high threshold; I T low threshold; I A; I K; I h; I_Ks; I_KD; Gaba; Glutamate;
/
KonstantoudakiEtAl2014
experiment
data
ampa.mod *
ampain.mod *
cadyn.mod *
cadynin.mod *
cal.mod *
calc.mod *
calcb.mod *
can.mod *
cancr.mod *
canin.mod *
car.mod *
cat.mod *
catcb.mod *
gabaa.mod *
gabaain.mod *
gabab.mod *
h.mod *
hcb.mod *
hin.mod *
ican.mod *
iccb.mod *
iccr.mod *
icin.mod *
iks.mod *
ikscb.mod *
ikscr.mod *
iksin.mod *
kadist.mod *
kadistcr.mod *
kadistin.mod *
kaprox.mod *
kaproxcb.mod *
kaproxin.mod *
kca.mod *
kcain.mod *
kct.mod *
kctin.mod *
kdr.mod *
kdrcb.mod *
kdrcr.mod *
kdrin.mod *
naf.mod *
nafcb.mod *
nafcr.mod *
nafin.mod *
nafx.mod *
nap.mod *
netstim.mod *
NMDA.mod *
NMDAIN.mod *
sinclamp.mod *
cb.hoc
cr.hoc
ExperimentControl.hoc *
final.hoc
incell.hoc
net.hoc
pfc_pc_temp.hoc
run
run_orig
                            
                             TITLE Slow Ca-dependent cation current
                             :
                             :   Ca++ dependent nonspecific cation current ICAN
                             :   Differential equations
                             :
                             :   Model based on a first order kinetic scheme
                             :
                             :       + n cai <->     (alpha,beta)
                             :
                             :   Following this model, the activation fct will be half-activated at 
                             :   a concentration of Cai = (beta/alpha)^(1/n) = cac (parameter)
                             :
                             :   The mod file is here written for the case n=2 (2 binding sites)
                             :   ---------------------------------------------
                             :
                             :   Kinetics based on: Partridge & Swandulla, TINS 11: 69-72, 1988.
                             :
                             :   This current has the following properties:
                             :      - inward current (non specific for cations Na, K, Ca, ...)
                             :      - activated by intracellular calcium
                             :      - NOT voltage dependent
                             :
                             :   A minimal value for the time constant has been added
                             :
                             :   Ref: Destexhe et al., J. Neurophysiology 72: 803-818, 1994.
                             :   See also:  http://www.cnl.salk.edu/~alain , http://cns.fmed.ulaval.ca
                             :

                             INDEPENDENT {t FROM 0 TO 1 WITH 1 (ms)}

                             NEURON {
                                     SUFFIX ican
                                     USEION n READ en WRITE in VALENCE 1
                                     USEION ca READ cai
				     USEION na WRITE ina
                                     RANGE gbar, m_inf, tau_m, in
                                     GLOBAL beta, cac, taumin
                             }


                             UNITS {
                                     (mA) = (milliamp)
                                     (mV) = (millivolt)
                                     (molar) = (1/liter)
                                     (mM) = (millimolar)
                             }


                             PARAMETER {
                                     v               (mV)
                                     celsius = 36    (degC)
                                     en      = -20   (mV)            	: reversal potential
                                     cai     	     (mM)           	: initial [Ca]i
                                     gbar    = 0.00025 (mho/cm2)
                                     beta = 0.0003                      :0.001   :0.004      :Since Aprile 2008
                                     cac = 0.0001                         :Since Aprile 2008

                                     taumin  = 0.1   (ms)            	: minimal value of time constant
                             }


                             STATE {
                                     m
                             }

                             ASSIGNED {
                                     in      (mA/cm2)
				     ina     (mA/cm2)
                                     m_inf
                                     tau_m   (ms)
                                     tadj
                             }

                             BREAKPOINT { 
                                     SOLVE states METHOD euler
                                     in = gbar * m*m * (v - en)
				     ina = 0.7* in
                             }

                             DERIVATIVE states { 
                                     evaluate_fct(v,cai)

                                     m' = (m_inf - m) / tau_m
                             }

                             UNITSOFF
                             INITIAL {
                             :
                             :  activation kinetics are assumed to be at 22 deg. C
                             :  Q10 is assumed to be 3
                             :
                                     tadj = 3 ^ ((celsius-22.0)/10)

                                     evaluate_fct(v,cai)
                                     m = m_inf
                             }


                             PROCEDURE evaluate_fct(v(mV),cai(mM)) {  LOCAL alpha2

                                     alpha2 = beta * (cai/cac)^2

                                     tau_m = 1 / (alpha2 + beta) / tadj
                                     m_inf = alpha2 / (alpha2 + beta)

                                     if(tau_m < taumin) { tau_m = taumin }   : min value of time cst
                             }
                             UNITSON

Loading data, please wait...