Allen Institute: Pvalb-IRES-Cre VISp layer 6a 473860269

 Download zip file   Auto-launch 
Help downloading and running models
Accession:184323
This is an Allen Cell Types Database model of a Pvalb-IRES-Cre neuron from layer 6a of the mouse primary visual cortex. The model was based on a traced morphology after filling the cell with biocytin and optimized using experimental electrophysiology data recorded from the same cell. The electrophysiology data was collected in a highly standardized way to facilitate comparison across all cells in the database. The model was optimized by a genetic algorithm that adjusted the densities of conductances placed at the soma to match experimentally-measured features of action potential firing. Data and models from the Allen Cell Types Database are made available to the community under the Allen Institute's Terms of Use and Citation Policy.
Reference:
1 . Allen Institute (2015) Documentation Allen Cell Types Database
Model Information (Click on a link to find other models with that property)
Model Type: Neuron or other electrically excitable cell;
Brain Region(s)/Organism: Neocortex;
Cell Type(s): Neocortex layer 6a interneuron;
Channel(s): I L high threshold; I T low threshold; I A; I K; I M; I h; I K,Ca; I Sodium; I A, slow;
Gap Junctions:
Receptor(s):
Gene(s):
Transmitter(s):
Simulation Environment: NEURON; Python;
Model Concept(s): Parameter Fitting; Calcium dynamics; Vision;
Implementer(s):
Search NeuronDB for information about:  I L high threshold; I T low threshold; I A; I K; I M; I h; I K,Ca; I Sodium; I A, slow;
Files displayed below are from the implementation
/
473860269
modfiles
Ca_HVA.mod *
Ca_LVA.mod *
CaDynamics.mod *
Ih.mod *
Im.mod *
Im_v2.mod *
K_P.mod *
K_T.mod *
Kd.mod *
Kv2like.mod *
Kv3_1.mod *
Nap.mod *
NaTa.mod *
NaTs.mod *
NaV.mod *
SK.mod *
                            
: Reference:		Reuveni, Friedman, Amitai, and Gutnick, J.Neurosci. 1993

NEURON	{
	SUFFIX Ca_HVA
	USEION ca READ eca WRITE ica
	RANGE gbar, g, ica 
}

UNITS	{
	(S) = (siemens)
	(mV) = (millivolt)
	(mA) = (milliamp)
}

PARAMETER	{
	gbar = 0.00001 (S/cm2) 
}

ASSIGNED	{
	v	(mV)
	eca	(mV)
	ica	(mA/cm2)
	g	(S/cm2)
	mInf
	mTau
	mAlpha
	mBeta
	hInf
	hTau
	hAlpha
	hBeta
}

STATE	{ 
	m
	h
}

BREAKPOINT	{
	SOLVE states METHOD cnexp
	g = gbar*m*m*h
	ica = g*(v-eca)
}

DERIVATIVE states	{
	rates()
	m' = (mInf-m)/mTau
	h' = (hInf-h)/hTau
}

INITIAL{
	rates()
	m = mInf
	h = hInf
}

PROCEDURE rates(){
	UNITSOFF
    :   if((v == -27) ){        
    :       v = v+0.0001
    :   }
		:mAlpha =  (0.055*(-27-v))/(exp((-27-v)/3.8) - 1)
		mAlpha = 0.055 * vtrap(-27 - v, 3.8)        
		mBeta  =  (0.94*exp((-75-v)/17))
		mInf = mAlpha/(mAlpha + mBeta)
		mTau = 1/(mAlpha + mBeta)
		hAlpha =  (0.000457*exp((-13-v)/50))
		hBeta  =  (0.0065/(exp((-v-15)/28)+1))
		hInf = hAlpha/(hAlpha + hBeta)
		hTau = 1/(hAlpha + hBeta)
	UNITSON
}

FUNCTION vtrap(x, y) { : Traps for 0 in denominator of rate equations
	UNITSOFF
	if (fabs(x / y) < 1e-6) {
		vtrap = y * (1 - x / y / 2)
	} else {
		vtrap = x / (exp(x / y) - 1)
	}
	UNITSON
}

Loading data, please wait...