Schiz.-linked gene effects on intrinsic single-neuron excitability (Maki-Marttunen et al. 2016)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:169457
Python scripts for running NEURON simulations that model a layer V pyramidal cell with certain genetic variants implemented. The genes included are obtained from genome-wide association studies of schizophrenia.
Reference:
1 . Mäki-Marttunen T, Halnes G, Devor A, Witoelar A, Bettella F, Djurovic S, Wang Y, Einevoll GT, Andreassen OA, Dale AM (2016) Functional Effects of Schizophrenia-Linked Genetic Variants on Intrinsic Single-Neuron Excitability: A Modeling Study. Biol Psychiatry Cogn Neurosci Neuroimaging 1:49-59 [PubMed]
Model Information (Click on a link to find other models with that property)
Model Type: Neuron or other electrically excitable cell;
Brain Region(s)/Organism:
Cell Type(s): Neocortex L5/6 pyramidal GLU cell;
Channel(s): I Na,p; I Na,t; I L high threshold; I T low threshold; I K; I K,leak; I M; I h; I K,Ca; I A, slow; Ca pump;
Gap Junctions:
Receptor(s):
Gene(s): Nav1.1 SCN1A; Nav1.7 SCN9A; Cav3.3 CACNA1I; Cav1.3 CACNA1D; Cav1.2 CACNA1C; Kv2.1 KCNB1; HCN1;
Transmitter(s):
Simulation Environment: NEURON; Python;
Model Concept(s): Coincidence Detection; Active Dendrites; Detailed Neuronal Models; Schizophrenia;
Implementer(s): Maki-Marttunen, Tuomo [tuomo.maki-marttunen at tut.fi];
Search NeuronDB for information about:  Neocortex L5/6 pyramidal GLU cell; I Na,p; I Na,t; I L high threshold; I T low threshold; I K; I K,leak; I M; I h; I K,Ca; I A, slow; Ca pump;
/
Maki-MarttunenEtAl2015
models
morphologies
readme.txt
Ca_HVA.mod *
Ca_LVAst.mod *
CaDynamics_E2.mod *
epsp.mod *
Ih.mod *
Im.mod *
K_Pst.mod *
K_Tst.mod *
Nap_Et2.mod
NaTa_t.mod
NaTs2_t.mod
SK_E2.mod *
SKv3_1.mod *
collectscalings.py
collectthresholddistalamps.py
drawfig1.py
drawfig2.py
drawfig3.py
drawfig4.py
drawfig5.py
findthresholddistalamps.py
mutation_stuff.py
mytools.py
runcontrols.py
savesynapselocations.py
scalemutations.py
scalings.sav
                            
:Comment : The persistent component of the K current
:Reference : :		Voltage-gated K+ channels in layer 5 neocortical pyramidal neurones from young rats:subtypes and gradients,Korngreen and Sakmann, J. Physiology, 2000
:Comment : shifted -10 mv to correct for junction potential
:Comment: corrected rates using q10 = 2.3, target temperature 34, orginal 21


NEURON	{
	SUFFIX K_Pst
	USEION k READ ek WRITE ik
	RANGE gK_Pstbar, gK_Pst, ik, offm, slom, offmt, slomt, taummin, taumdiff1, taumdiff2, offh, sloh, offht1, offht2, sloht, tauhmean, tauhdiff1, tauhdiff2
}

UNITS	{
	(S) = (siemens)
	(mV) = (millivolt)
	(mA) = (milliamp)
}

PARAMETER	{
	gK_Pstbar = 0.00001 (S/cm2)
	offm = -11 (mV)
	slom = 12 (mV)
	offmt = -10 (mV)
	slomt = 38.46153846 (mV)
	taummin = 1.25 (ms)
        taumdiff1 = 175.03 (ms)
        taumdiff2 = 13 (ms)
	offh = -64 (mV)
	sloh = 11 (mV)
	offht1 = -65 (mV)
	offht2 = -85 (mV)
	sloht = 48 (mV)
	tauhmean = 360 (ms)
	tauhdiff1 = 1010 (ms)
        tauhdiff2 = 24 (ms/mV)

}

ASSIGNED	{
	v	(mV)
	ek	(mV)
	ik	(mA/cm2)
	gK_Pst	(S/cm2)
	mInf
	mTau
	hInf
	hTau
}

STATE	{
	m
	h
}

BREAKPOINT	{
	SOLVE states METHOD cnexp
	gK_Pst = gK_Pstbar*m*m*h
	ik = gK_Pst*(v-ek)
}

DERIVATIVE states	{
	rates()
	m' = (mInf-m)/mTau
	h' = (hInf-h)/hTau
}

INITIAL{
	rates()
	m = mInf
	h = hInf
}

PROCEDURE rates(){
  LOCAL qt, thresh
  qt = 2.3^((34-21)/10)
  thresh = offmt-slomt/2*log(taumdiff1/taumdiff2)
	UNITSOFF
		mInf =  (1/(1 + exp((offm-v)/slom)))
                if(v<thresh){
		    mTau =  (taummin+taumdiff1*exp(-(offmt-v)/slomt))/qt
                } else {
                    mTau = ((taummin+taumdiff2*exp((offmt-v)/slomt)))/qt
                }
		hInf =  1/(1 + exp(-(offh-v)/sloh))
		hTau =  (tauhmean+(tauhdiff1-tauhdiff2*(offht1-v))*exp(-((offht2-v)/sloht)^2))/qt
	UNITSON
}

Loading data, please wait...