Kinetic synaptic models applicable to building networks (Destexhe et al 1998)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:18500
Simplified AMPA, NMDA, GABAA, and GABAB receptor models useful for building networks are described in a book chapter. One reference paper synthesizes a comprehensive general description of synaptic transmission with Markov kinetic models which is applicable to modeling ion channels, synaptic release, and all receptors. Also a simple introduction to this method is given in a seperate paper Destexhe et al Neural Comput 6:14-18 , 1994). More information and papers at http://cns.iaf.cnrs-gif.fr/Main.html and through email: Destexhe@iaf.cnrs-gif.fr
References:
1 . Destexhe A, Mainen ZF, Sejnowski TJ (1994) Synthesis of models for excitable membranes, synaptic transmission and neuromodulation using a common kinetic formalism. J Comput Neurosci 1:195-230 [PubMed]
2 . Destexhe A, Mainen ZF, Sejnowski TJ (1998) Kinetic models of synaptic transmission Methods In Neuronal Modeling, Koch C:Segev I, ed. pp.1
3 . Destexhe A, Mainen Z, Sejnowski TJ (1994) An efficient method for computing synaptic conductances based on a kinetic model of receptor binding Neural Comput 6:14-18
Model Information (Click on a link to find other models with that property)
Model Type: Synapse;
Brain Region(s)/Organism:
Cell Type(s):
Channel(s):
Gap Junctions:
Receptor(s): GabaA; GabaB; AMPA; NMDA; Glutamate; Gaba;
Gene(s):
Transmitter(s): Gaba; Glutamate;
Simulation Environment: NEURON;
Model Concept(s): Ion Channel Kinetics; Simplified Models; Markov-type model;
Implementer(s): Destexhe, Alain [Destexhe at iaf.cnrs-gif.fr]; Mainen, Zach [Mainen at cshl.edu];
Search NeuronDB for information about:  GabaA; GabaB; AMPA; NMDA; Glutamate; Gaba; Gaba; Glutamate;
/*----------------------------------------------------------------------------

	demo file for first order kinetic synapse mechanism
	---------------------------------------------------

	This file provides a simulation of GABAergic IPSP's in a passive
	compartment.  A presyaptic compartment (PRE) is created and 
	contains Hodgkin-Huxley Na/K currents for generating action potentials.
	A current pulse is injected in PRE to elicit a train of spikes.
	For each spike an IPSP is generated in the postsynaptic compartment
	(POST).  The number of presynaptic spikes can be adjusted by changing
        the pulse duration (stim.dur).

	Whole-cell recorded GABA-A postsynaptic currents (Otis et al,
        J. Physiol. 463: 391-407, 1993) were used to estimate the parameters
	of the present simulations; the fit was performed using a simplex
	algorithm (see Destexhe et al., J. Neurophysiol. 72: 803-818, 1994).


	Alain Destexhe, The Salk Institute, 1994

----------------------------------------------------------------------------*/



//----------------------------------------------------------------------------
//  load and define general graphical procedures
//----------------------------------------------------------------------------

// xopen("$(NEURONHOME)/lib/hoc/stdrun.hoc")
load_file("nrngui.hoc")

objectvar g[20]			// max 20 graphs
ngraph = 0

proc addgraph() { local ii	// define subroutine to add a new graph
				// addgraph("variable", minvalue, maxvalue)
	ngraph = ngraph+1
	ii = ngraph-1
	g[ii] = new Graph()
	g[ii].size(0,tstop,$2,$3)
	g[ii].xaxis()
	g[ii].yaxis()
	g[ii].addvar($s1,1,0)
	g[ii].save_name("graphList[0].")
	graphList[0].append(g[ii])
}

// nrnmainmenu()			// create main menu
nrncontrolmenu()		// crate control menu



//----------------------------------------------------------------------------
//  general parameters
//----------------------------------------------------------------------------

dt=0.025
tstop = 50
runStopAt = tstop
steps_per_ms = 1/dt
celsius = 36
v_init = -70



//----------------------------------------------------------------------------
//  create compartments and insert passive properties
//----------------------------------------------------------------------------

create PRE,POST
forall {
  diam=10
  L=10
  insert pas
  g_pas=1/5000
  e_pas=v_init
}



//----------------------------------------------------------------------------
//  insert presynaptic mechanisms
//----------------------------------------------------------------------------

access PRE		// insert Hodgk-Hux. Na+ and K+ currents for spikes
insert hh2
ek = -90
gnabar_hh2 = 0.1
gkbar_hh2 = 0.03

objectvar stim		// insert current injection

PRE stim = new IClamp(.5)	  // command for version nrn3a8 or newer
// PRE stim = new PulseStim(.5)	  // command for older NEURON versions

stim.del = 0
stim.dur = 2		// 2 ms for single psp, 10 ms for train of psps
stim.amp = 0.1




//----------------------------------------------------------------------------
//  insert postsynaptic mechansisms
//----------------------------------------------------------------------------

objectvar c
c = new GABAa()			// create synapse
POST c.loc(0.5)			// assign postsynaptic compartment
setpointer c.pre, PRE.v(0.5)	// assign presynaptic compartment

Cmax_GABAa	= 1	//	(mM)	 max transmitter concentration
Cdur_GABAa	= 1	//	(ms)	 transmitter duration (rising phase)
Alpha_GABAa	= 0.53	//	(/ms mM) forward (binding) rate
Beta_GABAa	= 0.18	//	(/ms)	 backward (unbinding) rate
Erev_GABAa	= -80	//	(mV)	 reversal potential
Prethresh_GABAa	= 0 	//	(mV)	 voltage level nec for release
Deadtime_GABAa	= 1	//	(ms)	 mimimum time between release events
c.gmax		= 0.001	//	(umho)	 maximum conductance



//----------------------------------------------------------------------------
//  add graphs
//----------------------------------------------------------------------------

addgraph("PRE.v(0.5)",-90,40)
addgraph("c.C",0,1)
g[1].addvar("c.R",1,0)
addgraph("c.i",-0.00001,0.01)
addgraph("POST.v(0.5)",v_init-5,v_init)



Loading data, please wait...