Axon-somatic back-propagation in a detailed model of cat spinal motoneuron (Balbi et al, 2015)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:180370
Morphologically detailed conductance-based models of cat spinal alpha motoneurons have been developed, with the aim to reproduce and clarify some aspects of the electrophysiological behavior of the antidromic axon-somatic spike propagation. Fourteen 3D morphologically detailed somata and dendrites of cat spinal alpha motoneurons have been imported from an open-access web-based database of neuronal morphologies, NeuroMorpho.org, and instantiated in neurocomputational models.
Reference:
1 . Balbi P, Martinoia S, Massobrio P (2015) Axon-somatic back-propagation in detailed models of spinal alpha motoneurons. Front Comput Neurosci 9:15 [PubMed]
Model Information (Click on a link to find other models with that property)
Model Type: Neuron or other electrically excitable cell;
Brain Region(s)/Organism: Spinal motoneuron;
Cell Type(s): Spinal cord lumbar motor neuron alpha ACh cell;
Channel(s): I Na,p; I Na,t; I K; I h; I K,Ca; I Calcium;
Gap Junctions:
Receptor(s):
Gene(s):
Transmitter(s):
Simulation Environment: NEURON;
Model Concept(s):
Implementer(s): Balbi, Pietro [piero.balbi at fsm.it];
Search NeuronDB for information about:  Spinal cord lumbar motor neuron alpha ACh cell; I Na,p; I Na,t; I K; I h; I K,Ca; I Calcium;
TITLE naps		:modified to have slow inactivation described in Fleidervish and to make slope a global parameter

NEURON {
	SUFFIX naps
	USEION na READ ena WRITE ina
	RANGE  gbar, thegna, sh, ar
	GLOBAL minf, mtau,sinf,taus,vslope 
}

PARAMETER {
	gbar = .0052085   	(mho/cm2)
	sh = 0  (mV)
	vslope=6.8   (mV)	:activation slope
	ena		(mV)       :must be explicitly defined in hoc     
        a0s=0.001	(/ms)	
        b0s=0.0034	(/ms)
        asvh=-85	(mV) 
        bsvh=-17	(mV) 
        avs=30		(mV)
        bvs=10		(mV)
        ar=1		(1)		: 1=no inact., 0=max inact.
	celsius (degC)
	v 		(mV)
}


UNITS {
	(mA) = (milliamp)
	(mV) = (millivolt)
	(pS) = (picosiemens)
	(um) = (micron)
} 

ASSIGNED {
	ina 		(mA/cm2)
	thegna		(mho/cm2)
	minf 	
	mtau (ms)
	sinf
	taus (ms)
}
 

STATE { m s }

UNITSOFF

BREAKPOINT {
    SOLVE states METHOD cnexp
	        		
	thegna =gbar*m*s       
	ina = thegna * (v - ena)
	} 

INITIAL {
	trates(v,ar,sh)
	mtau = 1
	m=minf  
	s=sinf
}

DERIVATIVE states {   
    	trates(v,ar,sh)
	mtau = 1
        s' = (sinf - s)/taus
	m' = (minf-m)/mtau
}

PROCEDURE trates(vm,a2,sh2) {  
        LOCAL   c 

	minf = (1/(1+exp(-(vm+52.3-sh2)/vslope)))      	
        taus = 1/(alps(vm)+bets(vm))
	c=alps(vm)*taus
        sinf = c+a2*(1-c)
 }




FUNCTION alps(v(mV)) {  
  alps = a0s*exp((asvh-v)/avs)
}

FUNCTION bets(v(mV)) {
  bets = b0s/(exp((bsvh-v)/bvs)+1)
}

UNITSON

Loading data, please wait...