Schiz.-linked gene effects on intrinsic single-neuron excitability (Maki-Marttunen et al. 2016)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:169457
Python scripts for running NEURON simulations that model a layer V pyramidal cell with certain genetic variants implemented. The genes included are obtained from genome-wide association studies of schizophrenia.
Reference:
1 . Mäki-Marttunen T, Halnes G, Devor A, Witoelar A, Bettella F, Djurovic S, Wang Y, Einevoll GT, Andreassen OA, Dale AM (2016) Functional Effects of Schizophrenia-Linked Genetic Variants on Intrinsic Single-Neuron Excitability: A Modeling Study. Biol Psychiatry Cogn Neurosci Neuroimaging 1:49-59 [PubMed]
Model Information (Click on a link to find other models with that property)
Model Type: Neuron or other electrically excitable cell;
Brain Region(s)/Organism:
Cell Type(s): Neocortex L5/6 pyramidal GLU cell;
Channel(s): I Na,p; I Na,t; I L high threshold; I T low threshold; I K; I K,leak; I M; I h; I K,Ca; I A, slow; Ca pump;
Gap Junctions:
Receptor(s):
Gene(s): Nav1.1 SCN1A; Nav1.7 SCN9A; Cav3.3 CACNA1I; Cav1.3 CACNA1D; Cav1.2 CACNA1C; Kv2.1 KCNB1; HCN1;
Transmitter(s):
Simulation Environment: NEURON; Python;
Model Concept(s): Coincidence Detection; Active Dendrites; Detailed Neuronal Models; Schizophrenia;
Implementer(s): Maki-Marttunen, Tuomo [tuomo.maki-marttunen at tut.fi];
Search NeuronDB for information about:  Neocortex L5/6 pyramidal GLU cell; I Na,p; I Na,t; I L high threshold; I T low threshold; I K; I K,leak; I M; I h; I K,Ca; I A, slow; Ca pump;
/
Maki-MarttunenEtAl2015
models
morphologies
readme.txt
Ca_HVA.mod *
Ca_LVAst.mod *
CaDynamics_E2.mod *
epsp.mod *
Ih.mod *
Im.mod *
K_Pst.mod *
K_Tst.mod *
Nap_Et2.mod
NaTa_t.mod
NaTs2_t.mod
SK_E2.mod *
SKv3_1.mod *
collectscalings.py
collectthresholddistalamps.py
drawfig1.py
drawfig2.py
drawfig3.py
drawfig4.py
drawfig5.py
findthresholddistalamps.py
mutation_stuff.py
mytools.py
runcontrols.py
savesynapselocations.py
scalemutations.py
scalings.sav
                            
:Reference :Colbert and Pan 2002

NEURON	{
	SUFFIX NaTa_t
	USEION na READ ena WRITE ina
	RANGE gNaTa_tbar, gNaTa_t, ina, offm, offh, slom, sloh, tauma, taumb, tauha, tauhb
}

UNITS	{
	(S) = (siemens)
	(mV) = (millivolt)
	(mA) = (milliamp)
}

PARAMETER	{
	gNaTa_tbar = 0.00001 (S/cm2)
        offm = -38 (mV)
        offh = -66 (mV)
        slom = 6.0 (mV)
        sloh = 6.0 (mV)
        tauma = 5.49451 (ms)
        taumb = 8.06452 (ms)
        tauha = 66.6667 (ms)
        tauhb = 66.6667 (ms)
}

ASSIGNED	{
	v	(mV)
	ena	(mV)
	ina	(mA/cm2)
	gNaTa_t	(S/cm2)
	mInf
	mTau
	mAlpha
	mBeta
	hInf
	hTau
	hAlpha
	hBeta
}

STATE	{
	m
	h
}

BREAKPOINT	{
	SOLVE states METHOD cnexp
	gNaTa_t = gNaTa_tbar*m*m*m*h
	ina = gNaTa_t*(v-ena)
}

DERIVATIVE states	{
	rates()
	m' = (mInf-m)/mTau
	h' = (hInf-h)/hTau
}

INITIAL{
	rates()
	m = mInf
	h = hInf
}

PROCEDURE rates(){
  LOCAL qt
  qt = 2.3^((34-21)/10)
	
  UNITSOFF
    if(v == offm){
    	v = v+0.0001
    }
		mAlpha = -(offm-v)/(1-(exp((offm-v)/slom)))/tauma
		mBeta  = (offm-v)/(1-(exp(-(offm-v)/slom)))/taumb
		mTau = (1/(mAlpha + mBeta))/qt
		mInf = mAlpha/(mAlpha + mBeta)

    if(v == offh){
      v = v + 0.0001
    }

		hAlpha = (offh-v)/(1-(exp(-(offh-v)/sloh)))/tauha
		hBeta  = -(offh-v)/(1-(exp((offh-v)/sloh)))/tauhb
		hTau = (1/(hAlpha + hBeta))/qt
		hInf = hAlpha/(hAlpha + hBeta)
	UNITSON
}

Loading data, please wait...