Effects of spinal cord stimulation on WDR dorsal horn network (Zhang et al 2014)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:168414
" ... To study the mechanisms underlying SCS (Spinal cord stimulation), we constructed a biophysically-based network model of the dorsal horn circuit consisting of interconnected dorsal horn interneurons and a wide dynamic range (WDR) projection neuron and representations of both local and surround receptive field inhibition. We validated the network model by reproducing cellular and network responses relevant to pain processing including wind-up, A-fiber mediated inhibition, and surround receptive field inhibition. ..." See paper for more.
Reference:
1 . Zhang TC, Janik JJ, Grill WM (2014) Modeling effects of spinal cord stimulation on wide-dynamic range dorsal horn neurons: influence of stimulation frequency and GABAergic inhibition. J Neurophysiol 112:552-67 [PubMed]
Model Information (Click on a link to find other models with that property)
Model Type: Realistic Network;
Brain Region(s)/Organism:
Cell Type(s): Wide dynamic range neuron;
Channel(s):
Gap Junctions:
Receptor(s): GabaA; AMPA; NMDA; Glutamate; Glycine;
Gene(s):
Transmitter(s):
Simulation Environment: NEURON;
Model Concept(s):
Implementer(s): Zhang, Tianhe [tz5@duke.edu];
Search NeuronDB for information about:  GabaA; AMPA; NMDA; Glutamate; Glycine;
/
ZhangEtAl2014
Critical Mod Files
AMPA_DynSyn.mod
B_A.mod
B_DR.mod
B_NA.mod
CaIntraCellDyn.mod *
GABAa_DynSyn.mod *
GABAb_DynSyn.mod *
Glycine_DynSyn.mod
HH2.mod *
HH2new.mod *
iCaAN.mod *
iCaL.mod
iKCa.mod *
iNaP.mod *
KDR.mod
KDRI.mod
NK1_DynSyn.mod *
NMDA_DynSyn.mod *
SS.mod
vsource.mod *
                            
TITLE (very)-Empirical model for the effect of NK1 receptor activation

COMMENT

 The effects of the activation of NK1 receptors are not totally
 clear but they seem to include both a membrane conductance change
 and an increase in intra-cellular calcium concentration (assumed
 to result from the release of calcium from intra-cellular buffers)
 The dynamics of this receptor should be used in association with
 dynamics for intra-cellular calcium dynamics. It affects all 
 calcium-dependent currents!

 We have based this model in the paper by Ito et al, 2002, with the
 title: "Substance P mobilizes intracellular calcium and activates
 a nonselective cation conductance in rat spiral ganglion neurons."
 The model includes therefore two mechanisms:
 a) a slow conductance change generating a depolarizing non-specific
    cationic current iNK1R
 b) an increase in cai
 Details are given in the code, in the form of comments.

 The activation of NK1R is subject to short-term dynamics acting on
 SP release & activation:
 "Release of substance P is induced by stressful stimuli, and 
 the magnitude of its release is proportional to the intensity 
 and frequency of stimulation. More potent and more frequent 
 stimuli allow diffusion of substance P farther from the site 
 of release, allowing activation of an approximately 3- to 5-times
 greater number of NK1 receptor-expressing neurons" (Mantyh, 2002)
 We used the short-term plasticity equations from Fuhrmann et al, 
 2002, to model the frequency dependent nature of the NK1R activation.
 Note however that these equations are being used in a more broad
 manner (i.e. the dynamics are intended to encapsulate not only
 synaptic release but other mechanisms, such as SP diffusion, which
 can give rise to facilitation).
 
 Written by Paulo Aguiar, May 2009
 pauloaguiar@fc.up.pt

 My thanks to Ted Carnevale for his fantastic help at
 The NEURON Forum
 "
ENDCOMMENT


NEURON {
	POINT_PROCESS NK1_DynSyn	
	USEION ca WRITE ica	
	RANGE tau_rise, tau_decay
	RANGE U1, tau_rec, tau_fac
	RANGE i, g, e, iNK1R, ica, ca_ratio
	NONSPECIFIC_CURRENT iNK1R
}
    
UNITS {
	(nA) = (nanoamp)
	(mV) = (millivolt)
	(molar) = (1/liter)
	(mM) = (millimolar)
}    
    
PARAMETER {
	tau_rise  = 10.0		(ms)  : dual-exponential conductance profile
	tau_decay = 5000.0		(ms)  : IMPORTANT: tau_rise < tau_decay
	U1        = 1.0			(1)   : The parameter U1, tau_rec and tau_fac define _
	tau_rec   = 0.1			(ms)  : the pre-synaptic SP short-term plasticity _
	tau_fac   = 0.1			(ms)  : mechanism (see Fuhrmann et al, 2002)
	e         = 0.0			(mV)  : reversal potential
	ca_ratio = 0.1			(1)   : the increase in cai is assumed here to be proportional to iNK1; this is the constant of proportionality	  
}
    
    
ASSIGNED {
	v		(mV)
	i		(nA)
	g		(umho)
	factor	(1)
	ica		(nA)
	iNK1R	(nA)
}

STATE {
	A
	B
}

INITIAL{
	LOCAL tp
	A = 0
	B = 0
	tp = (tau_rise*tau_decay)/(tau_decay-tau_rise)*log(tau_decay/tau_rise)
	factor = -exp(-tp/tau_rise)+exp(-tp/tau_decay)
	factor = 1/factor
}

BREAKPOINT {
	SOLVE state METHOD cnexp
	g = B-A
	i = g*(v-e)
	ica = ca_ratio * i
	: the ica current is "silenced" by removing ica from the total current
	iNK1R = i - ica
	: this way we have an increase in cai without a contribution of ica in membrane currents
}

DERIVATIVE state{
	A' = -A/tau_rise
	B' = -B/tau_decay
}

NET_RECEIVE (weight, Pv, P, Use, t0 (ms)){
	INITIAL{
		P=1
		Use=0
		t0=t
	}	

	Use = Use * exp(-(t-t0)/tau_fac)
	Use = Use + U1*(1-Use) 
	P = 1-(1- P) * exp(-(t-t0)/tau_rec)
	Pv= Use * P
	P = P - Use * P
	
	t0=t
	
	A=A + weight*factor*Pv
	B=B + weight*factor*Pv
}


Loading data, please wait...