Fast AMPA receptor signaling (Geiger et al 1997)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:19022
Glutamatergic transmission at a principal neuron-interneuron synapse was investigated by dual whole-cell patch-clamp recording in rat hippocampal slices combined with morphological analysis and modeling. Simulations based on a compartmental model of the interneuron indicated that the rapid postsynaptic conductance change determines the shape and the somatodendritic integration of EPSPs, thus enabling interneurons to detect synchronous principal neuron activity.
Reference:
1 . Geiger JR, Lübke J, Roth A, Frotscher M, Jonas P (1997) Submillisecond AMPA receptor-mediated signaling at a principal neuron-interneuron synapse. Neuron 18:1009-23 [PubMed]
Model Information (Click on a link to find other models with that property)
Model Type: Synapse;
Brain Region(s)/Organism:
Cell Type(s):
Channel(s):
Gap Junctions:
Receptor(s): AMPA;
Gene(s):
Transmitter(s): Glutamate;
Simulation Environment: NEURON;
Model Concept(s): Influence of Dendritic Geometry; Detailed Neuronal Models;
Implementer(s): Roth, Arnd ;
Search NeuronDB for information about:  AMPA; Glutamate;
: Suffix syn2

COMMENT
synaptic current with exponential rise and decay conductance defined by
        i = g * (v - e)      i(nanoamps), g(micromhos);
        where
         g = 0 for t < onset and
         g=amp*((1-exp(-(t-onset)/tau0))-(1-exp(-(t-onset)/tau1)))
          for t > onset
plus a little bulletproofing and stuff to make it run a mite faster
and make it compatible with cvode
ENDCOMMENT

NEURON {
	POINT_PROCESS syn2
	RANGE onset, tau0, tau1, gmax, e, i
	NONSPECIFIC_CURRENT i
}

UNITS {
	(nA) = (nanoamp)
	(mV) = (millivolt)
	(uS) = (microsiemens)
}

PARAMETER {
	onset=0  (ms)
	tau0=0.5 (ms) <1e-3,1e6>
	tau1=5.0 (ms) <1e-3,1e6>
	gmax=0 	 (uS) <0,1e9>
	e=0	 (mV)
}

ASSIGNED {
	v (mV)
	i (nA)
	g (uS)
	factor
	a0
	a1
}

INITIAL { LOCAL tpeak
	if (tau0/tau1 > 0.9999) {
		tau0 = 0.9999*tau1
	}
	tpeak=tau0*tau1*log(tau0/tau1)/(tau0-tau1)
	factor=1/((1-exp(-tpeak/tau0))-(1-exp(-tpeak/tau1)))
}

BREAKPOINT {
	if (gmax) { at_time(onset) }
	g = gmax*cond(t-onset)
	i = g*(v - e)
}

FUNCTION cond(x (ms)) { LOCAL temp
	if (x < 0) {
		cond = 0
	}else{
		temp = x/tau0
		if (temp > 10) {
			a0 = 1
		} else {
			a0=1-exp(-temp)
		}
		temp = x/tau1
		if (temp > 10) {
			a1 = 1
		} else {
			a1=1-exp(-temp)
		}
		cond = factor*(a0-a1)
	}
}

Loading data, please wait...